[amel27]

как-то так:

Код:

@echo off
SETLOCAL EnableDelayedExpansion

set "MyProgPath=c:\Program Files\My Program"
set "RemotePath=\\MyServer\Share"

for /f "usebackq tokens=2-4 delims==. " %%a in ("%MyProgPath%\version.inf") do (
  set "$b=0%%b"& set "$c=0%%c"& set "$v=%%a!$b:~-2!!$c:~-2!"
)
for /f "tokens=1-3 delims=update." %%a in ('dir /b/a-d "%RemotePath%\update*.exe"') do (
  set "$b=0%%b"& set "$c=0%%c"& set "$n=%%a!$b:~-2!!$c:~-2!"
  if !$n! gtr !$v! copy /b/y/v/z "%RemotePath%\update%%a.%%b.%%c.exe" "%MyProgPath%\"
)

[hant]

Спасибо! работает, но скачивает все файлы выше версией, а хотелось бы реализовать так чтобы только один файл который выше версией.
т.е. версия проги 1.0.2 , и надо скачать файл update1.0.3
если не трудно подскажите что подправить в коде надо.
заранее благодарю!

[amel27]

хотелось бы реализовать так чтобы только один файл который выше версией »

Код:

@echo off
SETLOCAL EnableDelayedExpansion

set "MyProgPath=c:\Program Files\My Program"
set "RemotePath=\\MyServer\Share"

for /f "usebackq tokens=2-4 delims==. " %%a in ("%MyProgPath%\version.inf") do (
  set "$b=0%%b"& set "$c=0%%c"& set "$v=%%a!$b:~-2!!$c:~-2!"
)& set "$m=999999"& set "$f="
for /f "tokens=1-3 delims=update." %%a in ('dir /b/a-d "%RemotePath%\update*.exe"') do (
  set "$b=0%%b"& set "$c=0%%c"& set "$n=%%a!$b:~-2!!$c:~-2!"
  if !$n! gtr !$v! if !$n! lss !$m! set "$m=!$n!"& set "$f=update%%a.%%b.%%c.exe"
)
if defined $f copy /b/y/v/z "%RemotePath%\!$f!" "%MyProgPath%\"

[hant]

Огромное спасибо!!! весьма признателен Вам за Вашу помошь!
Все работает!