[Iska]

Пробуйте:

Скрытый текст

Код:

Option Explicit

Dim strSourceFile
Dim arrNames
Dim strContent


strSourceFile = "G:\css\cstrike\config.cfg"

arrNames = Array("grey", "silver", "blue", "red", "yellow")

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FileExists(strSourceFile) Then
		With .OpenTextFile(strSourceFile)
			strContent = .ReadAll()
			.Close
		End With
		
		With WScript.CreateObject("VBScript.RegExp")
			.MultiLine = True
			.IgnoreCase = True
			.Pattern = "^(name +)(.*)$"
		
			If .Test(strContent) Then
				Randomize Timer
				
				strContent = .Replace(strContent, "$1""" & arrNames(Int((UBound(arrNames) - LBound(arrNames) + 1) * Rnd + LBound(arrNames))) & """")
			Else
				WScript.Echo "Can't find pattern [" & .Pattern & "] in source file [" & strSourceFile & "]."
				WScript.Quit 2
			End If
		End With
		
		With .CreateTextFile(strSourceFile, True)
			strContent = .Write(strContent)
			.Close
		End With
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

[kot318]

Спасибо, теперь имя автоматически меняется перед входом в Контр страйк, вот пример, может кому нибудь ещё пригодится.
Спасибо!!!!
А то не интересно под одним ником вечно играть.

1) Запускаем: start.bat

Код:

start /w wscript.exe "G:\css\start.vbs" 
G:\css\hl.exe -game cstrike -steam -noforcemparms -noforcemaccel

2) start.vbs

Код:

Option Explicit

Dim strSourceFile
Dim arrNames
Dim strContent

strSourceFile = "G:\css\cstrike\config.cfg"

arrNames = Array(".mQ!", "coffee", "FasTiK", "oNe", "Sk1pe", "zEfN", "fromJkeee", "O_o", "LomaL cTek", "whOo", "aimbat", "QweRez", "icemaN", "Qqoffe", "Donjkeee", "Don1", "GaZ", "BeJIuKuu", "okeeey", "funny", "cerber", "efes", "R@MZE$$", "Arhangel", "maN1aK x_O", "furyy", "VeNoM1K", "Zoom^eR", "X-Team", "Z(o_O)M", "GamEOveR", "SurpriSe", "6y6JIuk", "4ekHyTbIu", "M@$ter Bit", "Quattro", "STRELOK", "Serial killer", "YAMAHA", "Loxnes", "Fatherv", "@RTEMK@", "BOND 007", "TauRus", "easy frag", "CuCe4Ka", "coco", "Pro100i", "~B@ND!T~", "6yM_6yM", "Inkognito", "BONGO", "Iguana", "3aHo3a", "policeman", "+Alucard+", "ANTILOL", "Dark", "Painkiller", "nTu4ko", "Fallen AngeL", "MiNi_ZLoB", "SPONGE BOB", "AnGeL", "S.T.A.L.K.E.R", "Сherry" )

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FileExists(strSourceFile) Then
		With .OpenTextFile(strSourceFile)
			strContent = .ReadAll()
			.Close
		End With
		
		With WScript.CreateObject("VBScript.RegExp")
			.MultiLine = True
			.IgnoreCase = True
			.Pattern = "^(name +)(.*)$"
		
			If .Test(strContent) Then
				Randomize Timer
				
				strContent = .Replace(strContent, "$1""" & arrNames(Int((UBound(arrNames) - LBound(arrNames) + 1) * Rnd + LBound(arrNames))) & """")
			Else
				WScript.Echo "Can't find pattern [" & .Pattern & "] in source file [" & strSourceFile & "]."
				WScript.Quit 2
			End If
		End With
		
		With .CreateTextFile(strSourceFile, True)
			strContent = .Write(strContent)
			.Close
		End With
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

[Iska]

kot318, старайтесь не использовать имён пакетных файлов и скриптов, совпадающих с внутренними или внешними командами. Замените «start» в «start.bat» и «start.vbs» на что-либо иное.