[4EJLO6PEK]

Извините, думал примера достаточно
1.rar

[Iska]

Вставьте следующий код:

читать дальше »

Код:

Option Explicit

Sub ReplaceInFile()
    Dim strFileName As String
    Dim strFileFullName As String
    
    Dim strContent As String
    Dim objRange As Range
    
    
    strFileName = "2new_4(sootvetstvuet).txt"
    
    With CreateObject("Scripting.FileSystemObject")
        strFileFullName = .Buildpath(ThisWorkbook.Path, strFileName)
        
        If .FileExists(strFileFullName) Then
            With .OpenTextFile(strFileFullName)
                strContent = .ReadAll()
                .Close
            End With
            
            .CopyFile strFileFullName, strFileFullName & ".bak", True
            
            With .CreateTextFile(strFileFullName, True)
                For Each objRange In ThisWorkbook.ActiveSheet.UsedRange.Rows
                    strContent = Replace(strContent, objRange.Cells(1, 1).Value, objRange.Cells(1, 2).Value)
                Next
                
                .Write strContent
                .Close
            End With
        Else
            MsgBox "File [" & strFileFullName & "] not found."
        End If
    End With
End Sub

в рабочую книгу «Книга1.xlsx», сделайте в ней активным рабочий лист со списком для замены, затем исполните процедуру «ReplaceInFile()». Ожидается, что текстовый файл «2new_4(sootvetstvuet).txt» будет находиться рядом с этой рабочей книгой.

[4EJLO6PEK]

большое спасибо....все получилось