[Uragan66]

можно батник в exe конвертировать? »

Logonius, можно сразу и скрипт PS компилировать в исполняемый файл, но нужны точные значения переменных $app и $del
Выложите здесь код с Вашими переменными

[Uragan66]

Logonius, пробуйте исп. файл. Рядом нужно положить test.ps1

[Logonius]

Uragan66,

Код:

param(
    $app = 'Spotify',
    $del = 'Data'
)cls

if(ps $app){
    while(ps $app){sleep 1}
    ri "$PSScriptRoot\$del" -rec 
}
else{"$app not launched yet."}

run_proc.zip (201.8 Kb, 0 просмотров) »

архив поврежден, пишет ошибка контрольной суммы

[Uragan66]

архив поврежден, пишет ошибка контрольной суммы »

странно... попробовал скачать - нормально архив открывается. Перекачайте другим браузером...

Вот ещё скомпилированный скрипт PS, без батника.

[Logonius]

Вот ещё скомпилированный скрипт PS, без батника. »

работает, че та делает вроде)), при закрытии проги, потом он следом исчезает и все, а папку не удалил за собой. ЭХ)), 3 дня мучаюсь, вроде задача простая, а так сложно реализовать.

[megaloman]

Код:

NameExe = "notepad.exe"             'Здесь прописать имя процесса
NameDel = "Какая то папка или файл" 'Здесь прописать имя папки или файла
WaitMsec = 5000                     'Здесь прописать периодичность опроса наличия процесса милисек.

Do
    WScript.Sleep WaitMsec
    Set WMI = GetObject("winMgmts:").ExecQuery("SELECT * From Win32_Process WHERE Name='" + NameExe + "'")
    If WMI.Count = 0 Then
        FScript = WScript.ScriptFullName
        With CreateObject("Scripting.FileSystemObject")
            PNameDel = .GetParentFolderName(FScript) + "\" + NameDel
            If .FolderExists(PNameDel) Then .DeleteFolder PNameDel, True
            If .FileExists(PNameDel) Then .DeleteFile PNameDel, True
        End With
        Exit Do
    End If
Loop

Сохранить в кодировке 1251 в .vbs файл, например, kuku.vbs
Запускать как wscript.exe kuku.vbs
Чтобы не грузился зря процессор, периодичность опроса делайте разумной, не слишком маленькой

[Logonius]

megaloman, От души, дружище, работает как надо, благодарю []~(￣▽￣)~*

[megaloman]

Logonius, По видимому, моё решение прямолинейно: Вы сформулировали, как Вы хотите решить задачу, я тупо написал решение. Но, вчитываясь в Ваши посты:

батник будет запускаться после основного файла следом. ........................ работает, а можно батник в exe конвертировать?, будет работать, просто мне надо чтоб он тихо в фоне включался, а так CMD окно вылазит. »

, делаю вывод, что ваша основная программа запускается неким командным файлом. И, чтобы убить папку после её отработки, вовсе не надо дополнительно анализировать, есть она в процессах, или нет. Надо просто дождаться окончания программы стандартным образом, то есть, в CMD запустить ее через Start /Wait (сохранить в 866 кодировке)

Код:

@Echo Off
	Set "NameExe=C:\Windows\System32\notepad.exe" 'Здесь прописать путь к программе
	Set "NameDel=Какая то папка или файл"         'Здесь прописать имя папки или файла

	Start /Wait " " "%NameExe%"
	2>nul Rd /S /Q "%NameDel%" 
	2>nul Del "%NameDel%" 
Exit /B

А чтобы не напрягало CMD-окно, вот VBS вариант (сохранить в 1251 кодировке)

Код:

NameExe = "C:\Windows\System32\notepad.exe" 'Здесь прописать путь к программе
NameDel = "Какая то папка или файл"         'Здесь прописать имя папки или файла

Ret = CreateObject("WScript.Shell").Run(NameExe, 1, True)
        
With CreateObject("Scripting.FileSystemObject")
    PNameDel = .GetParentFolderName(WScript.ScriptFullName) + "\" + NameDel
    If .FolderExists(PNameDel) Then .DeleteFolder PNameDel, True
    If .FileExists(PNameDel) Then .DeleteFile PNameDel, True
End With

[NLOLegion]

А чтобы не напрягало CMD-окно, вот VBS вариант (сохранить в 1251 кодировке) »

вот вроде всё делаю правильно, сохранил скрипт в кодировке ANSI, но ничего не происходит. Блокнот запускается, я жду несколько сек, закрываю блокнот, но файл не удаляется. В чём моя ошибка?

Код:

NameExe = "C:\Windows\System32\notepad.exe" 'Здесь прописать путь к программе
NameDel = "C:\1\scripts\2.txt"         'Здесь прописать имя папки или файла

Ret = CreateObject("WScript.Shell").Run(NameExe, 1, True)
        
With CreateObject("Scripting.FileSystemObject")
    PNameDel = .GetParentFolderName(WScript.ScriptFullName) + "\" + NameDel
    If .FolderExists(PNameDel) Then .DeleteFolder PNameDel, True
    If .FileExists(PNameDel) Then .DeleteFile PNameDel, True
End With

И сразу второй вопрос, что изменить если я хочу не удалить какой-то файл, а запустить после программы какой-нибудь батник?

[megaloman]

удаление папки, там, куда будет помещен батник »

Вы указали полный путь к файлу, скрипт к нему добавил путь к себе, а в результате файл не нашелся. Уберите в коде путь к скрипту, если хотите указывать полный путь к файлу

Код:

PNameDel = .GetParentFolderName(WScript.ScriptFullName) + "\" + NameDel

Не тестировал.

Вот вариант, Если путь указан, берётся указанный, если нет - берётся путь к скрипту

Код:

NameExe = "C:\Windows\System32\notepad.exe"                             'Здесь прописать путь к программе
NameDel = "Z:\Box_In\Длинное имя\Тест1\Тест2\Какая то папка или файл"   'Здесь прописать имя папки или файла

Ret = CreateObject("WScript.Shell").Run(NameExe, 1, True)
        
PNameDel = NameDel
With CreateObject("Scripting.FileSystemObject")
    If InStr(NameDel, "\") <= 0 Then PNameDel = .GetParentFolderName(WScript.ScriptFullName) + "\" + NameDel
    If .FolderExists(PNameDel) Then .DeleteFolder PNameDel, True
    If .FileExists(PNameDel) Then .DeleteFile PNameDel, True
End With

что изменить если я хочу не удалить какой-то файл, а запустить после программы какой-нибудь батник? »

Код:

NameExe = "C:\Windows\System32\notepad.exe"     'Здесь прописать путь к программе
NameBat = "D:\CMD_Forum\Soft_In\мой батник.bat" 'Здесь прописать путь к батнику

With CreateObject("WScript.Shell")
    Ret = .Run(NameExe, 1, True)
    Ret = .Run("cmd /c """ + NameBat + """", 1, False)
End With