[viliam]

Кажись, работает так:

Код:

Dim WINDIR, WshShell, objFSO
Set WshShell = CreateObject("Wscript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")
WINDIR = WshShell.ExpandEnvironmentStrings("%WINDIR%/system32")
Set obj = CreateObject("Scripting.FileSystemObject")
if obj.FileExists (WINDIR & "\file.txt") then objFSO.DeleteFile(WINDIR & "\file.txt")

[Iska]

Надо проверить папку system32 на наличие файла file.txt, и удалить его если он там есть. »

Код:

Option Explicit

Const SystemFolder = 1

Dim strPath


With WScript.CreateObject("Scripting.FileSystemObject")
	strPath = .BuildPath(.GetSpecialFolder(SystemFolder).Path, "file.txt")
	
	If .FileExists(strPath) Then
		.DeleteFile strPath, True
	End If
End With

WScript.Quit 0

Знаю что надо использовать метод ExpandEnvironmentStrings, но как не знаю. »

Код:

Option Explicit

Dim strPath


With WScript.CreateObject("Scripting.FileSystemObject")
	strPath = WScript.CreateObject("WScript.Shell").ExpandEnvironmentStrings("%SystemRoot%\System32\file.txt")
	
	If .FileExists(strPath) Then
		.DeleteFile strPath, True
	End If
End With

WScript.Quit 0

Но правильнее — использовать первый код.

[viliam]

Спасибо. А как перед этим убить процесс notepad.exe?
Вот этот скрипт убивает:

Код:

strComputer = "."
strProcsToKill = "notepad.exe"
Set wbemObjectSet = GetObject("winmgmts://" & strComputer).InstancesOf("Win32_Process")
For Each wbemObject In wbemObjectSet
 If LCase(wbemObject.Name) = strProcsToKill Then wbemObject.Terminate
Next

но не знаю как объединить его с этим:

Код:

Option Explicit

Const SystemFolder = 1

Dim strPath


With WScript.CreateObject("Scripting.FileSystemObject")
	strPath = .BuildPath(.GetSpecialFolder(SystemFolder).Path, "file.txt")
	
	If .FileExists(strPath) Then
		.DeleteFile strPath, True
	End If
End With

WScript.Quit 0

[Iska]

Например, так:

Код:

Option Explicit

Const SystemFolder = 1

Dim objSWbemObjectEx
Dim strPath


For Each objSWbemObjectEx In WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2").ExecQuery("SELECT * FROM Win32_Process WHERE Name='notepad.exe'")
	objSWbemObjectEx.Terminate
Next

With WScript.CreateObject("Scripting.FileSystemObject")
	strPath = .BuildPath(.GetSpecialFolder(SystemFolder).Path, "file.txt")
	
	If .FileExists(strPath) Then
		.DeleteFile strPath, True
	End If
End With

WScript.Quit 0

[viliam]

Все работает идеально. Благодарю.

[mwz]

Ну и вдогонку:

%windows% »

Нет такой переменной среды. Есть %windir%.