[megaloman]

spb-nord, Как-то путано. Вот вариант

Код:

@Echo Off
cls
	Set "FileIn=Z:\Box_In\infile.txt"
	Set "FileOut=Z:\Box_In\outfile.txt"

	Set "FirstNew=box place client_id"

	>"%FileOut%" (Echo %FirstNew%)
	Set /P FirstOld=<"%FileIn%"

        Echo %FirstNew%
	FOR /F "usebackq delims=" %%i In (`2^>nul More +1 "%FileIn%"`) DO (
		(Set /P EndStr=%%i %FirstOld% )
		>>"%FileOut%" (Call Echo %%i %FirstOld% %%EndStr%%)
	)
Pause
Exit /B

Вопросы по постановке:
1. Откуда берётся "box place client_id" или это некая постоянная?
2. Через "tab" или через пробел? Что такое "tab" - приведите код символа
3. Третье значение - постоянная для всех строк или для каждой строки своя?

[spb-nord]

Спасибо за ответ.
1. box place client_id это постоянная которая появляется во всех новых файлах.
2. Взято из примера самого файла. Прикрепил.
3. Третье для одного документа постоянная. Для другого может быть 444 к примеру, но так же на весь файл.

[megaloman]

Попробуйте. Здесь Tab присвоены не пробелы, а табуляция.

Код:

@Echo Off
cls
	Set "FileIn=Z:\Box_In\infile.txt"
	Set "FileOut=Z:\Box_In\outfile.txt"

	Set "Tab=	"
	Set "FirstNew=box place%Tab%client_id"
rem	Set "FirstNew=box%Tab%place%Tab%client_id"
rem	Set "FirstNew=box%Tab%%Tab%place%Tab%%Tab%client_id"

	(Set /P EndStr=Enter the third component ^> )

	>"%FileOut%" (Echo %FirstNew%)
	Set /P FirstOld=<"%FileIn%"

	FOR /F "usebackq delims=" %%i In (`2^>nul More +1 "%FileIn%"`) DO (
		>>"%FileOut%" (Echo %%i%Tab%%FirstOld%%Tab%%EndStr%)
	)
Pause
Exit /B

Результат

Я не понимаю, к чему привязан заголовок. Приведенный вариант даёт

Код:

box place	client_id
KB920673	P1-31-00-00	klwhjejhwlqjlkjrlejl
KB920674	P1-31-00-00	klwhjejhwlqjlkjrlejl
KB920675	P1-31-00-00	klwhjejhwlqjlkjrlejl
KB920676	P1-31-00-00	klwhjejhwlqjlkjrlejl
KB920677	P1-31-00-00	klwhjejhwlqjlkjrlejl

Возможно, Вас более устроит строка:

Код:

	Set "FirstNew=box%Tab%place%Tab%client_id"

При этом получим как в Вашем файле

Код:

box	place	client_id
KB920673	P1-31-00-00	868686
KB920674	P1-31-00-00	868686
KB920675	P1-31-00-00	868686
KB920676	P1-31-00-00	868686
KB920677	P1-31-00-00	868686

Или еще вариант

Код:

	Set "FirstNew=box%Tab%%Tab%place%Tab%%Tab%client_id"

Код:

box		place		client_id
KB920673	P1-31-00-00	42321
KB920674	P1-31-00-00	42321
KB920675	P1-31-00-00	42321
KB920676	P1-31-00-00	42321
KB920677	P1-31-00-00	42321

[spb-nord]

Спасибо огромное! Все супер