[Johny777]

alert30, EvilAlex,


код:

читать дальше »

Код:

[Setup]
AppName=777
AppVerName=777
DefaultDirname=C:\Program Files (x86)\Source Engine 15\common\half-life 2\platform
Compression=none


[Files]
Source: C:\Program Files (x86)\Source Engine 15\common\half-life 2\hl2\maps\*; DestDir: {app}; BeforeInstall: BetterInfo();


[code]
#ifdef UNICODE
    #define A "W"
#else
    #define A "A"
#endif

const
  MAX_PATH = 260;
  PATH_LEN = 69;
    
var
  hInfoPath, hInfoFile: HWND;

function SetWindowText(hWnd: HWND; lpString: String): BOOL; external 'SetWindowText{#A}@user32.dll stdcall';
function PathCompactPathEx(pszOut: String; pszSrc: String; cchMax: UINT; dwFlags: DWORD): BOOL; external 'PathCompactPathEx{#A}@shlwapi.dll stdcall';
function CompactPath(const sInput: String; const iNewLen: Integer): String;
begin
  SetLength(Result, MAX_PATH);
  if not PathCompactPathEx(Result, sInput, iNewLen, 0) then Result := sInput;
end;

procedure BetterInfo();
var
  CurrentFile: String;
begin
  CurrentFile := ExpandConstant(CurrentFilename);
  SetWindowText(hInfoPath, 'Директория:' + #32 + CompactPath(RemoveBackslash(ExtractFilePath(CurrentFile)), PATH_LEN));
  SetWindowText(hInfoFile,  StringOfChar(#32, 12) + 'Файл:' + #32 + ExtractFileName(CurrentFile));
end;

procedure InitializeWizard();
begin
  with WizardForm do
  begin
    with TNewStaticText.Create(WizardForm) do
    begin
      Parent := FilenameLabel.Parent;
      SetBounds(FilenameLabel.Left, ScaleY(0), ProgressGauge.Width, ScaleY(16));
      hInfoPath := Handle;
      AutoSize := False;
    end;
    with TNewStaticText.Create(WizardForm) do
    begin
      Parent := FilenameLabel.Parent;
      SetBounds(FilenameLabel.Left, ScaleY(20), ProgressGauge.Width, ScaleY(16));
      hInfoFile := Handle;
      AutoSize := False;
    end;
    FilenameLabel.Hide;
    StatusLabel.Hide;
  end;
end;

==================================================================================================== ===========

Nightwishh,

можно ли изменить цвет стандартных чекбоксов в ComponentsList-е и TasksList-е через скин »

нет, это неисправленный косяк скинирования!
Геморно но можно создать скроллбокс и массив радиобаттонов и чекбоксов и всё это добавлять на него, через самописную функцию, если так нужен именно чеклистбокс. Короче кастомный чеклистбокс

[Nightwishh]

Johny777, Ясно, вообщем трогать я это не буду :-) спасибо.
И последний вопрос. Можно ли запустить инсталл только один раз, т.е. при запущеном setup.exe нельзя было запустить его ещё раз и выдовалось сообщение, типо "Программа запущена". Спасибо!!!

[Gnom_aka_Lexander]

Nightwishh, в секции сетап есть параметры мьютекса, которые для этого и служат. почитай про них в справке. еще в коде есть функции для работы с мьютексами.

[ChVL]

Как к стандартному файлу unins000.exe прикрутить свою иконку? Именно свою, а не ту, что имеет исполняемый файл.

Знаю, как это делается через секцию [Icons], но мне это не надо. Точнее, не нужен unins000.exe в меню Пуск.
Где-то было, но потерял...

[dracosha]

ChVL

Код:

[Setup]
UninstallIconFile={#MyAppProjectPath}\Installer\uninst.ico

В справке написано что эта функция не используется с версии 5.0, но она работает.

[ChVL]

dracosha,
Спасибо, уже вспомнил. Сделал проще:

Код:

[Setup] 
UninstallIconFile=unins.ico

В этом случае положить её надо рядом со скриптом, по аналогии с иконкой для исполняемого файла (чтоб в {app} не светились).

[EvilAlex]

alert30, EvilAlex, код: читать дальше » »

Супер, спасибо ! Но возник еще 1 вопрос, его можно к исдону сделать ?
Чтобы при распаковке арка или срепа, он отображал куда и что извлекает?

[habib2302]

люди.помогите мне исправить эту ошибку

Error: Custom message name may only include alphanumeric characters and/or underscores, and cannot begin with a number.

вот часть скрипта на которую он ругается

Код:

[Tasks]
Name: icons; Description: Создать Ярлыки:;
Name: icons\desktop; Description: На Рабочем Столе;
Name: icons\quicklaunchicon; Description: В Панели Задач;
Name: soft; Description: Установка Дополнительного ПО
Name: soft\msv; Description: Microsoft Visual C++

[CustomMessages]
Создать Ярлыки:=Create Shortcuts:
На Рабочем Столе=On the Desktop
В Панели Задач=In the Taskbar
Установка Дополнительного ПО=Install Additional Software

[saurn]

habib2302

Надо так:

Код:

[Tasks]
Name: icons; Description: {cm:CreateShortcuts};
Name: icons\desktop; Description: {cm:OntheDesktop};
Name: icons\quicklaunchicon; Description: {cm:IntheTaskbar};
Name: soft; Description: {cm:InstallAdditionalSoftware}
Name: soft\msv; Description: Microsoft Visual C++

[CustomMessages]
CreateShortcuts=Создать Ярлыки
OntheDesktop=На Рабочем Столе
IntheTaskbar=В Панели Задач
InstallAdditionalSoftware=Установка Дополнительного ПО

[habib2302]

saurn, оно как было на русском так и осталось.а мне нужно чтобы стало на английском