Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  | Правила  

Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка Windows 10 / 8 / 7 / Vista » 8 / 2012 - Создание мультиязычного установочного диска Windows 8.1 Update x86 и x64

Ответить
Настройки темы
8 / 2012 - Создание мультиязычного установочного диска Windows 8.1 Update x86 и x64

Аватара для alegz81

Старожил


Сообщения: 167
Благодарности: 47


Конфигурация

Профиль | Отправить PM | Цитировать


Изменения
Автор: alegz81
Дата: 26-06-2014
Описание: Статья обновлена до актуального состояния
Создание установочного диска Windows 8.1 Update EN RU TR x86 и x64

В общем работа с windows 8 практически не отличается от windows 7.
Так что подробно будет описано только то, что относится к windows 8.
Если же вы в первые решили создать сборку или что-то не понятно, то прочитайте статью
Создание мультиязычного установочного диска Windows 7 SP1 x86 и x64

ВНИМАНИЕ. Если вы работаете в 64-х битной системе, то создать файл каталога (.clg) для Windows x86 у вас не получится. (инфо)

Подготовка

Вот то что мне понадобилось для работы:
1. Комплект средств для развертывания и оценки Windows (ADK) для Windows 8.1 Update скачать
2. Оригинальный установочный диск Windows 8.1 Update EN x86 или Windows 8.1 Update EN x64.
3. Языковые пакеты для Windows 8.1, отдельных пакетов для Windows 8.1 Update нет (я собираю диск с тремя языками – английский, русский и турецкий. Соответственно я использовал русский и турецкий пакеты. ВНИМАНИЕ пакеты для х86 и х64 разные). Для OEM-ов Microsoft предоставила обновления для языковых пакетов. Обычным пользователям оно не доступно, но кто ищет тот найдет.
4. VMware Workstation 10.0.1 или VirtualBox 4.3.12.
5. Эмулятор CD-DVD (Alcohol 120%). Если работаете в Windows 8.x, то не нужен.
6. Редактор SciTE или FAR 2.0
7. Обновления для Windows 8.1 Update. Можно взять здесь, или с помощью этой программы.

Для установки ADK нужно скачать файл adksetup.exe, который является веб-установщиком.
При установке есть два варианта:
1 Установка нужных компонентов на компьютер.
2 Скачивание всего пакета для последующей off-line установки.
Первый способ самый быстрый и экономичный в плане интернет-трафика - будет скачано только то что нужно.
При втором будет скачан весь пакет со всеми дополнительными зависимостями , но потом можно ставить уже без интернета.
Из всего ADK нужно установить только "Средства развертывания" и "Среда предустановки Windows (Windows PE)"

Я буду показывать все действия на примере Windows 8.1 Update Ent x64, но все это так же работает и на других редакциях Windows 8.1 Update.

Теперь надо создать структуру папок для работы.
Вот текст батника который это делает:
Код: Выделить весь код
@echo off
:Start
ECHO.
ECHO Этот командный файл создает структуру папок для
ECHO работы над автоматической установкой Windows 8.1 Update
ECHO.
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL
:CreateFolders
CLS
ECHO.
ECHO Создание папок . . .
SET work=%CD%\window8.1updEntx64
IF NOT EXIST %work%\NUL MKDIR %work%
IF NOT EXIST %work%\DVD\NUL MKDIR %work%\DVD
IF NOT EXIST %work%\ISO\NUL MKDIR %work%\ISO
IF NOT EXIST %work%\Logs\NUL MKDIR %work%\Logs
IF NOT EXIST %work%\Mount\NUL MKDIR %work%\Mount
IF NOT EXIST %work%\wim\NUL MKDIR %work%\wim
IF NOT EXIST %work%\Sandbox\NUL MKDIR %work%\Sandbox
IF NOT EXIST %work%\Updates\NUL MKDIR %work%\Updates
IF NOT EXIST %work%\xml\NUL MKDIR %work%\xml
IF NOT EXIST %work%\bootwim\NUL MKDIR %work%\bootwim
IF NOT EXIST %work%\bootwim\lp\NUL MKDIR %work%\bootwim\lp
IF NOT EXIST %work%\bootwim\mount\NUL MKDIR %work%\bootwim\mount
IF NOT EXIST %work%\winREwim\NUL MKDIR %work%\winREwim
IF NOT EXIST %work%\winREwim\mount\NUL MKDIR %work%\winREwim\mount
IF NOT EXIST %work%\mui\NUL MKDIR %work%\mui
IF NOT EXIST %work%\mui\upd\NUL MKDIR %work%\mui\upd
ECHO.
ECHO Процесс создания структуры папок завершен!
pause
exit
Сохраните его в файл с названием Windows8.1updEntx64.cmd в DOS(OEM866) кодировке. Это можно сделать с помощью FARа или SciTE. Скопируйте файл в то место где вы хотите создать папки и запустите (у меня С:\win). А для windows x86 сохраните в файл с названием Windows8.1updEntx86.cmd, и измените строчку «SET work=%CD%\window8.1updEntx64» на «SET work=%CD%\window8.1updEntx86».

Копирую языковые пакеты для Windows 8.1 x64 ( у меня папки ru-ru и tr-tr в которых находятся lp.cab) в С:\win\window8Entx64\mui. Обновления для языковых пакетов в С:\win\window8Entx64\mui\upd (папки ru-ru и tr-tr в которых находятся Windows8.1-KB2938307-x64.msu и Windows8.1-KB2938315-x64.msu соответственно).
Копирую языковые пакеты для Win PE x64 из C:\Program Files\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\amd64\WinPE_OCs (для х86 C:\Program Files\Windows Kits\8.1\Assessment and Deployment Kit\Windows Preinstallation Environment\x86\WinPE_OCs) в С:\win\window8Entx64\bootwim\lp. Я уже давно делаю сборки на виртуальной машине, на данный момент это Windows 8.1 Update x86 в которой стоит только необходимый софт. Во первых нет ни каких конфликтов с другими программами, которые обязательно вылезли бы на рабочей системе. Во вторых можно собирать все разрядности (архитектура x86, x64, Windows(R) RT ARM) без всяких проблем.
Копирую весь установочный диск windows 8.1 Update Ent x64 в папку С:\win\window8.1updEntx64\DVD.
Обновления, если они есть, копирую в С:\win\window8.1updEntx64\Updates в соответствии с рекомендациями по интеграции.
Пути подставите свои.
С подготовкой закончено.

Изменение boot.wim, WinRE.wim и install.wim

Теперь можно установить нужные языки в дистрибутив.
Для этого я подготовил батник Win8.1Build.cmd.
Он хорошо прокомментирован, так что думаю будет всем понятен.
Для временных файлов используется %wd%\Sandbox\.
Все логи записываются в %wd%\Logs\.
Перед каждым отключением образа, делается пауза.
Так что можно внести еще свои изменения в подключенный образ.
В батнике надо изменить параметр wd указывающий на папку с рабочим окружением -> set wd=C:\win\window8.1updEntx64
Перед изменением install.wim, батник покажет информацию об имеющихся в нем образах и их индексах и попросит указать нужный.
Так же можно указать индекс нужного образа в install.wim, если точно знаете какая редакция Windows 8.1 Update нужна.
Для этого надо раскомментировать (стр. 12)
Код: Выделить весь код
rem индекс нужного образа в install.wim
rem set indx=1
что бы было вот так
Код: Выделить весь код
rem индекс нужного образа в install.wim
set indx=1
и закомментировать запрос нужного индекса (стр. 116)
Код: Выделить весь код
set /P indx="Укажите индекс нужного образа -> "
что бы было вот так
Код: Выделить весь код
rem set /P indx="Укажите индекс нужного образа -> "
Если у вас нет обновлений для языковых пакетов, то не страшно. Все необходимое скачается через Windows Update.
Команды для установки этих обновлений в скрипте есть (строки 135-137 и 184-186), но они закомментированы.
Код: Выделить весь код
rem ECHO .
rem ECHO Установка обновлений для языковых пакетов Install.wim
rem Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\mui\upd\ru-ru\Windows8.1-KB2938307-x64.msu /PackagePath:%wd%\mui\upd\tr-tr\Windows8.1-KB2938315-x64.msu
                 и
rem ECHO .
rem ECHO Установка обновлений для языковых пакетов Winre.wim
rem Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Add-Package /PackagePath:%wd%\mui\upd\ru-ru\Windows8.1-KB2938307-x64.msu /PackagePath:%wd%\mui\upd\tr-tr\Windows8.1-KB2938315-x64.msu
Ну а если эти пакеты у вас есть, то раскомментируйте эти строки и измените под себя.
Для x86 свои файлы, название отличается только указанием архитектуры - Windows8.1-KB2938307-x86.msu - для русского языкового пакета.

Для нормальной работы многих программ нужен .Net Framework 2 или 3, которые по умолчанию не установлены в Windows 8.1 Update и доступны в виде компонента.
По этому включаем этот компонент в дистрибутиве, что бы в установленной системе он уже был.
ВНИМАНИЕ. Первым всегда надо включать компонент .Net Framework, а потом интегрировать языковые пакеты. Иначе будут проблемы.
К другим компонентам это не относится.
(инфо)

Команда для интеграции обновлений так же закомментирована (стр. 147-149)
Предполагается что все обновления находятся в одной папке Updates.
Код: Выделить весь код
rem ECHO .
rem ECHO Установка обновлений
rem Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\Updates
Win8.1Build.cmd надо сохранить в DOS(OEM866) кодировке.
Открыть от имени Администратора "Среда средств развертывания и работы с образами" и запустить батник из нее.
Код: Выделить весь код
С:\win\Win8.1Build.cmd
Win8.1Build.cmd

Код: Выделить весь код
@Echo off
::Alegz81 2014

ECHO Этот командный файл интегрирует языковые пакеты и обновления в дистрибутив Windows 8.1 Update
ECHO.
ECHO Для начала просто нажмите любую клавишу.
PAUSE > NUL
rem папка с рабочим окружением
set wd=C:\win\window8.1updEntx64

rem индекс нужного образа в install.wim
rem set indx=1

cls

ECHO .
ECHO Копирую boot.wim из %wd%\DVD\sources\ в %wd%\bootwim\ , и создаю резервную копию %wd%\bootwim\boot.wim.bak
copy /Y %wd%\DVD\sources\boot.wim %wd%\bootwim\boot.wim.bak
copy /Y %wd%\DVD\sources\boot.wim %wd%\bootwim\

ECHO .
ECHO Просмотр имеющихся образов и их индексы в boot.wim 
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\bootwim\boot.wim

ECHO .
ECHO Подключение первого образа WinPE(index:1)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\bootwim\boot.wim /index:1 /MountDir:%wd%\bootwim\mount

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl

ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab

rem Установлены следующие пакеты (6 штук):
rem WinPE-EnhancedStorage-Package, WinPE-Scripting-Package, WinPE-SecureStartup-Package, WinPE-SRT-Package, WinPE-WDS-Tools-Package, WinPE-WMI-Package
ECHO .
ECHO Установка локализации пакетов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-EnhancedStorage_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-EnhancedStorage_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SecureStartup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SecureStartup_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SRT_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SRT_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WDS-Tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WDS-Tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WMI_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WMI_tr-tr.cab

ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount

ECHO .
ECHO Просмотр установленных пакетов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Packages

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl
ECHO Работа над первым образом boot.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
cls

ECHO .
ECHO Отключение образа с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit

ECHO .
ECHO Подключение второго образа WinPE (index:2)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\bootwim\boot.wim /index:2 /MountDir:%wd%\bootwim\mount

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl

ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab

rem Установлены следующие пакеты (8 штук):
rem WinPE-EnhancedStorage-Package, WinPE-Scripting-Package, WinPE-SecureStartup-Package, WinPE-Setup-Client-Package, WinPE-Setup-Package, WinPE-SRT-Package, WinPE-WDS-Tools-Package, WinPE-WMI-Package
ECHO .
ECHO Установка локализации пакетов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-EnhancedStorage_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-EnhancedStorage_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SecureStartup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SecureStartup_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SRT_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SRT_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WDS-Tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WDS-Tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WMI_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WMI_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Setup-Client_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Setup-Client_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Setup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Setup_tr-tr.cab

ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Gen-LangINI /distribution:%wd%\bootwim\mount

ECHO .
ECHO Просмотр установленных пакетов
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Packages

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\bootwim\mount /Get-Intl

ECHO Работа над вторым образом boot.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL
cls

ECHO .
ECHO Отключение образа с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\bootwim\mount /Commit

ECHO .
ECHO Копирую новый boot.wim в %wd%\DVD\sources
copy /Y %wd%\bootwim\boot.wim %wd%\DVD\sources\

ECHO Работа над boot.wim закончена
ECHO Начинаем работать с install.wim
pause
cls

ECHO .
ECHO Просмотр имеющихся образов и их индексы в %wd%\DVD\sources\install.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\DVD\sources\install.wim

ECHO .
set /P indx="Укажите индекс нужного образа -> "
ECHO Подключение образа № %indx%
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-WIM /WimFile:%wd%\DVD\sources\install.wim /index:%indx% /MountDir:%wd%\Mount

ECHO .
ECHO Включаем компонент .Net Framework 3.5
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Image:%wd%\Mount /Enable-Feature /FeatureName:NetFx3 /Source:%wd%\DVD\sources\sxs
ECHO .
ECHO Проверяем состояние компонента .Net Framework 3.5
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Image:%wd%\Mount /Get-FeatureInfo /FeatureName:NetFx3

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Get-Intl

ECHO .
ECHO Установка языков
Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\mui\ru-ru\lp.cab /PackagePath:%wd%\mui\tr-tr\lp.cab

rem ECHO .
rem ECHO Установка обновлений для языковых пакетов install.wim
rem Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\mui\upd\ru-ru\Windows8.1-KB2938307-x64.msu /PackagePath:%wd%\mui\upd\tr-tr\Windows8.1-KB2938315-x64.msu

ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Image:%wd%\Mount /Gen-LangINI /Distribution:%wd%\DVD

ECHO .
ECHO Просмотр установленных языков
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\Mount /Get-Intl

rem ECHO .
rem ECHO Установка обновлений
rem Dism /LogPath:%wd%\Logs\DISM.log /Image:%wd%\Mount /ScratchDir:%wd%\Sandbox /Add-Package /PackagePath:%wd%\Updates

ECHO Работа над install.wim закончена
ECHO Что бы начать работу над WinRE нажмите любую клавишу
pause > NUL
cls

ECHO ========================================
ECHO Изменение WinRE
ECHO ========================================
ECHO .
ECHO Изменение атрибутов winre.wim
attrib -s -h %wd%\Mount\Windows\System32\Recovery\winre.wim

ECHO .
ECHO Копирую WinRE.wim из %wd%\Mount\Windows\System32\Recovery\ в %wd%\winREwim\ , и создаю резервную копию %wd%\winREwim\Winre.wim.bak
copy /Y %wd%\Mount\Windows\System32\Recovery\winre.wim %wd%\winREwim\Winre.wim.bak
copy /Y %wd%\Mount\Windows\System32\Recovery\winre.wim %wd%\winREwim\

ECHO .
ECHO Просмотр имеющихся образов и их индексы в %wd%\winREwim\Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Get-WIMInfo /WimFile:%wd%\winREwim\Winre.wim

ECHO .
ECHO Подключение первого образа Winre.wim(index:1)
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /Mount-Wim /WimFile:%wd%\winREwim\Winre.wim /index:1 /MountDir:%wd%\winREwim\mount

ECHO .
ECHO Просмотр установленных языков Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Get-Intl

ECHO .
ECHO Установка языков Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\lp.cab /PackagePath:%wd%\bootwim\lp\tr-tr\lp.cab

rem ECHO .
rem ECHO Установка обновлений для языковых пакетов Winre.wim
rem Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Add-Package /PackagePath:%wd%\mui\upd\ru-ru\Windows8.1-KB2938307-x64.msu /PackagePath:%wd%\mui\upd\tr-tr\Windows8.1-KB2938315-x64.msu

ECHO .
ECHO Просмотр установленных пакетов Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Get-Packages

rem Установлены следующие пакеты (8 штук):
rem WinPE-EnhancedStorage-Package WinPE-Rejuv-Package WinPE-Scripting-Package WinPE-SecureStartup-Package WinPE-SRT-Package WinPE-StorageWMI-Package WinPE-WDS-Tools-Package WinPE-WMI-Package
ECHO .
ECHO Установка локализации пакетов Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Add-Package /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-EnhancedStorage_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-EnhancedStorage_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Rejuv_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Rejuv_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-Scripting_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-Scripting_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SecureStartup_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SecureStartup_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-SRT_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-SRT_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-StorageWMI_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-StorageWMI_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WDS-Tools_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WDS-Tools_tr-tr.cab /PackagePath:%wd%\bootwim\lp\ru-ru\WinPE-WMI_ru-ru.cab /PackagePath:%wd%\bootwim\lp\tr-tr\WinPE-WMI_tr-tr.cab

ECHO .
ECHO Создание нового файла lang.ini
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Gen-LangINI /distribution:%wd%\winREwim\mount

cls
ECHO .
ECHO Просмотр установленных пакетов Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Get-Packages

ECHO .
ECHO Просмотр установленных языков Winre.wim
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /image:%wd%\winREwim\mount /Get-Intl

ECHO ========================================
ECHO Изменение WinRE закончено
ECHO ========================================
ECHO Что бы отключить WinRE с сохранением нажмите любую клавишу
pause > NUL

ECHO Отключение образа WinRE.wim с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\winREwim\mount /Commit

ECHO .
ECHO Копирую новый WinRE.wim в %wd%\Mount\Windows\System32\Recovery\
ECHO И меняю атрибуты
copy /Y %wd%\winREwim\winre.wim %wd%\Mount\Windows\System32\Recovery\
attrib +s +h %wd%\Mount\Windows\System32\Recovery\winre.wim
ECHO ========================================
ECHO ========================================

ECHO Работа над install.wim закончена
ECHO Что бы отключить образ с сохранением нажмите любую клавишу
pause > NUL

ECHO Отключение образа install.wim с сохранением всех изменений
Dism /LogPath:%wd%\Logs\DISM.log /ScratchDir:%wd%\Sandbox /unmount-Wim /MountDir:%wd%\Mount /Commit

ECHO Работа закончена
ECHO Что бы выйти нажмите любую клавишу
pause > NUL

exit /b 0

Теперь осталось подготовить файл ответов и создать загрузочный диск.

Файл ответов

Запускаем "Диспетчер установки Windows" с правами Администратора. Открываем наш Install.wim – Файл-Выбрать образ Windows. Потом выбираем нужную версию Windows и создаем файл каталога.
На форуме есть раздел посвященный файлу ответа в котором есть ссылки на статьи с подробным описанием. Хоть в статье показывается на примере Windows Vista, все это подходит и к Windows 8.
Есть важное замечание.
В отличии от Windows 7, где можно установить нужную редакцию без ввода ключа, в Windows 8 это не возможно.
В файле ответов обязательно должен быть ключ подходящий для устанавливаемой редакции.

Исключение составляет Windows 8 Enterprise, в которой ключ уже "вшит" в дистрибутив.
Для других редакций ключ должен быть в секции 1windowsPE Microsoft-Windows-Setup__neutral-UserData/ProductKey
Файл должен называться «AUTOUNATTEND.XML», и лежать в ..\DVD.

В форуме действует ограничение на количество символов с посте - 30000.
Если я включу примеры файлов ответа, то выйду за это ограничение.
Так что примеров не будет.


Создание загрузочного образа Windows 8.1 Update

Запускаем с правами Администратора «Среда средств развертывания и работы с образами». Не забываем про «set wd=C:\win\window8.1updEntx64».
Будем делать загрузочный образ с двойной загрузкой - BIOS\MBR и UEFI\GPT
Создание загрузочного образа x86
Код: Выделить весь код
oscdimg -h -lWindows8.1Upd_Ent_x86 -m -u1 -udfver102 -oc -bootdata:2#p0,e,b"%wd%\DVD\boot\etfsboot.com"#pEF,e,b"%wd%\DVD\efi\microsoft\boot\efisys.bin" %wd%\DVD %wd%\ISO\Windows8.1Upd_Ent_x86.iso
Создание загрузочного образа x64
Код: Выделить весь код
oscdimg -h -lWindows8.1Upd_Ent_x64 -m -u1 -udfver102 -oc -bootdata:2#p0,e,b"%wd%\DVD\boot\etfsboot.com"#pEF,e,b"%wd%\DVD\efi\microsoft\boot\efisys.bin" %wd%\DVD %wd%\ISO\Windows8.1Upd_Ent_x64.iso
В папке ISO появится готовый образ, который можно проверить на виртуальной машине.

-------
Создание сборки Windows 7 SP1
Создание сборки Windows 8.1

Это сообщение посчитали полезным следующие участники:

Отправлено: 14:54, 31-08-2012

 

Аватара для Stealthmax

Пользователь


Сообщения: 84
Благодарности: 15

Профиль | Отправить PM | Цитировать


Цитата alegz81:
Создание установочного диска Windows 8 EN RU TR x86 и x64 »
Вот ты реально чел помог))) Я весь нэт перерыл в поисках подобной статьи. У меня ситуация получилась после установки одного кастомного образа, этот горе-умелец вырезал много чего нужного и интегрировал Framework 3.5, не проверив работоспособность сборки(проще сказать сделал из Enterprise версию Starter). Глюки пошли в стадии Framework 3.5. Удалил кучу всего, основные компоненты среды повырезал. В итоге, пришлось скачивать другой образ и делать сборку самостоятельно, только вот не мог никак найти мануала подробного и актуального для меня. А данный пост просто "золото"! Респект! О результатах своей работы отпишусь, как закончу "ковыряние".

Отправлено: 05:03, 24-10-2012 | #2



Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.


Аватара для alegz81

Старожил


Сообщения: 167
Благодарности: 47

Профиль | Отправить PM | Цитировать


Stealthmax да пожалуйста.
Если сделаешь все по статье, то получишь 100% рабочий дистрибутив.
Я прежде чем писать статьи все проверяю.
Так что это у меня не теоретические измышления, а практические знания.
Если нужно интегрировать .Net Framework 3.5, то при смонтированном образе выполни такую команду
Код: Выделить весь код
Dism /Image:%wd%\Mount /enable-feature /featurename:NetFX3 /Source:%wd%\DVD\sources\sxs
Скоро внесу это и еще несколько изменений в статью

-------
Создание сборки Windows 7 SP1
Создание сборки Windows 8.1

Это сообщение посчитали полезным следующие участники:

Отправлено: 11:54, 24-10-2012 | #3


Аватара для CtrlSoft

Ветеран


Сообщения: 569
Благодарности: 169

Профиль | Сайт | Отправить PM | Цитировать


alegz81, так наверное правильнее
Код: Выделить весь код
Dism /Image:%wd%\Mount /enable-feature /featurename:NetFx3 /All /LimitAccess /Source:%wd%\DVD\sources\sxs
Цитата:
Use /All to enable all parent features of the specified feature Use /LimitAccess to prevent DISM from contacting WU/WSUS

-------
Windows 7 AIO x86-x64

Это сообщение посчитали полезным следующие участники:

Отправлено: 18:37, 24-10-2012 | #4


Аватара для Stealthmax

Пользователь


Сообщения: 84
Благодарности: 15

Профиль | Отправить PM | Цитировать


alegz81, у меня пару вопросов появилось в процессе.
Ситуация 1
Все батники отработали на отлично, я убрал только указание на турецкий язык, у меня только Ru и Eng, но вот не могу понять как отключить образ для редактирования в нём ресурсов, т.е. просит права на доступ к папкам и пришлось мучиться через Unlocker. Представь ситуацию, что удаляю приложения Windows Store весом метров 300, вместо 30 секунд на всё про всё, через Unlocker удаляет час-полтора!!! Реально полночи тыкался.
Лог событий
[2448] [0xc142011d] WIMCommitImageHandle1181)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 base\ntsetup\opktools\dism\providers\wimprovider\dll\wimimage.cpp:200 - CWimImage::Save(hr:0xc142011d)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 Could not commit changes during unmount. - CWimImage::Unmount(hr:0xc142011d)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 base\ntsetup\opktools\dism\providers\wimprovider\dll\wimmanager.cpp:2474 - CWimManager::InternalOpUnmount(hr:0xc142011d)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 base\ntsetup\opktools\dism\providers\wimprovider\dll\wimmanager.cpp:3894 - CWimManager::InternalCmdUnmount(hr:0xc142011d)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 Error executing command - CWimManager::InternalExecuteCmd(hr:0xc142011d)
2012-10-25 01:23:49, Error DISM DISM WIM Provider: PID=2448 TID=3668 base\ntsetup\opktools\dism\providers\wimprovider\dll\wimmanager.cpp:1928 - CWimManager::ExecuteCmdLine(hr:0xc142011d)
2012-10-25 01:23:49, Info DISM DISM.EXE: Image session has been closed. Reboot required=no.
Cкрин
Как отключил: после команды /commit запустил ещё /discard и тогда всё норм стало.
Вопрос 1: Как получить полный доступ без вышеперечисленного, т.е. свободная манипуляция папками?
Ситуация 2
Далее ситуация получилась тоже непонятная: при демонтировании любого boot.wim или install.wim пишет, что образ используется и не удалось полностью отключить его, хотя в папке лежит перепакованный образ с изменениями. Поясню сразу: работаю при полностью отключенном UAC через Групповую политику, всё запускается от моей учетки с полными правами.
Вопрос 2: В чём суть этой проблемы? Где я затупил?
Ситуация 3
Следующий момент: я хочу добавить пакет обновлений, тот что при первой установке просит докачать. Пакеты все в наличии в формате *.msu и трансформировал в *.cab.
Вопрос 3: Как "вшить" эти пакеты в сборку? И также драйвера удалить ненужные и добавить пакет для своего железа, дабы установка произошла с полной интеграцией при первом запуске.
Ситуация 4
Далее такой момент. Есть некий софт с ключами "тихой" установки я бы хотел его видеть в системе, а не стандартный и неудобный набор инструментов.[/color]
Вопрос 4: Как это воплотить? Для Windows 7 есть WinToolKit с готовыми "плюшками" в этом вопросе, а как быть с Windows 8?
Ситуация 5
Следующее. Есть бэкап реестра с изменениями "под себя". В нём много изменений, касаемо того же самого кастомного софта.
Вопрос 5: Как занести все изменения в установку? Где папка знаю- C:\Windows\System32\config, только вот не пойму как туда импортировать изменения. В том же WinToolKit есть такой момент редактирования реестра с возможностью импорта изменений.
Вопрос 6: Как полностью убить UAC? В том числе и драйвер виртуализации UAC. Этот момент вообще остался неясен. Не спросил бы, если бы не видел две сборки, где напрочь убит UAC, кроме ползунка в меню, который для меня особо неважен будет.
И по .NetFramework 3.5 я так понял, что нужно брать этот пакет ? Решено)

Последний раз редактировалось Stealthmax, 17-10-2015 в 22:49.


Отправлено: 02:51, 25-10-2012 | #5


Аватара для Stealthmax

Пользователь


Сообщения: 84
Благодарности: 15

Профиль | Отправить PM | Цитировать


Цитата CtrlSoft:
Dism /Image:%wd%\Mount /enable-feature /featurename:NetFx3 /All /LimitAccess /Source:%wd%\DVD\sources\sxs »
Респект))) Отработала команда на отлично. В папках Mount\Windows\Microsoft.NET\Framework и Mount\Windows\Microsoft.NET\Framework64 вижу все версии теперь.))) Зер гуд!!!

Отправлено: 03:06, 25-10-2012 | #6


Аватара для alegz81

Старожил


Сообщения: 167
Благодарности: 47

Профиль | Отправить PM | Цитировать


CtrlSoft можно и так.
Но и мой вариант работает
Установка:
Код: Выделить весь код
C:\Program Files (x86)\Windows Kits\8.0\Assessment and Deployment Kit\Deployment Tools
>Dism /Image:%wd%\Mount /enable-feature /featurename:NetFx3 /Source:%wd%\DVD\sources\sxs 

Cистема DISM
Версия: 6.2.9200.16384

Версия образа: 6.2.9200.16384

Enabling feature(s)
[==========================100.0%==========================]
Операция успешно завершена.
Проверка:
Код: Выделить весь код
C:\Program Files (x86)\Windows Kits\8.0\Assessment and Deployment Kit\Deployment Tools
>Dism /Image:%wd%\Mount /Get-FeatureInfo /FeatureName:NetFx3 

Cистема DISM
Версия: 6.2.9200.16384

Версия образа: 6.2.9200.16384

Feature Information:

Feature Name : NetFx3
Display Name : .NET Framework 3.5 (includes .NET 2.0 and 3.0)
Description : .NET Framework 3.5 (includes .NET 2.0 and 3.0)
Restart Required : Possible
State : Enable Pending

Custom Properties:

FWLink : http://go.microsoft.com/fwlink/?LinkId=235976

Операция успешно завершена.
Цитата:
If the status is Enable Pending, you must boot the image in order to enable the feature entirely.
Stealthmax а у тебя не Windows xp?
Цитата:
Для установки Windows ADK необходимо, чтобы ваш компьютер работал под управлением одной из следующих операционных систем:

Windows(R) 8
Windows(R) 7
Windows Server(R) 2012
Windows Server(R) 2008 R2
Windows Vista(R)
Windows Server(R) 2008
Ошибки уж слишком характерные.
Если не ХР, то может какая-нибудь говно-сборка всё в одном?
Тогда ставь чистый дистрибутив.
Ну а если все выше перечисленное не про тебя, то попробуй проверить винт
Код: Выделить весь код
chkdsk  X: /f /v /x
Вместо Х: подставишь своё.
И не торопись сделать все сразу.
С начала сделай дистрибутив без дров и всего остального и проверь.
Так будет легче искать причины ошибок.
Для установки софта я использую FirstLogonCommands
Вот статья об этом.

-------
Создание сборки Windows 7 SP1
Создание сборки Windows 8.1


Последний раз редактировалось alegz81, 26-10-2012 в 10:48.

Это сообщение посчитали полезным следующие участники:

Отправлено: 20:55, 25-10-2012 | #7


Аватара для Stealthmax

Пользователь


Сообщения: 84
Благодарности: 15

Профиль | Отправить PM | Цитировать


alegz81, разобрался.
рассказываю по порядку

1. В общем, проблема доступа к файлам банальная и ошибки диска тут ни причем абсолютно, диск у меня в норме, регулярно обслуживание делаю. При распаковке утилитой DISM каталоги сохраняют системные права, соответственно удалить так просто, как и в рабочей системе, не получится. Права выставил на папках и удалил одним нажатием, намного быстрее оказалось, чем глючным Unlocker-ом. И такой момент ещё, если при демонтировании образа, случайно будет открыт образ в проводнике, любой каталог, то будет ошибка при демонтировании, укажет на неполное отключение.

2. Далее произошел казус с добавлением обновлений, сначала netFr 3.5 ставил, а потом пакеты из последних обновлений начал устанавливать и на втором пакете пошел отказ. Вникать сильно не стал в суть проблемы, сделал методом "тыка", взял оригинал и заново всё добавил, но в обратной последовательности: сначала обновления, потом Frame и всё прекрасно добавилось, суммарно весу прибавилось на 500 Мб с 2.7 до 3.2Гб, с учетом сжатия через Imagex))) Я доволен,как слон.

А насчет XP ты пошутил неплохо Последний раз её юзал полгода назад да и то на виртуалке. Не фанат я этой оси, хотя уважаю сей продукт.
3. А вот с дровами я так и не въехал. Куда их пихать именно? Я забэкапил текущие актуальные дрова через Driver Genius, но не понял куда их надо конкретно внести и как почистить ненужные стандартные?! И главный неприятный момент: у меня проц без поддержки виртуализации, т.е. систему не получится тестировать на VB((( Только на "живом" железе. Вот и думаю, как распилить теперь диски по удачнее, дабы потом не тренироваться снова форматированием и переносом данных.

P.S. Cегодня нарыл офис 2013 от доктора, шедевр просто. Полностью RUS. В сравнении с 2010 просто земля и небо.

Кстати, в батнике не обязательно кодировку выставлять 866, я раньше тоже парился, теперь проще сделал, пишешь сверху chcp 1251 и сохраняешь в юникоде. Прекрасно всё отображает. Внимание для тех, кто увидит крякозябры при таком варианте: в свойствах cmd шрифт выставить надо Lucida Console обязательно.

Последний раз редактировалось Stealthmax, 26-10-2012 в 10:55.


Отправлено: 10:50, 26-10-2012 | #8


Аватара для Stealthmax

Пользователь


Сообщения: 84
Благодарности: 15

Профиль | Отправить PM | Цитировать


Протестировал сегодня, только непонятно почему после установки обновление высветилось Windows8-RT-KB2756872-x64.cab? Установил его без проблем, но в образ изначально добавлял. В чём глюк?

Отправлено: 07:59, 27-10-2012 | #9


Новый участник


Сообщения: 8
Благодарности: 4

Профиль | Отправить PM | Цитировать


Цитата:
Создание загрузочного образа x64
В приведенном примере не будет загрузки EFI, надо делать двойной загрузчик:
Код: Выделить весь код
oscdimg -h -lWindows8Entx64 -n -m -oc -bootdata:2#p0,e,b"C:\Program Files (x86)\Windows Kits\8.0\Assessment and Deployment Kit\Deployment Tools\amd64\Oscdimg\etfsboot.com"#pEF,e,b"C:\Program Files (x86)\Windows Kits\8.0\Assessment and Deployment Kit\Deployment Tools\amd64\Oscdimg\efisys.bin" %wd%\DVD %wd%\ISO\windows8Ent_x64.iso
Но проще взять из дистрибутива:
Код: Выделить весь код
oscdimg -h -lWindows8Entx64 -n -m -oc -bootdata:2#p0,e,b"%wd%\DVD\boot\etfsboot.com"#pEF,e,b"%wd%\DVD\efi\microsoft\boot\efisys.bin" %wd%\DVD %wd%\ISO\windows8Ent_x64.iso
Это сообщение посчитали полезным следующие участники:

Отправлено: 11:51, 30-10-2012 | #10



Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка Windows 10 / 8 / 7 / Vista » 8 / 2012 - Создание мультиязычного установочного диска Windows 8.1 Update x86 и x64

Участник сейчас на форуме Участник сейчас на форуме Участник вне форума Участник вне форума Автор темы Автор темы Шапка темы Сообщение прикреплено

Похожие темы
Название темы Автор Информация о форуме Ответов Последнее сообщение
7 / 2008 R2 - Созданиие мультиязычного установочного диска Windows 7 SP1 x86 или x64 alegz81 Автоматическая установка Windows 10 / 8 / 7 / Vista 314 17-04-2019 12:38
логотип с установочного диска windows xp zed212 Поиск драйверов, прошивок и руководств 1 01-06-2012 20:54
Загрузка - windows не загружается без диска(установочного) Ride Microsoft Windows 2000/XP 6 02-02-2008 16:55
Проблема установки Windows XP с установочного диска paZZZitif Непонятные проблемы с Железом 14 15-01-2008 22:07




 
Переход