[madmasles]

чтобы он искал эксели во всех папках что находятся на одном уровне с самим скриптом, и вложенных в этих папках папки »

Код:

#include <Array.au3>

$aExcel = _FileSearch(@ScriptDir, '*.xlsx', 1)
_ArrayDisplay($aExcel)


Func _FileSearch($sPath, $sFileMask = '*', $iFlag = 0, $iSubdir = 1)
    ;фильтры для поиска нужно указывать через ;
    ;$iFlag = 0 - Файлы и папки (по умолчанию)
    ;$iFlag = 1 - Только файлы
    ;$iFlag = 2 - Только папки
    ;$iSubdir = 1 - Искать во всех подкаталогах (по умолчанию). Возвращает полные пути.
    ;$iSubdir = 0 - Искать только в самой папке. Возвращает только имена файлов(папок).
    Local $sOutBin, $sOut, $aOut, $sRead, $hDir, $sAttrib, $sSubdir, $aMasks

    If StringRight($sPath, 1) == '\' Then
        $sPath = StringTrimRight($sPath, 1)
    EndIf
    If $iSubdir Then
        $sSubdir = ' /S /B'
    Else
        $sSubdir = ' /B'
    EndIf
    Switch $iFlag
        Case 1
            $sAttrib = ' /A-D'
        Case 2
            $sAttrib = ' /AD'
        Case Else
            $sAttrib = ' /A'
    EndSwitch

    $sOut = StringToBinary('0' & @CRLF, 2)
    $aMasks = StringSplit($sFileMask, ';')

    For $i = 1 To $aMasks[0]
        $hDir = Run(@ComSpec & ' /U /C DIR "' & $sPath & '\' & $aMasks[$i] & '"' & $sSubdir & $sAttrib, @SystemDir, @SW_HIDE, 6)
        While 1
            $sRead = StdoutRead($hDir, False, True)
            If @error Then
                ExitLoop
            EndIf
            If $sRead <> "" Then
                $sOut &= $sRead
            EndIf
            Sleep(2)
        WEnd
    Next
    $aOut = StringRegExp(BinaryToString($sOut, 2), '[^\r\n]+', 3)
    If @error Then
        Return SetError(1)
    EndIf
    $aOut[0] = UBound($aOut) - 1
    Return $aOut
EndFunc   ;==>_FileSearch

_FileSearch().

[Pozia]

madmasles, что то я не допру как этим добром пользоваться. Запустил, нашлись мои эксели. Выбрал. Нажал внизу кнопку. И ничего...

[madmasles]

Запустил, нашлись мои эксели »

Выбирать ничего не надо. _ArrayDisplay($aExcel) только чтобы показать, что нашли. Можно его убрать вместе с #include <Array.au3> . Дальше, наверное, так, как у Вас раньше было:

Код:

;...
If $aExcel[0] Then
    For $i = 1 To $aExcel[0]
        $sFile = $aExcel[$i]
        $oExcel = ObjCreate('Excel.Application'); Запускаем экземпляр Excel
        $oExcel.AskToUpdateLinks = False
        $oExcel.WorkBooks.Open($sFile); Открываем файл Excel'ем
        $oExcel.ActiveWorkBook.UpdateLinks; Обновляем ссылки
        $oExcel.ActiveWorkBook.Save; Сохраняем файл
        $oExcel.Application.Quit; Выходим из Excel
        $oExcel = 0; Освобождаем переменную
    Next
Else
    MsgBox(16, 'Error', 'Нет файлов')
EndIf

Попробуйте так, по идее, быстрее должно работать.

читать дальше »

Код:

$aExcel = _FileSearch(@ScriptDir, '*.xlsx', 1)

If $aExcel[0] Then
    $oExcel = ObjCreate('Excel.Application'); Запускаем экземпляр Excel
    $oExcel.AskToUpdateLinks = False
    For $i = 1 To $aExcel[0]
        $oExcel.WorkBooks.Open($aExcel[$i]); Открываем файл Excel'ем
        $oExcel.ActiveWorkBook.UpdateLinks; Обновляем ссылки
        $oExcel.ActiveWorkBook.Save; Сохраняем файл
    Next
    $oExcel.Application.Quit; Выходим из Excel
    MsgBox(64, 'Info', 'Обработано ' & $aExcel[0] & ' файлов Excel')
Else
    MsgBox(16, 'Error', 'Нет файлов')
EndIf

Func _FileSearch($sPath, $sFileMask = '*', $iFlag = 0, $iSubdir = 1)
    ;фильтры для поиска нужно указывать через ;
    ;$iFlag = 0 - Файлы и папки (по умолчанию)
    ;$iFlag = 1 - Только файлы
    ;$iFlag = 2 - Только папки
    ;$iSubdir = 1 - Искать во всех подкаталогах (по умолчанию). Возвращает полные пути.
    ;$iSubdir = 0 - Искать только в самой папке. Возвращает только имена файлов(папок).
    Local $sOutBin, $sOut, $aOut, $sRead, $hDir, $sAttrib, $sSubdir, $aMasks

    If StringRight($sPath, 1) == '\' Then
        $sPath = StringTrimRight($sPath, 1)
    EndIf
    If $iSubdir Then
        $sSubdir = ' /S /B'
    Else
        $sSubdir = ' /B'
    EndIf
    Switch $iFlag
        Case 1
            $sAttrib = ' /A-D'
        Case 2
            $sAttrib = ' /AD'
        Case Else
            $sAttrib = ' /A'
    EndSwitch

    $sOut = StringToBinary('0' & @CRLF, 2)
    $aMasks = StringSplit($sFileMask, ';')

    For $i = 1 To $aMasks[0]
        $hDir = Run(@ComSpec & ' /U /C DIR "' & $sPath & '\' & $aMasks[$i] & '"' & $sSubdir & $sAttrib, @SystemDir, @SW_HIDE, 6)
        While 1
            $sRead = StdoutRead($hDir, False, True)
            If @error Then
                ExitLoop
            EndIf
            If $sRead <> "" Then
                $sOut &= $sRead
            EndIf
            Sleep(2)
        WEnd
    Next
    $aOut = StringRegExp(BinaryToString($sOut, 2), '[^\r\n]+', 3)
    If @error Then
        Return SetError(1)
    EndIf
    $aOut[0] = UBound($aOut) - 1
    Return $aOut
EndFunc   ;==>_FileSearch

[Pozia]

madmasles, мне идея со списком ваша понравилась. А могли бы вы подправить так, чтобы я в списке выбирал какие файлы сохранить?

[madmasles]

чтобы я в списке выбирал какие файлы сохранить? »

Завтра попробую сделать.

[madmasles]

Pozia,
То, что у меня получилось, в прикрепленном архиве. Вроде работает, проверял на Windows XP SP3 32 и Windows 7 SP1 32, Office 2003. Пытался написать здесь, но ругается, говорит, что слишком много символов.

PS
Поменяйте в скрипте на 14-ой строке $sExt = '*.xls' на $sExt = '*.xlsx', а то я на 2003 проверял.
Не надо, я добавил функцию на проверку версии, должно само определить.

Добавил вариант (3_Excel.7z) с возможностью изменения папки поиска файлов.

[Pozia]

madmasles, при попытке скомпилировать выскакивает ошибка на winAPIE.au3. типа не может открыть. Это какая то добавка которой у меня нет?

[madmasles]

Pozia,
Забыл дать ссылку: Расширение стандартной AutoIt библиотеки WinAPI.au3.

[Pozia]

madmasles, разобрался. Клева работает. Спасибо за помощь. Очень упростили мои мучения. По ходу юзания появилась еще хотелка. Если не сложно, сделайте вверху над всеми птичками еще одну общую птичку, которой можно было бы снять со всего или на все повесить. Если файлов много, а нужно выбрать несколько, то так будет удобнее. И если это возможно, сделайте возможность сортировки если нажимать вверху по Имя файла или Папка файла. Спасибо!!!

[madmasles]

Pozia,
Птичку сделал, сортировку добавил, только не по нажиманию по заголовку ListView, а перед заполнением таблицы.