[alpap]

1.
пример файла в архиве чтобы видеть его структуру, кодировку и расширение
2.

Нужно вытащить »

куда? В отдельный файл или что делать с этим.
3.
четко не понятно что делать в цикле, кроме как вычленять что-то из файлов, а какие файлы выбирать, откуда, по какой маске или какому критерию и в какой промежуток времени, если это будет из планировщика. Или это сами сделаете?

[megaloman]

Код:

@Echo Off
cls
	Set "FileIn=Z:\Box_In\~???????.???"
	For %%f In ("%FileIn%") Do Call :OutFirst "%%f" 18 3 24 2
Pause
Exit /B 0

:OutFirst
	Set /P First=<%1
	Call Set "First1=%%First:~%2,%3%%"
	Call Set "First2=%%First:~%4,%5%%"
	Echo %First1% %First2%   %1
Exit /B

Alexeyshka,

Ваш вариант

Код:

@Echo Off
cls
	For %%i In ("Z:\Box_In\~y??????.???") Do (
		Set /P val=<"%%i"
		Call Set "val1=%%val:~18,3%%"
		Call Set "val2=%%val:~24,2%%"
		Call Echo %%val1%% %%val2%%   %%i
	)
Pause
Exit /B 0

или так:

Код:

@Echo Off
cls
SetLocal EnableExtensions EnableDelayedExpansion
	For %%i In ("Z:\Box_In\~y??????.???") Do (
		Set /P val=<"%%i"
		Set "val1=!val:~18,3!"
		Set "val2=!val:~24,2!"
		Echo !val1! !val2!   %%i
	)
Pause
Exit /B 0

Если хочется увидеть на экране первую строку, то в Echo её надо взять в кавычки, так как символ "|" служебный

Код:

		Call Echo %%val1%% %%val2%%   %%i   "%%val%%"

или так:

Код:

@Echo Off
cls
	For %%i In ("Z:\Box_In\~y??????.???") Do Set /P val=<"%%i" &Call :OutFirst %%val:~18,3%% %%val:~24,2%% %%i
Pause
Exit /B 0

:OutFirst
	Echo %1 %2  %3
Exit /B