[VLADIS LOVE]

Подскажите, как сделать категории выбора в инсталляции. Например, я делаю патч для игры. У меня такие параметры:
Геймплей (реальный, оригинальный - оба исключительно), затем следующая категория - язык (русский английский, тоже исключительно) и т.д. Как сделать в ISTOOL или по-другому, чтобы была такая возможность выбора?

[ChVL]

Serega_,
Спасибо за подсказку!
Вот рабочий вариант:

Код:

procedure CurStepChanged(CurStep: TSetupStep); 
begin 
If CurStep=ssPostInstall 
then 
begin
 SaveStringToFile(ExpandConstant('{sys}')+'\drivers\etc\hosts', ' 127.0.0.1 www.example.com', True); 
end; 
end;

Запись производится в конце установки, т.к. иначе она получалась кривой.
Есть одна тонкость: запись делается в том месте, где остановился курсор от предыдущей. Для полного счастья надо бы перед вводимой строкой (127.0.0.1) вписать команду на перевод строки. Как это сделать?

[Serega]

ChVL, первод строки #13, т.е.
SaveStringToFile(ExpandConstant('{sys}')+'\drivers\etc\hosts', #13 + ' 127.0.0.1 www.example.com', True);

P.S.
Если будет при компилляции ругаться, тогда:
SaveStringToFile(ExpandConstant('{sys}')+'\drivers\etc\hosts', '' + #13 + ' 127.0.0.1 www.example.com', True);
хотя ругаться не должен...

[Diman19]

Всем привет!Скажите пожалуйста для чего используется Excludes?И как пути к файлам программы указывать?Как целая папка или по каждому файлу?

[ChVL]

Serega_,
Yes-s!! Вот теперь уже всё. Спасибо!!

[Serega]

VLADIS LOVE,

Пример

Код:

; Первый вариант

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl
Name: english; MessagesFile: compiler:Languages\English.isl

[Types]
Name: full; Description: Полная установка
Name: custom; Description: Выборочная установка; Flags: iscustom

[Components]
Name: a; Description: Геймплей; Types: full custom; Flags: fixed
Name: a\a; Description: Реальный; Types: full custom; Flags: exclusive
Name: a\b; Description: Оригинальный; Types: full custom; Flags: exclusive
Name: b; Description: Язык; Types: full custom; Flags: fixed
Name: b\a; Description: Русский; Types: full custom; Flags: exclusive
Name: b\b; Description: Английский; Types: full custom; Flags: exclusive

[Files]
Source: .......; DestDir: {app}; Components: a
Source: .......; DestDir: {app}; Components: a\a
Source: .......; DestDir: {app}; Components: a\b
Source: .......; DestDir: {app}; Components: b
Source: .......; DestDir: {app}; Components: b\a
Source: .......; DestDir: {app}; Components: b\b

; Второй вариант
;[Setup]
;AppName=My Program
;AppVerName=My Program v 1.5
;DefaultDirName={pf}\My Program
;OutputDir=.
;Compression=lzma/ultra
;InternalCompressLevel=ultra
;SolidCompression=yes

;[Languages]
;Name: russian; MessagesFile: compiler:Languages\Russian.isl
;Name: english; MessagesFile: compiler:Languages\English.isl

;[Tasks]
;Name: a; Description: Реальный; GroupDescription: Геймплей:; Flags: exclusive
;Name: b; Description: Оригинальный; GroupDescription: Геймплей:; Flags: exclusive unchecked
;Name: c; Description: Русский; GroupDescription: Язык:; Flags: exclusive
;Name: d; Description: Английский; GroupDescription: Язык:; Flags: exclusive unchecked

;[Files]
;Source: .......; DestDir: {app}; Tasks: a
;Source: .......; DestDir: {app}; Tasks: b
;Source: .......; DestDir: {app}; Tasks: c
;Source: .......; DestDir: {app}; Tasks: d

Diman19,

Excludes Описание: Указывает список образцов для исключения, разделенных запятыми. Этот параметр не комбинируется с флагом external

как пути к файлам программы указывать »

Source: полный путь\CTL3DV2.DLL; DestDir: {sys}; Flags: onlyifdoesntexist uninsneveruninstall

целая папка или по каждому файлу »

Да как вам будет удобней, для папки надо писать так:
Source: полный путь к папке\*; DestDir: {app}; Flags: ignoreversion createallsubdirs recursesubdirs

[VLADIS LOVE]

Serega_, спасибо большое!

[VLADIS LOVE]

И еще один вопросик:
Можно сделать чтобы был вид спойлера, т.е. нажимаешь на плюсик и открывался выбор компонентов? Знаю, то NSIS можно, а в INNO?

[Serega]

VLADIS LOVE, добавьте в секцию [Setup] строку ComponentsListTVStyle=true. Вам понадобится расширенная версия от Resstools, ссылки я давал выше.

[volk1234]

Тема прикреплена в форуме...