CMD/BAT

Iska · Отправлено: **12:11, 28-01-2013** | #2

Цитата deniskx:

неизменно (примерно 451 символ, или 9 строка, с 25 символа). »

Определитесь. Машине не скажешь «примерно». Нужны отличительные признаки, позволяющие однозначно определять искомое.

deniskx · Отправлено: **16:20, 28-01-2013** | #3

Давайте будем считать положение неизменным. Длина UID 32 символа.
То есть 451-483 > 196-228
Я правда не знаю как учитываются переносы строк. Если учитывать строки, то:
player.htm 9 строка 25-57 символы > playlist.m3u 4 строка 62-94 символы.

deniskx · Отправлено: **09:07, 30-01-2013** | #4

Что никто не знает?

Anonymоus · Отправлено: **11:23, 30-01-2013** | #5

Для работы скрипта нужен wget и grep. Умеет как добавлять строку с радио в m3u-плейлист, так и заменять UID в уже существующей. Не забудьте поменять имя плейлиста на ваше, и, если в плейлисте используется юникод - сохранить скрипт в UTF-8 без BOM.

Код:

@Echo Off
SetLocal EnableDelayedExpansion
Set Playlist=playlist.m3u

:: Получаем страницу и вытягиваем UID
For /F "tokens=2 delims='" %%A In ('bin\wget "http://www.radiodacha.ru/player.htm" -O-^|bin\grep -Eo "uid: '[0-9A-Z]{32}'"') Do (Set UID=%%A)

:: Вписываем требуемое значение в m3u-плейлист
Find "radiodacha.ru" "%Playlist%">nul&&(
	rem Если станция найдена - заменяем значение UID
	For /F "usebackq eol= delims=" %%A In ("%Playlist%") Do (
		Set Data=%%A
		If Not "!Data:~,25!"=="http://stream2.radiodacha" (
			Echo %%A>>"%Playlist%.tmp"
		) Else (
			Echo http://stream2.radiodacha.ru:9000/radiodacha_64?type=.mp3^&UID=%UID%>>"%Playlist%.tmp"
		)
	)
	Del "%Playlist%" && Move "%Playlist%.tmp" "%Playlist%"
)||(
	rem Если станции до этого не было в плейлисте, просто добавляем её в конец
	Echo #EXTINF:-1,RadioDacha>>"%Playlist%"
	Echo http://stream2.radiodacha.ru:9000/radiodacha_64?type=.mp3^&UID=%UID%>>"%Playlist%"
)
Exit

Архив со скриптом, тестовым плейлистом и необходимыми утилитами: http://rghost.ru/43413044

deniskx · Отправлено: **17:07, 30-01-2013** | #6

Спасибо. Все отлично работает. На всякий случай перезалил на постоянное хранение в яндекс диск. Вдруг кому еще пригодится.

evggrig · Отправлено: **22:22, 20-12-2017** | #7

всем привет. а эта фишка сейчас работает? UID с радио дача и прочих подобных станций не выдергивается. подскажите как пофиксить?