Любой язык

Iska · Отправлено: **00:25, 10-03-2014** | #2

Цитата Димончик555:

Хочу ввести имя .asm файла находящегося в одной папке с батником в переменную. »

Первого из найденных «*.asm»:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`dir /b /a:-d "%~dp0*.asm" 2^>nul`
) do if not defined sFirstAsmFile set sFirstAsmFile=%%~nxi

if defined sFirstAsmFile (
	echo First *.asm file: [%sFirstAsmFile%].
) else (
	echo Not found any *.asm files.
)

endlocal
exit /b 0

P.S. Выберете какой-нибудь нормальный хостинг изображений, либо научитесь корректно выбирать и вставлять правильные ссылки. На приведённом изображении трудно разобрать что-либо осмысленное.

Димончик555 · Отправлено: **00:57, 10-03-2014** | #3

Спасибо!!!

Димончик555 · Отправлено: **01:29, 10-03-2014** | #4

Можете ли обьяснить, как этот код работает? Как- бы целые фразы
setlocal enableextensions enabledelayedexpansion
do if not defined sFirstAsmFile set sFirstAsmFile=%%~nxi

Неужели это действующие части кода?

Iska · Отправлено: **02:09, 10-03-2014** | #5

Цитата Димончик555:

Как- бы целые фразы
setlocal enableextensions enabledelayedexpansion »

Код:

setlocal /?

Цитата Димончик555:

do if not defined sFirstAsmFile set sFirstAsmFile=%%~nxi »

Здесь три конструкции — «for /f», «if», «set» и вложенная команда:

Код:

for /f "usebackq delims=" %%i in (
	`dir /b /a:-d "%~dp0*.asm" 2^>nul`
) do if not defined sFirstAsmFile set sFirstAsmFile=%%~nxi

Суть такова: получив stdout команды «dir», разобрать его построчно. Для каждой строки проверяется условие — не определена ли переменная окружения «sFirstAsmFile»? На первом проходе разбора она ещё не определена, поэтому будет исполнена конструкция «set sFirstAsmFile=%%~nxi», которая присвоит переменной окружения «sFirstAsmFile» содержимое первой строки из stdout команды «dir». На втором и последующем проходах разбора условие не будет истинным, поскольку переменная окружения «sFirstAsmFile» была определена на первом проходе разбора («set sFirstAsmFile=…»), посему команда присвоения на этих проходах больше не исполнится. В результате мы получим на выходе «for /f …» содержимое первой строки из stdout команды «dir».

Для чистоты также можно на всякий случай очищать переменную окружения «sFirstAsmFile» перед циклом разбора «for /f»:

Код:

set sFirstAsmFile=

for /f "usebackq delims=" %%i in ( …

— на тот случай, если Вы, например, не пользуете «setlocal» в своих пакетных файлах, или переменная «sFirstAsmFile» может вдруг достаться «по наследству» в унаследованном пакетным файлом окружении.

А что будет, если в каталоге не окажется вовсе ни одного файла «*.asm»? В данном примере сие решается следующим образом — stderr команды «dir» перенаправляется в пустое устройство, а stdout окажется в данном случае пуст. Поэтому переменная окружения «sFirstAsmFile» попросту окажется не определена. И нам остаётся только проверить этот факт аналогичным условием «if defined sFirstAsmFile …».

Димончик555 · Отправлено: **11:08, 10-03-2014** | #6

СПАСИБО!!!!

Димончик555 · Отправлено: **19:36, 10-03-2014** | #7

Спасибо огромное!! Действительно, понятно!!