CMD/BAT - [решено] Удаление файлов и папок кроме указанных.

megaloman · Отправлено: **15:59, 02-11-2015** | #2

Как понять steam\SteamApps\common\"dota 2 beta" ???

Я не искал ошибку в Вашем коде. У меня получилось нечто такое (в меру моего понимания возможного имени папки которую обрабатываем):

Цитата:

кладу батник рядом с папкой

которую надо чистить и запускаю батник

Код:

@Echo Off 

SetLocal EnableExtensions EnableDelayedExpansion

set "sTargetFolder=Где чистим\Подпапка"
set sExcludeFilesOrFolders="_CommonRedist" "EmptySteamDepot" "game" "Нужный файл 1" "Нужный файл 2.txt"


FOR /F "usebackq delims=" %%i IN (`dir "%sTargetFolder%\" /b /A:D 2^>nul`) DO (
	Set /A Log=0
	FOR %%j IN (%sExcludeFilesOrFolders%) DO If "%%i"==%%j Set /A Log=1
	If !Log!==0 Rd /s /q "%sTargetFolder%\%%i"
)

FOR /F "usebackq delims=" %%i IN (`dir "%sTargetFolder%\" /b /A:-D 2^>nul`) DO (
	Set /A Log=0
	FOR %%j IN (%sExcludeFilesOrFolders%) DO If "%%i"==%%j Set /A Log=1
	If !Log!==0 Del "%sTargetFolder%\%%i"
)

Батник написан в 866 кодировке (Dos). Идея та же что и у Вас

Чуть короче, но , скорее всего, медленнее в работе

Код:

@Echo Off

SetLocal EnableExtensions EnableDelayedExpansion

set "sTargetFolder=Где чистим\Подпапка"
set sExcludeFilesOrFolders="_CommonRedist" "EmptySteamDepot" "game" "Нужный файл 1" "Нужный файл 2.txt"


FOR /F "usebackq delims=" %%i IN (`dir "%sTargetFolder%\" /b 2^>nul`) DO (
	Set /A Log=0
	FOR %%j IN (%sExcludeFilesOrFolders%) DO If "%%i"==%%j Set /A Log=1
	If !Log!==0 (
		Rd /s /q "%sTargetFolder%\%%i" 2>nul || Del /q "%sTargetFolder%\%%i" 2>nul
	)
)

mrG0bliN · Отправлено: **18:29, 02-11-2015** | #3

Цитата megaloman:

Как понять steam\SteamApps\common\"dota 2 beta" ??? »

отличное замечание, но толко я все равно не могу понять когда нужны ковычки а когда нет
вычитал что cmd не видит пути с пробелами и ковычки помогают там где в названии папки "дырки"

нашел почему именно некоторые файлы не удаляются, там присутствует такой значек:
—
пример: vcredist_x86 — копия.exe
как сделать так или добавить его в правило что бы такие файлы тоже удалялись?!

Iska · Отправлено: **19:25, 02-11-2015** | #4

Цитата mrG0bliN:

но толко я все равно не могу понять когда нужны ковычки а когда нет »

Нужны, когда в пути есть/могут быть пробельные символы (это не только сам пробел, но и другие). Лучше всего использовать всегда. Только лучше обрамлять весь путь целиком.

Цитата mrG0bliN:

как сделать так или добавить его в правило что бы такие файлы тоже удалялись?! »

Перейти на WSH/PoSH. А может вот как раз тут и понадобится «chcp 1251».

mrG0bliN · Отправлено: **19:50, 02-11-2015** | #5

Цитата Iska:

А может вот как раз тут и понадобится «chcp 1251». »

супер просто супер все удалилось ))

впринципе для роботоспособности сойдет, а ништяки такие можно ли как нить реализовать?
что бы вначале было 3 пункта на выбор, например:
1.вариант а
2. вариант б
3. выход

и по нажатию цифр на клаве выбирался метод

Iska · Отправлено: **20:19, 02-11-2015** | #6

Легко

:

Код:

@echo off

echo 1. вариант а
echo 2. вариант б
echo 3. выход
echo.
choice.exe /c 123 /m "Enter your choice:"
call :Choice%ErrorLevel%
exit /b 0

rem Variant A
:Choice1
echo Variant A
exit /b 0

rem Variant B
:Choice2
echo Variant B
exit /b 0

rem Exit
:Choice3
exit /b 0

rem Ctrl-C
:Choice0
rem Error
:Choice255

rem Nothing to do
exit /b 0

mrG0bliN · Отправлено: **21:58, 02-11-2015** | #7

не закрывайте пока тему, все супер осталось переписать под себя и протестировать

mrG0bliN · Отправлено: **22:34, 03-11-2015** | #8

Цитата Iska:

m "Enter your choice:" »

а как получить выбор информации в столбик? в одну строку не оч

Iska · Отправлено: **23:40, 03-11-2015** | #9

Цитата mrG0bliN:

а как получить выбор информации в столбик? в одну строку не оч »

Не пойму Вашего вопроса про столбик. Покажите/нарисуйте хотелку.

mrG0bliN · Отправлено: **00:24, 04-11-2015** | #10

Цитата Iska:

Покажите/нарисуйте хотелку. »