[Iska]

Начнём с этого:

Но существуют несколько процессов, которые винда сама завершить не может и подвисает. »

Каких именно процессов? Почему не может?

[krokradio]

Каких именно процессов? Почему не может? »

При попытке перезагрузить стандартными средствами процедура доходит до появления логотипа винды и на этом останавливается. Не виснет полностью. Просто переливается. Какой-то из процессов остается незакрытым и мешает ей уйти в перезагрузку. Всего там 47 процессов. Какой именно из них держит - извините, не помню. Автоматизацию проводил мой отец 8 лет назад. Это что-то связанное с защитой от дурака. Возможно процесс блокировки ввода. Знаю точно, что скрипт http://forum.oszone.net/post-1888484-3.html проблему решает. Проверял сегодня. Если же имя процесса очень критично - попробую завтра вытянуть из отца, хотя сомневаюсь, что вспомнит. Возраст.

[Iska]

Рекомендую всё-таки:

а) указать название и версию Вашей ОС;
б) попросить модераторов перенести тему в раздел, соответствующий ОС, и там решать проблему с поиском данного процесса.

По поводу скрипта: в Вашем случае его использование фактически ничем не отличается от применения одной-единственной команды «shutdown.exe /r /f».

[krokradio]

указать название и версию Вашей ОС »

Win XP SP2 x86 чистая лицензионная.

По поводу скрипта: в Вашем случае его использование фактически ничем не отличается от применения одной-единственной команды «shutdown.exe /r /f» »

В таком случае я бы сам добавил строку перезагрузки в http://forum.oszone.net/post-1888484-3.html и все. Но мне важна автоматизация. Автоматический опрос и сверка времени создания лог-файла. «shutdown.exe /r /f» с этим не справится :-).

[Iska]

В таком случае я бы сам добавил строку перезагрузки в http://forum.oszone.net/post-1888484-3.html »

Туда параметр «/f» не нужен.

После загрузки винды с задержкой в 10 минут запускается скрипт »

Как будете реализовывать запуск?

идет проверка времени создания файла »

и запускается снова через 20 минут. »

Полагаю, в этом случае речь должна вестись о времени последней модификации файла, а не о времени создания.

На WSH:

читать дальше »

Код:

Option Explicit

Dim strSourceFolder

Dim dtNow
Dim strFile


strSourceFolder = "E:\Air\log"

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strSourceFolder) Then
		WScript.Sleep 10 * 60 * 1000
		
		Do
			dtNow = Now()
			strFile = .BuildPath(strSourceFolder, CStr(Year(dtNow)) & "-" & Right("00" & CStr(Month(dtNow)), 2) & "-" & Right("00" & CStr(Day(dtNow)), 2) & ".log")
			
			If .FileExists(strFile) Then
				If Abs(DateDiff("n", dtNow, .GetFile(strFile).DateLastModified)) > 70 Then
					ShutdownSystem
				End If
			Else
				ShutdownSystem
			End If
			
			WScript.Sleep 20 * 60 * 1000
		Loop
	Else
		WScript.Echo "Source folder [" & strSourceFolder & "] not found."
		WScript.Quit 1
	End If
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub ShutdownSystem()
	Dim objSWbemObjectEx
	
	With WScript.CreateObject("WbemScripting.SWbemLocator")
		.Security_.Privileges.AddAsString "SeShutdownPrivilege", True
		
		For Each objSWbemObjectEx In .ConnectServer(".", "root\cimv2").ExecQuery("SELECT * FROM Win32_OperatingSystem")
			objSWbemObjectEx.Win32Shutdown 6
		Next
	End With
End Sub
'=============================================================================

Используется перезагрузка с принудительным снятием процессов. «WScript.Sleep 10 * 60 * 1000» — «с задержкой в 10 минут». Если в самом скрипте не нужна — закомментируйте или удалите.

[krokradio]

Как будете реализовывать запуск? »

Возможно автозапуск WSH timer как например такой (http://www.sql.ru/forum/419055/wsh-timer)

Полагаю, в этом случае речь должна вестись о времени последней модификации файла, а не о времени создания. »

Совершенно верно. В первом абзаце указал

информация о времени последнего изменения файла постоянно меняется »

а в четвертом перепутал

проверка времени создания файла »

. Прошу прощения.

На сколько я понимаю (возможно ошибаюсь, не судите строго), вы в скрипте задаете в условии проверку наличия папки

strSourceFolder = "E:\Air\log" With WScript.CreateObject("Scripting.FileSystemObject") If .FolderExists(strSourceFolder) Then WScript.Sleep 10 * 60 * 1000 »

Эта папка существует всегда по умолчанию. А проверить нужно именно наличие в ней созданного в этот день лог-файла формата ГГГГ-ММ-ЧЧ.LOG

Используется перезагрузка с принудительным снятием процессов. «WScript.Sleep 10 * 60 * 1000» — «с задержкой в 10 минут». »

Нужна.

[Iska]

На сколько я понимаю … вы в скрипте задаете в условии проверку наличия папки »

Да.

Эта папка существует всегда по умолчанию. »

А вдруг! Данная проверка ничем не вредит.

А проверить нужно именно наличие в ней созданного в этот день лог-файла формата ГГГГ-ММ-ЧЧ.LOG »

Код: strFile = .BuildPath(strSourceFolder, CStr(Year(dtNow)) & "-" & Right("00" & CStr(Month(dtNow)), 2) & "-" & Right("00" & CStr(Day(dtNow)), 2) & ".log") If .FileExists(strFile) Then … »

Возможно автозапуск WSH timer как например такой (http://www.sql.ru/forum/419055/wsh-timer) »

Вам это не нужно:

Код: Do … WScript.Sleep 20 * 60 * 1000 Loop »

Я имел в виду — если Вы, например, будете запускать скрипт из Планировщика задач и в нём же сделаете отсроченный на двадцать десять минут запуск, тогда удалите:

Код:

WScript.Sleep 10 * 60 * 1000

Если без отсрочки запуска — тогда оставьте эту десятиминутную паузу в начале скрипта.

[krokradio]

Понял. Спасибо. Сейчас поставлю на проверку. О результате отпишусь.

[Iska]

и в нём же сделаете отсроченный на двадцать минут запуск, »

Прошу прощения, разумеется, следует читать — «отсроченный на десять минут».