[Iska]

support23, текущего пользователя или произвольного?

[support23]

текущего пользователя или произвольного? »

произвольного, работающего в домене

[Iska]

Например, так:

Код:

AutoItSetOption("MustDeclareVars", 1)

Local $sComputer         = "."
Local $oSWbemLocator     = ObjCreate("WbemScripting.SWbemLocator")
Local $oSWbemServicesEx  = $oSWbemLocator.ConnectServer($sComputer, "root\cimv2")
Local $oSWbemObjectEx

Local $sDomain   = "domain"
Local $sUserName = "username"

For $oSWbemObjectEx In $oSWbemServicesEx.ExecQuery( _
		"SELECT * FROM Win32_UserAccount WHERE " & _
		"Domain = '" & $sDomain & "' AND " & _
		"Name   = '" & $sUserName & "'" _
	)

	ConsoleWrite($oSWbemObjectEx.SID & @CRLF)
Next

Exit(0)

[glax24]

Или считать из реестра

Код:

$s_Key = 'HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList'
$i = 0
While 1
	$i += 1
	$sSID = RegEnumKey($s_Key, $i)
	If @error <> 0 Then ExitLoop ; no more Keys
	If StringLen($sSID) > 8 Then
		MsgBox(0, "", 'SID = ' & $sSID)
	EndIf
WEnd

[Iska]

Или считать из реестра »

glax24, откуда такая уверенность — что произвольно выбранный пользователь регистрировался на данной машине?

[glax24]

Iska, а как с помощью WMI вы получите SID пользователя не активной ОС, да никак.

что произвольно выбранный пользователь регистрировался на данной машине »

И что значит регистрировался? Был создан но под ним не разу не заходили?

[Iska]

а как с помощью WMI вы получите SID пользователя не активной ОС, да никак. »

Коллега! Я что-то пропустил в вопросе и пояснениях автора темы? Вы сами придумали свой вопрос, сами ответили на него, а теперь пытаетесь его обосновать.

И что значит регистрировался? »

Нажал «Ctrl-Alt-Del», ввёл логин, домен, пароль и нажал «Enter».

Был создан но под ним не разу не заходили? »

На данной машине.

[support23]

Iska, благодарю за помощь! Вопрос закрыт!

[madmasles]

support23,
Штатный вариант.

Код:

#include <Security.au3>

Local $aArrayOfData = _Security__LookupAccountName(@UserName)

; Print returned data if no error occured
If IsArray($aArrayOfData) Then
    ConsoleWrite("SID String = " & $aArrayOfData[0] & @CRLF)
    ConsoleWrite("Domain name = " & $aArrayOfData[1] & @CRLF)
    ConsoleWrite("SID type = " & _Security__SidTypeStr($aArrayOfData[2]) & @CRLF)
EndIf