Ветеран
Сообщения: 649
Благодарности: 444
|
Профиль
|
Отправить PM
| Цитировать
Ivan_009,
так состояния "заблокирована" нет
используй пример с 4-мя состояниями и в конце процедуры OnClick чекбокса припиши UpdateButtons
вот так (только что проверил)
кнопка обзор блокируется
Код:
procedure Твой_кастомный_чекбокс_OnClick(Sender: TObject);
begin
WizardForm.GroupEdit.Enabled := not TCheckBox(Sender).Checked;
WizardForm.GroupBrowseButton.Enabled := not TCheckBox(Sender).Checked;
UpdateButtons();
end;
=========================================================================================
Batistas,
смотри
El Sanchez вынес создание страниц в процедуры, которые выполняются в InitializeWizard
процедуры выполняется между логическими скобками begin и end
те сверху вниз (от начала до конца) и никак иначе
а теперь смотри в каком порядке они - процедуры - у тебя перечислены:
CreateNickNamePage;
CreateDownloadDirPage; -- сначала эта
CreateTempDownloadDirPage; -- потом эта
CreateShareDirPage;
CreateAboutInfoButton;
CreateURLlink;
а теперь посмотри на функцию создания страницы в процедуре CreateTempDownloadDirPage
первой настройкой (выделил зелёным) идёт страница после которой должна создаться эта - TempDownloadDirPage
TempDownloadDirPage := CreateInputDirPage( ShareDirPage.ID, ...
те ты указывать в функции создания страницы создать страницу такую-то после ещё не созданной но которая будет создана следующей "по списку"
компилятор выполняет код сверху вниз, те ты понимаешь, что так нельзя и ошибка неизбежна?
также у тебя есть некоторые недочёты в коде
например в событии OnChange элемента TStartMenuFolderTreeView, те при изменении директории (взаимодействии с деревом папок меню "Пуск")
WizardForm.GroupEdit.Text:= AddBackslash(TFV.Directory)+'MyApp';
в конце дописывается "MyApp"
это явно не было твоей целью
тоже самое касается и TFolderTreeView
позволил себе всё вышеописанное исправить и записать грамотнее
результат:
читать дальше »
Код:
//ANSI Version
#define MyAppName "Synergetic & MaxiRu DC-P2P Pack"
#define MyAppVersion "1.0.0"
#define MyAppPublisher "-=Batista=-"
#define MyAppURL "http://synergetic-hub.org/"
#define MyAppExeName "ApexDC-s16_4.exe"
#define StartupIcon "Запускать при старте Windows"
[Setup]
AppId={{E20E5BAA-70B0-4EE4-8D27-B1E312B1C083}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
AllowNoIcons=yes
OutputDir=Output
OutputBaseFilename=Synergetic & MaxiRu DC-P2P Pack 1.0.0
Compression=lzma2
SolidCompression=yes
//ArchitecturesInstallIn64BitMode=x64
[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl
[CustomMessages]
russian.NickNamePageCaption=Информация о пользователе
russian.NickNamePageDescription=Какой ник у Вас в DC++?
russian.NickNamePageSubcaption=Укажите ник и нажмите "Далее"%n%nРекомендуемые символы в нике:%n0123456789%nabcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ%n()+=[]^_{{})"%nАБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯабвгдеёжзийклмнопрстуфхцчшщъыьэюя
russian.NickNamePageEditName=Имя пользователя в DC++:
russian.DownloadDirPageCaption=Выбор каталога для загрузки
russian.DownloadDirPageDescription=Где будут храниться загружаемые файлы?
russian.DownloadDirPageSubcaption=Укажите каталог для скачки (при старте он будет автоматически "расшарен")
russian.ShareDirPageCaption=Выбор каталога для общего доступа
russian.ShareDirPageDescription=Где будут храниться файлы для общего доступа?
russian.ShareDirPageSubcaption=Укажите каталог для файлов общего доступа
russian.TempDownloadDirCaption=Выбор каталога для временных файлов
russian.TempDownloadDirPageDescription=Где будут храниться временные файлы?
russian.TempDownloadDirPageSubcaption=Укажите каталог для временных файлов
[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked
Name: quicklaunchicon; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked; OnlyBelowVersion: 0,6.1
Name: quicklaunchicon7; Description: {cm:CreateQuickLaunchIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked; MinVersion: 0,6.1
Name: startupicon; Description: {#StartupIcon}; GroupDescription: {cm:AdditionalIcons}
[Files]
Source: ApexDC-s16_4.exe; DestDir: "{app}"; Flags: ignoreversion; AfterInstall: Progress()
Source: AVIPreview.exe; DestDir: "{app}"; Flags: ignoreversion; AfterInstall: Progress()
Source: PinToTasckbar.vbs; DestDir: {tmp}; Flags: deleteafterinstall; AfterInstall: Progress()
Source: Synergetic DC++ Community.url; DestDir: "{app}"; Flags: ignoreversion; AfterInstall: Progress()
Source: Новые возможности клиента ApexDC++.txt; DestDir: "{app}"; Flags: ignoreversion; AfterInstall: Progress()
Source: EmoPacks\*; DestDir: {app}\EmoPacks\; AfterInstall: Progress();
Source: EmoPacks\Images\*;DestDir: {app}\EmoPacks\Images\;AfterInstall: Progress();
Source: EmoPacks\RadoX-Pack\*;DestDir: {app}\EmoPacks\RadoX-Pack\; AfterInstall: Progress();
Source: EmoPacks\Skype\*;DestDir: {app}\EmoPacks\Skype\; AfterInstall: Progress();
Source: EmoPacks\WAJIM-MegaEmoPack\*;DestDir: {app}\EmoPacks\WAJIM-MegaEmoPack\; AfterInstall: Progress();
Source: Settings\*; DestDir: {app}\Settings\; AfterInstall: Progress();
Source: Sounds\*; DestDir: {app}\Sounds\; AfterInstall: Progress();
Source: Themes\*; DestDir: {app}\Themes\; AfterInstall: Progress();
Source: Toolbars\*; DestDir: {app}\Toolbars; AfterInstall: Progress();
[Icons]
Name: {group}\{#MyAppName}; Filename: {app}\{#MyAppExeName}
Name: {group}\{cm:ProgramOnTheWeb,{#MyAppName}}; Filename: {#MyAppURL}
Name: {group}\{cm:UninstallProgram,{#MyAppName}}; Filename: {uninstallexe}
Name: {commondesktop}\{#MyAppName}; Filename: {app}\{#MyAppExeName}; Tasks: desktopicon
Name: {userstartup}\{#MyAppName}; Filename: {app}\{#MyAppExeName}; Tasks: startupicon
[Run]
Filename: {app}\{#MyAppExeName}; Description: {cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}; Flags: nowait postinstall skipifsilent
Filename: {#MyAppURL}; Verb: open; Description: Посетить сайт проекта Synergetic & MaxiRu; Flags: postinstall shellexec skipifsilent
Filename: {tmp}\PinToTasckbar.vbs; Parameters: """{app}\ApexDC-s16_4.exe"""; Flags: shellexec; Tasks: quicklaunchicon7
[code]
var
NickNamePage: TInputQueryWizardPage;
DownloadDirPage, ShareDirPage, TempDownloadDirPage: TInputDirWizardPage;
// TempDownloadDirPage: TInputDirWizardPage;
AboutInfoButton: TButton;
URLlink: TLabel;
procedure CreateDCPlusPlus(Filename: String);
var
objXMLDoc: Variant;
begin
try
objXMLDoc := CreateOleObject('Microsoft.XMLDOM');
except
ShowExceptionMessage;
Exit;
end;
objXMLDoc.async := False;
objXMLDoc.AppendChild(objXMLDoc.createProcessingInstruction('xml', 'version="1.0" encoding="utf-8" standalone="yes"'));
objXMLDoc.AppendChild(objXMLDoc.createNode(1, 'DCPlusPlus', ''));
//settings node
objXMLDoc.selectSingleNode('DCPlusPlus').AppendChild(objXMLDoc.createElement('Settings'));
//nick node
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createElement('Nick'));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/Nick').setAttribute('type', 'string');
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/Nick').text := NickNamePage.Values[0];
//downdir node
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createElement('DownloadDirectory'));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/DownloadDirectory').setAttribute('type', 'string');
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/DownloadDirectory').text := DownloadDirPage.Values[0];
//russian xml
if FileExists(ExpandConstant('{app}\Settings\Russian.xml')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'LanguageFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/LanguageFile').text :=(ExpandConstant('{app}\Settings\Russian.xml'));
end;
if FileExists(ExpandConstant('{app}\Sounds\PrivateMessage.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'BeepFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/BeepFile').text :=(ExpandConstant('{app}\Sounds\PrivateMessage.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\DownloadBegins.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'BeginFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/BeginFile').text :=(ExpandConstant('{app}\Sounds\DownloadBegins.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\DownloadFinished.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'FinishedFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/FinishedFile').text :=(ExpandConstant('{app}\Sounds\DownloadFinished.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\AltSourceAdded.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SourceFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SourceFile').text :=(ExpandConstant('{app}\Sounds\AltSourceAdded.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\UploadFinished.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'UploadFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/UploadFile').text :=(ExpandConstant('{app}\Sounds\UploadFinished.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\FakerFound.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'FakerFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/FakerFile').text :=(ExpandConstant('{app}\Sounds\FakerFound.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\MyNickInMainChat.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'ChatNameFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/ChatNameFile').text :=(ExpandConstant('{app}\Sounds\MyNickInMainChat.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\FileCorrupted.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundTTH', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundTTH').text :=(ExpandConstant('{app}\Sounds\FileCorrupted.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\UnhandledException.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundException', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundException').text :=(ExpandConstant('{app}\Sounds\UnhandledException.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\HubConnected.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundHubConnected', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundHubConnected').text :=(ExpandConstant('{app}\Sounds\HubConnected.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\HubDisconnected.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundHubDisconnected', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundHubDisconnected').text :=(ExpandConstant('{app}\Sounds\HubDisconnected.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\FavUser.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundFavUserOnline', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundFavUserOnline').text :=(ExpandConstant('{app}\Sounds\FavUser.wav'));
end;
if FileExists(ExpandConstant('{app}\Sounds\FavUserDisconnected.wav')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'SoundFavUserOffline', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/SoundFavUserOffline').text :=(ExpandConstant('{app}\Sounds\FavUserDisconnected.wav'));
end;
if FileExists(ExpandConstant('{app}\EmoPacks\WAJIM-MegaEmoPack v1.2c FiNAL.xml')) then
begin
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'EmoticonsFile', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/EmoticonsFile').text :='WAJIM-MegaEmoPack v1.2c FiNAL';
end;
//share node
objXMLDoc.selectSingleNode('DCPlusPlus').AppendChild(objXMLDoc.createElement('Share'));
objXMLDoc.selectSingleNode('//DCPlusPlus/Share').AppendChild(objXMLDoc.createElement('Directory'));
objXMLDoc.selectSingleNode('//DCPlusPlus/Share/Directory').setAttribute('Virtual', ExtractFileName(RemoveBackSlash(ShareDirPage.Values[0])));
objXMLDoc.selectSingleNode('//DCPlusPlus/Share/Directory').text := ShareDirPage.Values[0];
//tempdir node
// objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createElement('TempDownloadDir'));
// objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/TempDownloadDir').setAttribute('type', 'string');
// objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/TempDownloadDir').text := TempDownloadDirPage.Values[0];
//prevapps node
objXMLDoc.selectSingleNode('DCPlusPlus').AppendChild(objXMLDoc.createElement('PreviewApps'));
objXMLDoc.selectSingleNode('//DCPlusPlus/PreviewApps').AppendChild(objXMLDoc.createElement('Application'));
objXMLDoc.selectSingleNode('//DCPlusPlus/PreviewApps/Application').setAttribute('Name', 'AVI Preview');
objXMLDoc.selectSingleNode('//DCPlusPlus/PreviewApps/Application').setAttribute('Application', ExpandConstant('{app}\AVIPreview.exe'));
objXMLDoc.selectSingleNode('//DCPlusPlus/PreviewApps/Application').setAttribute('Arguments', '%[file]');
objXMLDoc.selectSingleNode('//DCPlusPlus/PreviewApps/Application').setAttribute('Extension', 'avi;divx;mpg;mpeg;vob');
//Description
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'Description', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/Description').text :='[Synergetic & MaxiRu DC-P2P Pack 1.0.0]';
//BanMessage
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'BanMessage', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/BanMessage').text :='Вы забанены. Расшарьте больше файлов или откройте больше слотов!';
//UploadSpeed
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings').AppendChild(objXMLDoc.createNode(1, 'UploadSpeed', ''));
objXMLDoc.selectSingleNode('//DCPlusPlus/Settings/UploadSpeed').text :='100';
objXMLDoc.save(Filename);
end;
function ReadDCPlusPlus(Filename, Node, Default: String): String;
var
objXMLDoc: Variant;
begin
Result := Default;
if not FileExists(Filename) then Exit;
try
objXMLDoc := CreateOleObject('Microsoft.XMLDOM'); //или другой объект
objXMLDoc.load(Filename);
objXMLDoc.async := False;
if objXMLDoc.parseError.errorCode <> 0 then Exit;
Result := objXMLDoc.selectSingleNode(Node).text;
except
ShowExceptionMessage;
Exit;
end;
end;
procedure CreateNickNamePage;
begin
NickNamePage := CreateInputQueryPage(wpSelectTasks, ExpandConstant('{cm:NickNamePageCaption}'), ExpandConstant('{cm:NickNamePageDescription}'), ExpandConstant('{cm:NickNamePageSubcaption}'));
NickNamePage.Add(ExpandConstant('{cm:NickNamePageEditName}'), False);
NickNamePage.Values[0] := ReadDCPlusPlus(WizardDirValue + '\Settings\DCPlusPlus.xml', '//DCPlusPlus/Settings/Nick', '');
end;
procedure CreateDownloadDirPage;
begin
DownloadDirPage := CreateInputDirPage(NickNamePage.ID, ExpandConstant('{cm:DownloadDirPageCaption}'), ExpandConstant('{cm:DownloadDirPageDescription}'), ExpandConstant('{cm:DownloadDirPageSubcaption}'), False, 'Новая папка');
DownloadDirPage.Add('');
DownloadDirPage.Values[0] := ReadDCPlusPlus(WizardDirValue + '\Settings\DCPlusPlus.xml', '//DCPlusPlus/Settings/DownloadDirectory', WizardDirValue + '\Downloads-P2P');
end;
procedure CreateShareDirPage;
begin
ShareDirPage := CreateInputDirPage(DownloadDirPage.ID, ExpandConstant('{cm:ShareDirPageCaption}'), ExpandConstant('{cm:ShareDirPageDescription}'), ExpandConstant('{cm:ShareDirPageSubcaption}'), False, 'Новая папка');
ShareDirPage.Add('');
ShareDirPage.Values[0] := ReadDCPlusPlus(WizardDirValue + '\Settings\DCPlusPlus.xml', '//DCPlusPlus/Share/Directory', '');
end;
procedure CreateTempDownloadDirPage;
begin
TempDownloadDirPage := CreateInputDirPage(ShareDirPage.ID, ExpandConstant('{cm:TempDownloadDirCaption}'), ExpandConstant('{cm:TempDownloadDirPageDescription}'), ExpandConstant('{cm:TempDownloadDirPageSubcaption}'), False, 'Новая папка');
TempDownloadDirPage.Add('');
TempDownloadDirPage.Values[0] := ReadDCPlusPlus(WizardDirValue + '\Settings\DCPlusPlus.xml', '//DCPlusPlus/Settings/TempDownloadDir', WizardDirValue + '\Temp');
end;
procedure ControlOnClick(Sender: TObject);
var
ResultCode: Integer;
begin
if Sender is TButton then MsgBox('© -=Batista=-, 2012', mbInformation, MB_OK);
if Sender is TLabel then ShellExec('open', '{#MyAppURL}', '', '', SW_SHOW, ewNoWait, ResultCode);
end;
procedure CreateAboutInfoButton;
begin
AboutInfoButton := TButton.Create(WizardForm);
with AboutInfoButton do begin
Parent := WizardForm;
SetBounds(WizardForm.ClientWidth - WizardForm.CancelButton.Left - WizardForm.CancelButton.Width, WizardForm.CancelButton.Top, WizardForm.CancelButton.Width, WizardForm.CancelButton.Height);
Caption := 'Автор...';
OnClick := @ControlOnClick;
end;
end;
procedure CreateURLlink;
begin
URLlink := TLabel.Create(WizardForm);
with URLlink do begin
Parent := WizardForm;
Left := 2*AboutInfoButton.Left + AboutInfoButton.Width;
Top := AboutInfoButton.Top + AboutInfoButton.Height - Height;
Caption := '{#MyAppURL}';
Font.Color := clBlue;
Font.Style := [fsUnderline];
Cursor := crHand;
OnClick := @ControlOnClick;
end;
end;
//function SetWindowTheme(hwnd: HWND; pszSubAppName: pchar; pszSubIdList: pchar): Longint; external 'SetWindowTheme@uxtheme.dll stdcall delayload';
var
ProgressLabel, SizeLabel: TLabel;
TDV: TFolderTreeView;
TFV: TStartMenuFolderTreeView;
procedure TFV_and_TDV_OnChange_and_else(Sender: TObject);
begin
if Sender is TStartMenuFolderTreeView then WizardForm.GroupEdit.Text := AddBackslash(TStartMenuFolderTreeView(Sender).Directory) + '{#SetupSetting("DefaultGroupName")}';
if Sender is TFolderTreeView then WizardForm.DirEdit.Text:= AddBackslash(TFolderTreeView(Sender).Directory) + '{#MyAppName}';
if Sender is TCheckBox then
begin
TFV.Enabled := not TCheckBox(Sender).Checked;
WizardForm.GroupEdit.Enabled := not TCheckBox(Sender).Checked;
WizardForm.GroupBrowseButton.Enabled := not TCheckBox(Sender).Checked;
end;
end;
procedure Progress();
var
size: integer;
begin
with WizardForm.ProgressGauge do
ProgressLabel.Caption:= IntToStr((Position-Min)/((Max - Min)/100)) + '%';
FileSize(ExpandConstant(CurrentFileName), size);
SizeLabel.Caption:= IntToStr(size) + ' бт';
end;
procedure InitializeWizard();
begin
CreateNickNamePage;
CreateDownloadDirPage;
CreateShareDirPage;
CreateTempDownloadDirPage;
CreateAboutInfoButton;
CreateURLlink;
WizardForm.NoIconsCheck.OnClick := @TFV_and_TDV_OnChange_and_else;
TDV := TFolderTreeView.Create(WizardForm);
with TDV do
begin
Top:= WizardForm.DirEdit.Top + ScaleY(28);
Width:= ScaleX(417);
Height:= ScaleY(100);
OnChange := @TFV_and_TDV_OnChange_and_else;
Parent := WizardForm.SelectDirPage;
end;
TFV:= TStartMenuFolderTreeView.Create(WizardForm);
with TFV do
begin
Top:= WizardForm.GroupEdit.Top + ScaleY(28);
Width:= ScaleX(417);
Height:= ScaleY(100);
SetPaths(ExpandConstant('{userprograms}'),ExpandConstant('{commonprograms}'),ExpandConstant('{userstartup}'),ExpandConstant('{commonstartup}'));
OnChange:= @TFV_and_TDV_OnChange_and_else;
Parent:= WizardForm.SelectProgramGroupPage;
end;
ProgressLabel := TLabel.Create(WizardForm);
with ProgressLabel do
begin
Top := WizardForm.ProgressGauge.Top + WizardForm.ProgressGauge.Height + ScaleY(8);
Left:= WizardForm.ProgressGauge.Left + WizardForm.ProgressGauge.Width/2 - ScaleX(8);
AutoSize := True;
Parent := WizardForm.InstallingPage;
end;
SizeLabel := TLabel.Create(WizardForm);
with SizeLabel do
begin
Top := WizardForm.ProgressGauge.Top + WizardForm.ProgressGauge.Height + ScaleY(8);
Left:= WizardForm.ProgressGauge.Left;
AutoSize := True;
Parent := WizardForm.InstallingPage;
end;
end;
procedure CurPageChanged(CurPageID: Integer);
begin
case CurPageID of
wpSelectProgramGroup: TFV.Enabled := WizardForm.GroupBrowseButton.Enabled; // это если первый раз не создавать значки то при повторном запуске инсталл возьмёт настройку из реестра и заблокирует эдит и кнопку а TFV Нет и чтоб это глупо не смотрелось делаем такую проерку
end;
end;
procedure CurStepChanged(CurStep: TSetupStep);
begin
case CurStep of
ssPostInstall: CreateDCPlusPlus(ExpandConstant('{app}\Settings\DCPlusPlus.xml'));
end;
end;
и на будущее убирай свой код в тег [more][code] твой код [/code][/more] тк без отступов код просматривать тяжело
====================================================================
El Sanchez,
спасибо
не знал про такую манеру написания if Sender is TStartMenuFolderTreeView ... до недавних пор
это в немалой для меня мере развязывает руки
раньше писал
case TButton(Sender) или case TLabel(Sender).Tag of
|