[Iska]

Есть файл fb2. »

Образец файла упакуйте в архив и приложите к сообщению, либо выложите архив на RGhost/Яндекс.Диск. Укажите пример строк:

начальную строку"Серж", конечную строку "Глава 2" »

для выложенного образца. Желательно также, чтобы образец содержал указанное Вами:

Таких кусков текста может быть несколько. »

[namin78]

Вот примерчик.http://forum.oszone.net/attachment.p...1&d=1484808471

[Iska]

Попробуйте так (WSH/VBScript):

Скрытый текст

Код:

Option Explicit

Dim strSourceFile
Dim strFromString, strToString

Dim objDomDocument
Dim objXMLDOMElement

Dim boolDeletion


strSourceFile = "C:\Мои проекты\0037\пример\пример.fb2"

strFromString = InputBox("From string") ' "Rinat-106 M"
strToString   = InputBox("To string")   ' "С нами: 3 года 2 месяца"

Set objDomDocument = WScript.CreateObject("Microsoft.XMLDOM")
objDomDocument.load(strSourceFile)

boolDeletion = False

For Each objXMLDOMElement In objDomDocument.selectNodes("/FictionBook/body/section/p")
	If Not boolDeletion Then
		If StrComp(objXMLDOMElement.text, strFromString, vbTextCompare) = 0 Then
			objXMLDOMElement.parentNode.removeChild objXMLDOMElement
			boolDeletion = True
		End If
	Else
		objXMLDOMElement.parentNode.removeChild objXMLDOMElement
		
		If StrComp(objXMLDOMElement.text, strToString, vbTextCompare) = 0 Then
			boolDeletion = False
		End If
	End If
Next

objDomDocument.Save strSourceFile
Set objDomDocument = Nothing

WScript.Quit 0

[namin78]

Все работает. Огромное спасибо. Единственное вопрос по имени файла(пример.fb2), какой код добавить в начале в скрипт, чтобы скрипт работал с файлом, который я перетащил на него?

Разобрался сам. Огромное спасибо еще раз.

[Iska]

чтобы скрипт работал с файлом, который я перетащил на него? »

Примерно так (не проверялось):

Скрытый текст

Код:

Option Explicit

Dim strSourceFile
Dim strFromString, strToString

Dim objXMLDOMElement

Dim boolDeletion


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	If WScript.CreateObject("Scripting.FileSystemObject").FileExists(strSourceFile) Then
		strFromString = InputBox("From string") ' "Rinat-106 M"
		strToString   = InputBox("To string")   ' "С нами: 3 года 2 месяца"
		
		With WScript.CreateObject("Microsoft.XMLDOM")
			.load(strSourceFile)
			
			boolDeletion = False
			
			For Each objXMLDOMElement In .selectNodes("/FictionBook/body/section/p")
				If Not boolDeletion Then
					If StrComp(objXMLDOMElement.text, strFromString, vbTextCompare) = 0 Then
						objXMLDOMElement.parentNode.removeChild objXMLDOMElement
						boolDeletion = True
					End If
				Else
					objXMLDOMElement.parentNode.removeChild objXMLDOMElement
					
					If StrComp(objXMLDOMElement.text, strToString, vbTextCompare) = 0 Then
						boolDeletion = False
					End If
				End If
			Next
			
			.Save strSourceFile
		End With
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 2
	End If
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

[namin78]

Iska, Вечер добрый, Вы мне недавно помогли(за что спасибо).
Есть еще одна просьба. Тот же fb2 файл, очень многие диалоги, начинаются с маленькой буквы(должны с большой).

Код:

<p>— и что же? — спросил начальник абордажной команды, здоровенный бугай, с татуировкой на всю лысую голову, с изображением взбешённого осьминога.</p>
<p>— что? А вы заметили, сколько в городе на данный момент ушастых? Кстати, все они моряки, причём военные. Нашего капитана и его помощника, окучивают на предмет покупки кораблей, только цены дают… и требуют обучить их магов для пользования движителей, причём без всякой охраной клятвы.</p>
<p>— кэп запёрся в своей вотчине и никуда носа не кажет. Поговаривают даже стычка у него была с ребятами Мика. — влез в разговор ещё один из «печальных» пиратов.</p>

Надо проверить в начале строки наличие длинного тире, если есть, то проверить какая буква идет через пробел после тире, если строчная, поменять на заглавную, если заглавная ни чего не делать.
Заранее спасибо.

[Iska]

какая буква идет через пробел после тире »

Там преимущественно неразрывные пробелы.

Примерно так: 0003.7z.

Оригинал будет сохранён в одноимённый файл с расширением .bak. Если таковой уже существовал — он будет перезаписан без подтверждения.

[Iska]

И, похоже, это ещё не конец. Там и тире не все длинные .

Код:

<p>- Ты глянь какая громадина в косынке в таверну-то забрела?</p>
…
<p>- но как такое может быть?*— удивлённо взирает на безопастника император.</p>

и т.д.

Добавил уточнение в предыдущий код.

[mwz]

на безопастника »

Н-да, в том тексте с грамотностью вообще не всё, мягко говоря, в порядке: споткнувшись на этом пассаже, посмотрел и остальные приведённые здесь строки того текста.