CMD/BAT - [решено] Как получить только значения реестра cmd

Iska · Отправлено: **13:05, 26-01-2016** | #2

Ну, например:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

>nul chcp 1251
for /f "usebackq tokens=3" %%i in (
	`reg.exe query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "DefaultUserName" ^| find.exe /i "DefaultUserName"`
) do set sDefaultUserName=%%i
>nul chcp 866

if defined sDefaultUserName (
	echo [%sDefaultUserName%]
) else (
	echo Not found [DefaultUserName] parameter in [HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon] subkey.
)

endlocal
exit /b 0

NeformalDron · Отправлено: **13:23, 26-01-2016** | #3

Спасибо огромное)))

Цитата Iska:

Ну, например:
Скрытый текст »

NeformalDron · Отправлено: **07:50, 28-01-2016** | #4

Всё вроде отлично. Код работает. Но есть один нюанс. При попытке изменить имя пользователя, осуществляющего автоматический вход в систему командой "wmic useraccount where name=’%sDefaultUserName%’ call rename Olen" получаю ответ "Отсутствуют экземпляры класса. :-(

Iska · Отправлено: **08:05, 28-01-2016** | #5

Цитата NeformalDron:

При попытке изменить имя пользователя, осуществляющего автоматический вход в систему командой "wmic useraccount where name=’%sDefaultUserName%’ call rename Olen" получаю ответ "Отсутствуют экземпляры класса. :-( »

Покажите Ваш код.

NeformalDron · Отправлено: **09:43, 28-01-2016** | #6

Цитата:

@echo off
setlocal enableextensions enabledelayedexpansion

>nul chcp 1251
for /f "usebackq tokens=3" %%i in (
`reg.exe query "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "DefaultUserName" ^| find.exe /i "DefaultUserName"`
) do set sDefaultUserName=%%i
>nul chcp 866

if defined sDefaultUserName (
echo [%sDefaultUserName%]
) else (
echo Not found [DefaultUserName] parameter in [HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon] subkey.
)
wmic useraccount where name=’%sDefaultUserName%’ call rename Olen
endlocal
exit /b 0

Если обрисовать суть задачи, то мне необходимо на ПК изменить имя пользователя, осуществляющего автоматический вход в систему. Имя пользователя заранее неизвестно и на разных ПК задано рэндомно. И необходимо массово "причесать" под единый стандарт.

Батник будет применяться локально.

Iska · Отправлено: **11:41, 28-01-2016** | #7

NeformalDron, как минимум замените Ваши «неправильные» кавычки на обычные одинарные. А ещё лучше — обрамите и всё условие двойными:

Код:

wmic.exe UserAccount where "Name='%sDefaultUserName%'" call rename Olen

NeformalDron · Отправлено: **11:52, 28-01-2016** | #8

Да)))) Обрамить всё условие помогло. Спасибо огромное