[Serega]

MrLD,
Установите себе ispack-5.2.3, упс уже вышло обновление, версия ispack-5.2.4-dev, сейчас скачаю, а также расширенную версию от Restools, которая добавляет много возможностей для инсталляторов...

P.S.
буду через час...

Забыл уточнить. Сначала нужно установить ispack, а затем обновить путём замены файлов от Restools.

[Diman19]

Всем привет!Скажите пожалуйста как при выборе компонентов указать в какую папку копировать выбранные компоненты?Также интересует вопрос в том как сделать так чтобы если выбираешь один компонент,копируется файл с одним содержанием,а если выбираешь другой компонент или если компонент не выбирать,то копируется файл с таким же именет но только с другим содержанием внутри.Скажите пожалуйста как так сделать.

[Serega]

Diman19,

пример

Код:

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Types]
Name: full; Description: Полная установка
Name: custom; Description: Выборочная установка; Flags: iscustom

[Components]
Name: a; Description: Моя программа™; Types: full custom
Name: a\a; Description: Руководство пользователя; Types: full
Name: a\a\a; Description: Русский; Flags: exclusive
Name: a\a\b; Description: English; Flags: exclusive
Name: a\b; Description: Справка; Types: full

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; Components: a
Source: compiler:Examples\Readme-ru.txt; DestDir: {app}; Components: a\a\a
Source: compiler:Examples\Readme-en.txt; DestDir: {app}; Components: a\a\b
Source: compiler:Examples\MyProg.chm; DestDir: {app}; Components: a\b

[Diman19]

Всем привет!Всем спасибо кто отвечает и помогает.Прошу помочь с маленькой проблемой.При создании исталлятора не работаю чекбоксы которые должны копировать файлы в папку если они помечены.Пишу код следующим образом

Name: programfiles; Description: Файлы программы; Types: full custom; Flags: fixed
Name: files; Description: Доп.файлы; Types: full
Name: plugins; Description: Плагины; Types: full custom
Name: "plugins\plugin1"; Description: "plugin1";



это путь к файлу запуска
Source: "C:\myprogram\myprogram.exe"; DestDir: "{app}"; Flags: ignoreversion
Это путь ко всем папкам и файлам.Тоестьв этой папке лежат файлы и папки программы.
Source: "C:\myprogram\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: programfiles

здесь я указываю путь к файлам плагина.

Source: "C:\myprogram\other\plugis\plugin1.exe"; DestDir: {app}; Components: plugins\plugin1

Source: "C:\myprogram\other\plugins\plugin1.txt"; DestDir: {app}; Components: plugins\plugin1

Проблема возникла в том что если во время установки не установить чекбоксы на плугины,то они всё равно устанавливаются незнаю почему.Скажите пожалуйста где я допустил ошибку?Может путь неправильно к файлам программы указал?Указывал папку со всеми файлами.Помогите пожалуйста разобраться

[Serega]

Diman19, я ничего не понял, покажите скрипт полностью и используйте тег [ more][/more], чтоб ваше сообщение не было объёмным...

[Diman19]

Serega_,

Ок Вот полный скрипт.

читать дальше »

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Myprogram"
#define MyAppVerName "Myprogram 1.5"
#define MyAppPublisher "My Company, Inc."
#define MyAppURL "http://www.example.com/"
#define MyAppExeName "myprogram.exe"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{5EEBB548-ED74-4FFF-9D6D-BE4A6C859BA4}
AppName={#MyAppName}
AppVerName={#MyAppVerName}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
LicenseFile=C:\myprogram\readme.txt
OutputDir=C:\Documents and Settings\Дима\My Documents
OutputBaseFilename=setup
Compression=lzma
SolidCompression=yes
ComponentsListTVStyle=true

[Languages]
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"

[Types]
Name: full; Description: Полная установка
Name: recomend; Description: Рекомендуемая установка
Name: custom; Description: Выборочная установка; Flags: iscustom

[Components]
Name: programfiles; Description: Файлы программы™; Types: full recomend custom; Flags: fixed
Name: source; Description: Исходники; Types: full
Name: plugins; Description: Плагины; Types: full recomend custom
Name: "plugins\Plugin1"; Description: "Plugin1";



[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked
Name: "quicklaunchicon"; Description: "{cm:CreateQuickLaunchIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]
Source: "C:\myprogram\myprogram.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\myprogram\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs; Components: programfiles
Source: "C:\myprogram\other\plugins\plugin1.exe"; DestDir: {app}; Components: plugins\Plugin1
Source: "C:\myprogram\other\plugins\plugin1.txt"; DestDir: {app}; Components: plugins\Plugin1

; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: quicklaunchicon

[Run]
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#MyAppName}}"; Flags: nowait postinstall skipifsilent

[Serega]

Diman19, добавьте Excludes: plugin1.exe, plugin1.txt

читать дальше »

Код:

......................................
Source: C:\myprogram\*; DestDir: {app}; Excludes: plugin1.exe, plugin1.txt; Flags: ignoreversion recursesubdirs createallsubdirs; Components: programfiles
Source: C:\myprogram\other\plugins\plugin1.exe; DestDir: {app}; Components: plugins\Plugin1; Flags: ignoreversion
Source: C:\myprogram\other\plugins\plugin1.txt; DestDir: {app}; Components: plugins\Plugin1; Flags: ignoreversion
......................................

[Serega]

Здравствуйте, решил реализовать в Inno Setup 'Бегущую строку' и вот, что получилось...

читать дальше »

Код:

; Решил реализовать в Inno Setup 'Бегущую строку' и вот, что получилось...
; Для нормальной работы у Вас должен быть установлен набор от Restools http://restools.hanzify.org/
; Подразумеваю под словом набор - InnoCompiler и ISCmplr, последние версии Вы можете найти на сайте Restools.
; Автор: Serega, http://forum.oszone.net/member.php?userid=88670

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[_Code]
var
  lbl1: TLabel;
  tmr1: TTimer;

procedure tmr1Timer(Sender: TObject);
var
  str: string;
begin
  str:= lbl1.Caption;
  lbl1.Caption:= Copy(str, 2, Length(str) - 1) + Copy(str, 1, 1);
end;

procedure InitializeWizard();
begin
  //lbl1
  lbl1:= TLabel.Create(WizardForm);
  with lbl1 do begin
    Parent:= WizardForm;
    Left:= 20;
    Top:= 325;
    Width:= 200;
    Height:= 20;
    AutoSize:= False;
    Caption:= 'Вот, что можно сделать средствами Inno Setup...   ';
    Font.Color:= clWindowText;
    Font.Height:= -16;
    Font.Name:= 'MS Sans Serif';
    Font.Style:= [];
    ParentFont:= False;
  end;
  
  //tmr1
  tmr1:= TTimer.Create(WizardForm);
  with tmr1 do begin
    Interval:= 200;
    OnTimer:= @tmr1Timer;
  end;
end;

Для правильной работы требуется: ispack, после чего необходимо обновить, путём замены файлов, до расширенной версии от Restools.
В расширенную версию входят:
InnoCompiler - в неё входят файлы: Compil32.exe и Templates.dat;
Inno_ISCmplr_Setup - в неё входят файлы, лучше из папки InnoSetup_FullVCL: setup.e32, ISCmplr.dls, ISCmplr.dll и SetupLdr.e32.

[de_MAX]

Serega_,
Что-то не выходит:

Unknown type 'TTimer'

[Serega]

de_MAX, установите себе ispack, а затем обновите, путём замены файлов, до расширенной версии от Restools. Ссылки я давл выше, ссылка на пост.