CMD/BAT - [решено] можно ли батником разрезать файл по шаблону?

Iska · Отправлено: **19:40, 27-09-2013** | #2

Код:

Option Explicit

Dim strSourceFile

Dim objFSO
Dim strContent

Dim objRegExp
Dim objMatch

Dim strNewFileName

If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FileExists(strSourceFile) Then
			With .OpenTextFile(strSourceFile)
				strContent = .ReadAll()
				.Close
			End With
			
			Set objRegExp = WScript.CreateObject("VBScript.RegExp")
			
			With objRegExp
				.Pattern = "<html>[\s\S]*?<title>([\s\S]*?)</title>[\s\S]*?</html>"
				.Global = True
			End With
			
			If objRegExp.Test(strContent) Then
				For Each objMatch In objRegExp.Execute(strContent)
					strNewFileName = .BuildPath(.GetParentFolderName(strSourceFile), objMatch.SubMatches(0) & ".htm")
					WScript.Echo "Create file [" & strNewFileName & "]."
					
					With .CreateTextFile(strNewFileName)
						.WriteLine objMatch.Value
						.Close
					End With
				Next
			Else
				WScript.Echo "No matches"
			End If
		Else
			WScript.Echo "Source file [" & strSourceFile & "] not found."
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source file>"
End If

WScript.Quit 0

Сохраните код в файл с расширением «.vbs», затем просто перетащите на него Ваш «один текстовый файл (file.txt)».

P.S. Никаких проверок на содержимое внутри тэга «title» не делается. Посему, ежели там окажется какой-либо запрещённый в именах файлов символ, например «:», скрипт завершится с ошибкой.

ruslaw · Отправлено: **21:37, 27-09-2013** | #3

Фантастика!
Огромнейшее спасибо, работает!

Pet20211029 · Отправлено: **12:05, 29-10-2021** | #4

Здравствуйте,.
Как прочитать текстовый файл (file.txt) из скрипта, не перетаскивая его

alpap · Конфигурация компьютера

Цитата Pet20211029:

не перетаскивая его »

а к чему его перетаскивать, в рамках задачи:

Код:

more file.txt

что еще надо?

Pet20211029 · Отправлено: **14:17, 29-10-2021** | #6

Писал про скрипт выше, от Iska.
Он пишет:
Сохраните код в файл с расширением «.vbs», затем просто перетащите на него Ваш «один текстовый файл (file.txt)».
Как его модифицировать?

Fors1k · Отправлено: **15:02, 29-10-2021** | #7

Код:

cls
$pathIn  = "D:\file.txt"
$pathOut = "D:\htmlDocs"

[Regex]::Matches((gc $pathIn -Raw), "<html>.*?</html>", 0x10).Value|ForEach{$i=1}{
    $_|Out-File "$pathOut\$i.htm";$i++
}

Pet20211029 · Отправлено: **15:23, 29-10-2021** | #8

Выдает ошибку Недопустимый знак " Строка 4"

alpap · Конфигурация компьютера

Pet20211029, это код для PowerShell, если что.

Pet20211029 · Отправлено: **15:33, 29-10-2021** | #10

Спасибо, все же надо в vbs