Код:

$aNetCon = _GetActiveConnectionsArray() ; получение массива всех активных сетевых соединений
; Отключение всех активных сетевых соединений
For $i = 1 To UBound($aNetCon) - 1
	_OnOffConnection($aNetCon[$i], False)
Next

MsgBox(0,"Привет","Интернет выключен, но после закрытия этого сообщения включится!", 4)

For $i = 1 To UBound($aNetCon) - 1
	_OnOffConnection($aNetCon[$i], True)
Next

; Ф-ция получения массива всех активных сетевых соединений
Func _GetActiveConnectionsArray()
	Local $sConnections, $sDelim = "|"
	
	$oNetSharingManager = ObjCreate("HNetCfg.HNetShare.1")
    If Not IsObj($oNetSharingManager) Then
        MsgBox(48, "_GetActiveConnectionsArray: Error", "Can't create HNetCfg.HnetShare.1 object.")
        Exit
    EndIf

    $oConnectionCollection = $oNetSharingManager.EnumEveryConnection
    For $oItem In $oConnectionCollection
        $oNCProps = $oNetSharingManager.NetConnectionProps($oItem)
		If $oNCProps.Status = 2 Then ; соединение в подключенном состоянии
			If $sConnections <> "" Then
				$sConnections = $sConnections & $sDelim & $oNCProps.Name
			Else
				$sConnections = $oNCProps.Name
			EndIf
		EndIf
    Next
	
	Return StringSplit($sConnections, $sDelim, 1)
EndFunc

; Ф-ция включения/отключения сетевых соединений
Func _OnOffConnection($sConnectionName, $bAction)
    Local $cnic = @ScriptDir & "\cnic.exe"
	If $bAction Then
		RunWait($cnic & ' "' & $sConnectionName & '" -c', @ScriptDir, @SW_HIDE) ; включить
	Else
		RunWait($cnic & ' "' & $sConnectionName & '" -d', @ScriptDir, @SW_HIDE) ; отключить
	EndIf
EndFunc