[megaloman]

Есть пару тысяч txt файлов »

Если в одной папке, то

Код:

@Echo Off
	Set "BoxIn=Z:\Box_In"
	Set "Mask=*.txt"
	Set "KeyWord=mozila"

	Pushd "%BoxIn%" && FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%Mask%" /B /A:-D`) DO (
		>"%%f.tmp" (FOR /F "usebackq delims=" %%t IN (`2^>nul More "%%f"^|FindStr /I /V "%KeyWord%"`) DO Echo %%t)
		>nul Move /Y "%%f.tmp" "%%f"
	)
	Popd
Exit /B

Если в разных, без просмотра подпапок, то:

Код:

@Echo Off
	Set BoxIn="Z:\Box_In" "Z:\Soft_In"
	Set "Mask=*.txt"
	Set "KeyWord=mozila"

	For %%d In (%BoxIn%) Do (
		Pushd "%%~d" && FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%Mask%" /B /A:-D`) DO (
			>"%%f.tmp" (FOR /F "usebackq delims=" %%t IN (`2^>nul More "%%f"^|FindStr /I /V "%KeyWord%"`) DO Echo %%t)
			>nul Move /Y "%%f.tmp" "%%f"
		)
		Popd
	)
Exit /B

[Jeka124]

Все файлы в одной папке. Что-то не работает. Первая строка это путь к папке с файлами? В третью строку я вписывают ключевой слово? Если в файле мне нужно оставить не одну строку а несколько, повторить третью строку с другим ключевым словом? Это через бат файл? Сорян возможно задаю тупые вопросы - новичок.

Текст в файлах на русском языке, возможно это имеет значение или должно срабатывать в любом случае?

[Jeka124]

Ок,

[megaloman]

Начнём сначала:

type your_file.txt | findstr /i /v "mozila" > temp.txt del your_file.txt rename temp.txt your_file.txt »

Если в файле мне нужно оставить не одну строку а несколько, повторить третью строку с другим ключевым словом? Это через бат файл? »

1.findstr /i /v "mozila" позволяет выдать все строки, которые не содержат , условно, слово mozila. Объясните, что Вы хотите: оставить все строки со словом, условно, mozila, либо удалить эти строки.
2. В какой кодировке сохранены текстовые файлы? Неплохо бы получить образец файла. Так как Вы хотите работать с кириллицей, кодировка важна.

[Jeka124]

Суть в том, что нужно собрать некоторые данные о школах есть файлы с данными но там много лишнего и это нужно убрать. В файле столбцы это те строки которые должны остаться в конечном итоге, второй файл образец. Работаю через Notepad++ и там кодировку можно изменить, вот только не знаю во всех одновременно можно это сделать.

[Iska]

Если в файле мне нужно оставить не одну строку а несколько, повторить третью строку с другим ключевым словом? »

Нет. Вам нужно было бы повторить параметр «/c» и, если именно «оставить» — то убрать параметр «/v»:

Код:

… findstr.exe /i /c:"мама" /c:"мыла" /c:"раму" …

Текст в файлах на русском языке, возможно это имеет значение или должно срабатывать в любом случае? »

Имеет значение кодировка данных файлов. У Вас она — UTF8/65001 без BOM, посему быстрее, проще и надёжнее в данном случае будет пользовать PowerShell.

[Jeka124]

А как это реализовать через PowerShell?

[Fors1k]

А как это реализовать через PowerShell? »

Код:

param(
    $model  = "C:\Files\Столбцы.txt",
    $folder = "C:\Box_In"
)cls

foreach($i in (gci $folder *.txt).FullName){
    foreach($j in (gc $model -en UTF8)){
        gc $i -enc UTF8|? {$_ -like "$j*"}
    }
}

[Jeka124]

Что-то не работает. Первая строка это путь к образу? Вторая путь к файлам? Если так то не работает, все файлы остались без изменений. Возможно я что-то не так делаю. В общем скопировал код создал файл вставил код, сохранил поменял расширение на ps1, открыл windows powerhell ise от имени админа нажал выполнить, какие-то действия были выполнены но вот результата нет, возможно результат не сохраняется?

[megaloman]

Если в пути папки, заданном в батнике, нет кириллических символов, если сохранять батник в UTF8 без BOM, то можно выкрутиться. В приложенном батнике, переименованном в txt, удаляются строки с двумя (можно больше) фразами.

Код:

@Echo Off
	Set "BoxIn=Z:\Box_In"
	Set "Mask=*.txt"
	Set KeyWord="Ступень" "Бюджетирование (основатель)"

	Pushd "%BoxIn%" && FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%Mask%" /B /A:-D`) DO (
		FOR  %%k IN (%KeyWord%) DO (
			>"%%f.tmp" (More "%%f"|Find /I /V %%k)
			>nul Move /Y "%%f.tmp" "%%f"
		)
	)
	Popd
Exit /B

FindStr не работает с UTF и за раз исключить строки с несколькими словами не получается, поэтому применяется Find последовательно для каждой из исключаемых фраз.
Можно, наверное, сделать выборку строк с ключевыми фразами, но это несколько иная песТня.
Надеюсь, спецы по PowerShell напишут приемлемое для ваших тысяч файлов