[amel27]

пример вывода в 5 столбцов:

Код:

@echo off
SetLocal EnableDelayedExpansion
(
for /f "delims=-." %%a in ('dir/b/a-d kb*.msp') do (set "$a=%%a   "
  set "$s=!$s!KB!$a:~2,9!"& set/a $i+=1
  if !$i! equ 5 echo:!$s!& set "$s="& set/a $i=0
))& echo:!$s!

pause>nul

[Foreigner]

sov44,

Код:

dir /d /a-d *.mst | findstr "\.mst"

[sov44]

amel27, супер! поясните пожалуйста код.

[amel27]

поясните пожалуйста код »

Код:

@echo off
SetLocal EnableDelayedExpansion

for /f "delims=-." %%a in ('dir/b/a-d kb*.msp') do (
  set "$a=%%a   "          &rem: добавляем в конец имени файла
                            rem: пробелы [для выравнивания столбцов]
  set "$s=!$s!KB!$a:~2,9!" &rem: добавляем в конец текущей строки [$s]
                            rem: "KB" и часть имени файла, начиная с 3-го
                            rem: символа длиной 9 символов [включая пробелы]
  set/a $i+=1              &rem: увеличиваем счетчик столбцов [$i]
  if !$i! equ 5 (           rem: если это последний столбец, то:
    echo:!$s!              &rem:   выводим строку [$s]
    set "$s="              &rem:   зачищаем переменную строки [$s]
    set/a $i=0             &rem:   обнуляем счетчик столбцов [$i]
  )
)
echo:!$s!                  &rem: выводим неполный остаток строки [$s]

[Foreigner]

sov44,
Вариант с верхним регистром:

Код:

@echo off

for /f "tokens=*" %%i in ('"dir /d /a-d *.msp | find "msp""') do (

    for /f "tokens=2 delims=:" %%j in ('"2>&1 find /c /v "" "%%i""') do echo %%j

)