[proxy]

пример:

Код:

#region: - Option
    Opt('MustDeclareVars',      1)
    Opt('TrayIconDebug',        1)
    Opt('TrayIconHide',         0)
    Opt('SendKeyDelay',         1)
#endregion

#region: - Global
    Global  $iPid, $hHwd
#endregion

$iPid = Run('notepad.exe', '', @SW_HIDE)
While 1
    $hHwd = _ProcessGetWindow($iPid, 1)
    If IsHWnd($hHwd) Then ExitLoop
WEnd
ConsoleWrite($hHwd & @CRLF)
;~ MsgBox(0, '', $hHwd)

ControlSetText($hHwd, '', '[CLASS:Edit; INSTANCE:1]', 'Новый текст')
ControlSend($hHwd, '', '[CLASS:Edit; INSTANCE:1]', '^s')
Sleep(500)
WinSetState($hHwd, '', @SW_SHOW)

MsgBox(64, 'Внимание', 'Пока окно было сркыто, ему была высланна строка текста и комбинация Ctrl+S')

ProcessClose($iPid)

Func _ProcessGetWindow($iPID, $iRet=-1)
    Local $aWinList = WinList()
    Local $aRet[2]

    If IsString($iPID) Then $iPID = ProcessExists($iPID)

    For $i = 1 To UBound($aWinList)-1
        If WinGetProcess($aWinList[$i][1]) = $iPID Then
            $aRet[0] = $aWinList[$i][0] ;Title
            $aRet[1] = $aWinList[$i][1] ;WinHandle

            If $iRet = 0 Then Return $aRet[0]
            If $iRet = 1 Then Return $aRet[1]

            Return $aRet
        EndIf
    Next

    Return SetError(1, 0, $aRet)
EndFunc