[amel27]

Код:

REG ADD "HKCU\Software\Gabest\Media Player Classic\Settings" /v Loop /t REG_DWORD /d 1 /f
REG ADD "HKCU\Software\Gabest\Media Player Classic\Settings" /v Rewind /t REG_DWORD /d 1 /f

mplayerc.exe "list.mpcpl"

[Anarasius]

Как задать плееру что бы он начал воспроизводить все файлы в папке kino в случайном порядке и повторяя(т.е. бесконечно)

[amel27]

где-то так:

Код:

@Echo Off
SetLocal EnableExtensions

Set ROOT=D:\MP3
Set MASK=*.mp3
Set $CPL=%ROOT%\random.mpcpl
Set $EXE=%ProgramFiles%\Media Player Classic\mplayerc.exe
Set $TMP=%TEMP%\$%RANDOM%%RANDOM%$.tmp

Echo Минутку... формирование списка воспроизведения
PushD %ROOT%& DIR /S/B %MASK%|Find /N /V "&">%$TMP%& PopD
<Nul >"%$CPL%" SET /P $Z=я╗┐
Echo MPCPLAYLIST>>%$CPL%
For /F "Tokens=3 Delims=:" %%i In ('Find /C /V "" "%$TMP%"') Do Set /A $C=%%i+0
Set /A $MAX=$C*2

:ADD_FILE_LOOP
::---
Set /A $I+=1
Set /A $R=%RANDOM%+0
Set /A $X=1+%$R%-(%$R%/%$C%)*%$C%
For /F "Tokens=2 Delims=][" %%i In ('FindStr /BRC:"\[%$X%\]" "%$TMP%"') Do Call :ADD_FILE "%%i"
If %$I% NEQ %$MAX% GoTo ADD_FILE_LOOP
::---
DEL /F/Q "%$TMP%"

REG ADD "HKCU\Software\Gabest\Media Player Classic\Settings" /v Loop /t REG_DWORD /d 1 /f
REG ADD "HKCU\Software\Gabest\Media Player Classic\Settings" /v Rewind /t REG_DWORD /d 1 /f

"%$EXE%" "%$CPL%"
Exit /B

:ADD_FILE
::---
Set /A $J+=1
Echo %$J%,type,0 >>%$CPL%
CHCP 65001|>>%$CPL% Echo %$J%,filename,%~1&CHCP 866 >Nul
::---
GoTo :EOF

[Itush]

Добрый день. Подниму старую тему.
Помогите изменить данный скрипт, что бы файлы игрались не в случайном порядке, а плейлист сгенерировался из файлов и проигрывался бесконечно.
И ещё вопрос - в данном скрипте файлы должны быть mp3, а как сделать, что бы в плейлист попадали файлы и с другим разрешением. (видео фалы)
Спасибо.