[madmasles]

А можно увидеть образец того, что есть, того что нужно получить и свой скрипт.

[u-Art]

Образец строки:

2,541
В наличии: мало
BK500-RS CS


кусок скрипта обработки в блокноте:

WinActivate("work.txt - Блокнот","")
WinWaitActive ("work.txt - Блокнот","")
Send("{CTRLDOWN}a{CTRLUP}{DEL}") ; Очистка блокнота
Send("{CTRLDOWN}v{CTRLUP}")
MouseClick("left", 9, 51, 1, 0) ; Клик в начало Блокнота
Send("{DEL}") ; Удаляем ТАб
Send("{SHIFTDOWN}") ; Начало выделения цены
MouseMove(66,51,1)
MouseDown("left")
MouseUp("left")
Send("{SHIFTUP}") ; Конец выделения цены
Send("{CTRLDOWN}c{CTRLUP}") ; Копируем цену обратно в буфер
$cena = ClipGet()

Обработка если нет запятой, в случае с запятой сначала три клика и удаление запятой.

[madmasles]

Я правильно понял, что из файла с текстом вида

1 строка - 2,541 2 строка - В наличии: мало 3 строка - BK500-RS CS

нужно получить в другой файл выборку всех элементов типа 2,541?
Вы бы скопировали фрагмент Вашего исходного текста и здесь привели.

[u-Art]

Я правильно понял, что из файла с текстом вида »

Да, верно, только обработку желательно вести непосредственно скриптом, т.к. через файл или блокнот уходит много времени.
Изначально текст в буфере, к сожалению на странице форума не отобразился отступ символа ТАБ перед 2,541

[Creat0R]

Код:

$sText = ClipGet()
$sResult = StringRegExpReplace($sText, "(?s)\s+?([0-9,?]*).*", "\1")

MsgBox(64, 'Title', $sResult)

[madmasles]

У меня первоначальный вариант был длиннее, плохо разбираюсь в "pattern", но воспользовавшись как всегда идеальной формулой от Creat0R

$sResult = StringRegExpReplace($sText, "(?s)\s+?([0-9,?]*).*", "\1") »

получил вот такой вариант:

Код:

#include <File.au3>

$file1 = "1.txt"
$file2 = "2.txt"

FileOpen($file1, 0)
FileOpen($file2, 2)
$CountLines = _FileCountLines($file1)
For $i = 1 To $CountLines
    $sText = FileReadLine($file1, $i)
    $sResult = StringRegExpReplace($sText, "(?s)\s+?([0-9,?]*).*", "\1")
    If StringLen($sResult) > 0 Then
        FileWrite($file2, $sResult & @CRLF)
    EndIf
Next
FileClose($file1)
FileClose($file2)

1.txt это файл для обработки, 2.txt это файл-результат.
Хочу попробовать то же самое сделать через массив, вроде намного быстрее получается.

[Creat0R]

получил вот такой вариант: »

Так будет правильнее:

Код:

$sFile1 = "1.txt"
$sFile2 = "2.txt"

$hFile1 = FileOpen($sFile1, 0)
$hFile2 = FileOpen($sFile2, 2)

$i = 0

While 1
    $i += 1
    $sText = FileReadLine($hFile1, $i)
    If @error <> 0 Then ExitLoop

    $sResult = StringRegExpReplace($sText, "\s+?([0-9,?]+).*", "\1")
    If @extended > 0 Then FileWriteLine($hFile2, $sResult)
WEnd

FileClose($hFile1)
FileClose($hFile2)

[u-Art]

но воспользовавшись как всегда идеальной формулой от Creat0R »

Благодарствую!
Действительно красиво, осталось решить проблему с удалением запятой, попробую поковыряться с функциями.

[Creat0R]

Или так:

Код:

$sFile1 = "1.txt"
$sFile2 = "2.txt"

$sText = FileRead($sFile1)
$aResult = StringRegExp($sText, "(?s)\s+?([0-9,?]+)", 3)

$hFile2 = FileOpen($sFile2, 2)

For $i = 0 To UBound($aResult)-1
    FileWriteLine($hFile2, StringReplace($aResult[$i], ",", ""))
Next

FileClose($hFile2)

осталось решить проблему с удалением запятой »

См. мой последний пост.