[Major_XXXX]

не стартует exe. пишет ошибку что ему не хватает ini файла. хотя он есть, и при запуске не через этот батник, прекрасно стартует

[Iska]

Major_XXXX, скорее всего, приложение так криво написано, что ему критичен текущий каталог при запуске.

Два варианта:

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sFileName=procexp.exe
set sLocalPath=%ProgramFiles%\Sysinternals.com\Sysinternals Suite
set sRemotePath=\\live.sysinternals.com\tools

if exist "%sLocalPath%\%sFileName%" (
	if exist "%sRemotePath%\%sFileName%" (
		1>nul 2>&1 fc.exe /b "%sLocalPath%\%sFileName%" "%sRemotePath%\%sFileName%" || (
			xcopy.exe /e /f /h /r /k /y /z "%sRemotePath%\*.*" "%sLocalPath%\*.*"
		)
	) else (
		echo Can't find remote file [%sRemotePath%\%sFileName%].
	)
	
	pushd ""%sLocalPath%"
	"%sLocalPath%\%sFileName%"
	popd
) else (
	echo Can't find local file [%sLocalPath%\%sFileName%].
)

endlocal
exit /b 0

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sFileName=procexp.exe
set sLocalPath=%ProgramFiles%\Sysinternals.com\Sysinternals Suite
set sRemotePath=\\live.sysinternals.com\tools

if exist "%sLocalPath%\%sFileName%" (
	if exist "%sRemotePath%\%sFileName%" (
		1>nul 2>&1 fc.exe /b "%sLocalPath%\%sFileName%" "%sRemotePath%\%sFileName%" || (
			xcopy.exe /e /f /h /r /k /y /z "%sRemotePath%\*.*" "%sLocalPath%\*.*"
		)
	) else (
		echo Can't find remote file [%sRemotePath%\%sFileName%].
	)
	
	start "" /d"%sLocalPath%" "%sLocalPath%\%sFileName%"
) else (
	echo Can't find local file [%sLocalPath%\%sFileName%].
)

endlocal
exit /b 0

Иначе, пишите как именно:

не через этот батник, прекрасно стартует »

сие осуществляете.

[Major_XXXX]

Огромное Вам спасибо!!! Второй вариант запустил и сделал всё что было необходимо!

[Iska]

Major_XXXX, а первый вариант пробовали?

[Major_XXXX]

я если честно, начал со второго. сейчас попробовал и первый. тоже работает. а в чем отличие?)

[Iska]

а в чем отличие?) »

В использованных командах. Они выделены цветом в приведённом выше коде.