[gora]

Код:

@Echo Off
Set txtfile=e:\Temp\bigtxt.txt

(Echo Создаем большой текст
Echo Весь текст в батнике
Echo Здесь очень много строк
Echo Но спец. символов здесь нет
Echo Иначе их придется экранировать
Echo А это сложно... :^)
Echo Три пустые строки
Echo.
Echo.
Echo.
Echo Последняя строка
)>"%txtfile%"

[Андрей_Угаров@vk]

Супер! Спасибо!)

[Iska]

Или так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sFile=BigText.txt
more +10 "%~0">"%sFile%"

endlocal
exit /b 0


Создаем большой текст
Весь текст в батнике
Здесь очень много строк
Так можно и спецсимволы :^)
`~!@#$%^&*()_+|\/.,;:'"
Три пустые строки



Последняя строка

[mactepcepbep@vk]

подскажите, последний скрипт идеально работает в локальной папке, но я никак не могу заставить его писать в файлы в директории выше, все значки cd ../ работают а вот set sFile ../12345/123.txt уже не работает. мне нужен только относительный путь касательно запускаемого бантика. заранее спасибо.

[Foreigner]

mactepcepbep@vk,

Тебе не надо "cd ..\"

Код:

set "sFile=%~dp0..\12345\123.txt"

[mactepcepbep@vk]

thanks, the script works well.

[V!RTuE]

Код: @echo off setlocal enableextensions enabledelayedexpansion set sFile=BigText.txt more +10 "%~0">"%sFile%" endlocal exit /b 0 Создаем большой текст Весь текст в батнике Здесь очень много строк Так можно и спецсимволы :^) `~!@#$%^&*()_+|\/.,;:'" Три пустые строки Последняя строка »

Возможно ли сделать так, чтобы после этого кода можно было написать другой еще? Просто есть код, который обязательно должен быть в конце.
После more можно ли указать точное количество строк, которое надо скопировать? или такого функционала нет?

[megaloman]

такого функционала нет »

Можно написать с заменой More на вывод Echo в цикле, тогда возможны проблемы со спецсимволами. У Вас что в тексте?

Просто есть код, который обязательно должен быть в конце. »

Почему, что, его нельзя оформить процедурой и вставить перед выводимым текстом? Как пример:

Код:

@Echo Off
cls
	Set "FileOut=Z:\Box_In\BigText.txt"

	Set /A N=10000000
	FOR /F "usebackq tokens=1 delims=[]" %%i In (`Find /N ":My_Out_Text" "%~dpnx0"`) DO Set /A N=%%i
	>"%FileOut%" more +%N% "%~dpnx0"
Echo 1. Тут можно продолжать писать код
	Call :MyCode
Echo 2. Тут можно продолжать писать код
pause
Exit /b 0

:MyCode
	Echo  Просто есть код, который НЕ обязательно должен быть в конце.
Exit /B

:My_Out_Text
Создаем большой текст
Весь текст в батнике
Здесь очень много строк
Так можно и спецсимволы :^)
`~!@#$%^&*()_+|\/.,;:'"
Три пустые строки
Последняя строка

[V!RTuE]

Можно написать с заменой More на вывод Echo в цикле, тогда возможны проблемы со спецсимволами. У Вас что в тексте? »

Спецсимволов полно. Текст более 200 строк. Содержимое файла openssl-1.0.0.cnf (программы OpenVPN)

Почему, что, его нельзя оформить процедурой и вставить перед выводимым текстом? »

Нельзя, так как используется этот код . Там обязательное условие, что он должен быть в конце.
В принципе уже задачу решил, но не копируются пустые строки (в данном случае абсолютно не критично), но для красоты хотелось бы. Да и просто на будущее знать как можно реализовать подобную задачу.
Вот рабочий код. Реализовано через поиск начальной и конечной строки

Код:

...
:Createopensslcnf
:: Обязательно должно быть в начале батника или здесь @echo off, иначе некорректно экспортируется текст
:: Допустимо в начале указать @echo on, а в этой части @echo off
@echo off
    Set "FileIn=%~0"
    Set "Key1=# For use with easy-rsa version 2.0 and OpenSSL 1.0.0*"
    Set "Key2=init = 0"
 
    FOR /F "usebackq skip=2 tokens=1 delims=[]" %%i In (`Find /N /I "%Key1%" "%FileIn%"`) DO Set /A N=%%i-1
 
    >"%KEY_CONFIG%" (FOR /F "usebackq delims=" %%i In (`More +%N% "%FileIn%"`) DO (
        Echo %%i|Find /I /V "%Key2%"||(<nul Set /P Str=%%i&Exit /B 0)
    ))
GoTo :EOF

# For use with easy-rsa version 2.0 and OpenSSL 1.0.0*
...
...
init = 0

:: ----------------------------------------
...

P.S.: это часть моего проекта по автоматизации работы с OpenVPN на Windows. Подобных решений нигде не встречал еще

Скрытый текст