[amel27]

когда есть пробелы, например s="две книги" то значение переменной присваивается вместе с кавычками »

Вы о чем?.. Вот пример VBS, который выводит всё БЕЗ кавычек:

Код:

s1="книга"
s2="две книги"

WScript.Echo s1
WScript.Echo s2

[Bint]

Код:

Dim objDesktop, objLink, objFSO
Dim DesktopFld1, objShell1, objFSO1 'для удаления'

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
objDesktop = WshShell.SpecialFolders("Desktop")

If not objFSO.FileExists(objDesktop & "\InOutD.lnk") Then
Set objLink = WshShell.CreateShortcut(objDesktop & "\InOutD.lnk")

objLink.IconLocation = "J:\InOutD\inoutd.ico"
objLink.TargetPath = "J:\InOutD\inoutd.exe -T -cJ:\InOutD\config.fpw"
objLink.WindowStyle = 1
objLink.WorkingDirectory = "J:\InOutD"
objLink.Save
End If

Путь к ярлыку в таком случае добавляется с кавычками и соответственно не работает.
Если делать:

Код:

objLink.TargetPath = "J:\InOutD\inoutd.exe"

то в свойствах ярлыка путь будет без кавычек.

[amel27]

может так?

Код:

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objWSH = WScript.CreateObject("WScript.Shell")

strDesktop = objWSH.SpecialFolders("Desktop")

If Not objFSO.FileExists(strDesktop & "\InOutD.lnk") Then
  Set objLink = objWSH.CreateShortcut(strDesktop & "\InOutD.lnk")

  objLink.IconLocation = "J:\InOutD\inoutd.ico"
  objLink.TargetPath = "J:\InOutD\inoutd.exe"
  objLink.Arguments  = "-T -cJ:\InOutD\config.fpw"
  objLink.WindowStyle = 1
  objLink.WorkingDirectory = "J:\InOutD"
  objLink.Save
End If

[Bint]

спасибо, помогло