[iglezz]

start /wait в том числе и для таких случаев
другие решения:
команда1 & команда2 & команда3 - последовательное выполнение
команда1 && команда2 && команда3 - выполнение следующей команды в случае успешного завершения предыдущей (определяется по кодам возврата и годится для программ, корректно работающих с ними)

[megaloman]

как сделать в bat файле так, чтобы команда запускалась только после выполнения предыдущей »

О какой предыдущей команде идёт речь?
Вот вариант создания архива на флэшке.

Код:

@Echo Off
cls
	Set "BoxIn=D:\CMD\JS_Host\Дискета_от_книги"

	Set "Arc=C:\Program Files\7-Zip\7zG.exe" 

	Set "Flash="
	FOR /F "usebackq tokens=1 skip=1 delims=:" %%d IN (`"wmic logicaldisk where drivetype="2" get caption | FINDSTR /R /C:"[A-Z]""`) DO Set "Flash=%%d" 
 	If "%Flash%"=="" (Echo Flash Disk not found &Pause &Exit /b 1)

	FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "@Tdate=%%d"

	Set "FileOut=%BoxIn::\=#%"
	Set "FileOut=%FileOut::=%"
	Set "FileOut=%Flash%:\%@Tdate:~0,8%_%FileOut:\=^%"

	"%Arc%" a -r "%FileOut%" "%BoxIn%\"
	shutdown /s /f
Exit /B 0

Можно, конечно, создавать архив где-то на внутреннем диске, а затем переносить на флэшку. Но смысл? Понимаю, если надо не переносить, а копировать архив. В норме команды делаются последовательно, одна после другой

[Iska]

вопрос в том, как сделать в bat файле так, чтобы команда запускалась только после выполнения предыдущей? »

Вопрос в том, как Вы сделали? Нам отсюда Ваш код не виден. Приведите его.

Можно, конечно, создавать архив где-то на внутреннем диске, а затем переносить на флэшку. Но смысл? »

Обычно это выходит намного быстрее.

[Colvor]

Это не готовый код, просто пример.
Вы можете использовать мой скрипт чуток поменяв его, он проверяет работу программы циклически с задержкой и в зависимости от того работает программа или нет уже делает действия.
timeout /t xxx /nobreak можно использовать вместо ping, однако тогда будет спамить "таймером"

Код:

@echo off
title Проверка работы программы

:start_manifest
tasklist|Find /I "7zG.exe" > nul||goto Power_off
ping -n 60 localhost > nul
goto start_manifest

:Power_off
shutdown /s /t 60
exit

[DJ Mogarych]

Powershell v5

Код:

Compress-Archive "путь\к\папке" "путь\к\архиву\на\флешке.zip"
shutdown.exe /s /f /t 00