CMD/BAT - [решено] Как вывести список установленных программ

Iska · Отправлено: **01:27, 23-02-2014** | #2

Цитата Valek271183:

Как можно с помощью CMD »

А другие варианты устроят?

Valek271183 · Конфигурация компьютера

хотелось бы конечно через CMD, потому что будет частью другого файла, это возможно?

Iska · Отправлено: **02:28, 23-02-2014** | #4

Только отчасти:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

>nul chcp 1251

for /f "usebackq delims=" %%i in (
	`reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"`
) do for /f "usebackq tokens=3*" %%j in (
		`reg.exe query "%%~i" /v "DisplayName" 2^>nul ^| find.exe /i "DisplayName"`
	) do echo %%~j %%k

>nul chcp 866

endlocal
exit /b 0

Valek271183 · Конфигурация компьютера

Iska, подскажите, можно ли очистить получившийся список с программами от определённых строк, например после запуска вышеуказанной команды на рабочем столе создаётся список установленных программ и некоторые из них повторяются, например очень много сток с : Microsoft Visual C++ 2010 такой-то, Microsoft Visual C++ 2012 такой-то, нельзяли удалить строки начинающиеся с Microsoft Visual C++ ?

Iska · Отправлено: **16:07, 28-02-2014** | #6

Цитата Valek271183:

и некоторые из них повторяются, например очень много сток с : Microsoft Visual C++ 2010 такой-то, Microsoft Visual C++ 2012 такой-то »

Покажите в виде текста.

Цитата Valek271183:

нельзяли удалить строки начинающиеся с Microsoft Visual C++ ? »

Зачем?

Valek271183 · Конфигурация компьютера

Примерно так

Iska · Отправлено: **16:50, 28-02-2014** | #8

Убрать «заглушки» (Система - [addon] Microsoft Visual C++ 05-08-10-12-13 Redistributable Package x86 & x64)? Попробуйте так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

>nul chcp 1251

for /f "usebackq delims=" %%i in (
	`reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"`
) do for /f "usebackq tokens=3*" %%j in (
		`reg.exe query "%%~i" /v "DisplayName" 2^>nul ^| find.exe /i "DisplayName"`
	) do echo %%~j %%k|findstr.exe /i /v /r /c:"^Microsoft Visual C++ .* False$"

>nul chcp 866

endlocal
exit /b 0

Valek271183 · Конфигурация компьютера

не получается сохранить на рабочем столе, в конце я писал
) do echo %%~j %%k >> "%userprofile%\Desktop\Список программ.txt"
как правильно добавить сюда |findstr.exe /i /v /r /c:"^Microsoft Visual C++ .* False$" ?

Iska · Отправлено: **16:23, 01-03-2014** | #10

Попробуйте так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

>"%UserProfile%\Desktop\Список программ.txt" (
	>nul chcp 1251
	
	for /f "usebackq delims=" %%i in (
		`reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"`
	) do for /f "usebackq tokens=3*" %%j in (
			`reg.exe query "%%~i" /v "DisplayName" 2^>nul ^| find.exe /i "DisplayName"`
		) do echo %%~j %%k|findstr.exe /i /v /r /c:"^Microsoft Visual C++ .* False$"
	
	>nul chcp 866
)

endlocal
exit /b 0