[megaloman]

rider42, не надо в путях указывать последний слэж

Код:

Set "BoxIn=D:\Download\Video"
Set "BoxOut=D:\Download\!Vid2CHG"

А во время скрипта какие-либо ошибки выскакивают?

[rider42]

megaloman,
Ещё раз спасибо. Убрал.

Как я выяснил ошибка с теми файлами, в названии которых есть символ

Код:

—

Такие файлы просто не обрабатываются.

Скопировать из командной строки почему-то не выходит, так что извиняюсь за сриншот
https://lh3.googleusercontent.com/-c...0_23-43-43.png

[megaloman]

Как я выяснил ошибка с теми файлами, в названии которых есть символ »

Символ как символ, если Вы, конечно, меня не обманываете. Дайте поиграться с именами Ваших файлов. Проделайте в командной строке команду

Код:

dir "D:\Download\Video\*.mp4" /B /A:-D >D:\яяяяяяяяяяя.txt

Получившийся файл прикрепите к сообщению.
У меня создалось впечатление, что Вы излагаете неверную версию. Моё предположение:
Файл "Ковёр.mp4" благополучно переименовался в 11.mp4
После обработки файл 11.mkv не создался
Файл 11.mp4 благополучно переименовался в "Ковёр.mp4"
Файл 11.mkv не переименовался в "Ковёр.mkv", так как не найден

Доработал батник, чтобы он делал лог-файл, чтобы можно было понять, что и как обработалось, а что нет

Код:

@Echo Off
cls
	Set "BoxIn=D:\Download\Video"
	Set "BoxOut=D:\Download\!Vid2CHG"

	Set "ExtIn=mp4"
	Set "ExtOut=mkv"
	
	Set "LogBat=%~dpnx0.log"
	
	If Not Exist "%BoxOut%" Md "%BoxOut%"

	Set /A NNN=11
	>"%LogBat%" Echo    %Date% %Time%

	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\*.%ExtIn%" /b /a:-d /O:D`) DO (

		>>"%LogBat%" (Echo: &Echo === begin "%BoxIn%\%%f")
		Del "%BoxOut%\%NNN%.%ExtOut%" >nul 2>&1

		Call :MyMove "%BoxIn%\%%f" "%BoxIn%\%NNN%.%ExtIn%"
rem Обработка программами
		Echo "%BoxIn%\%%f"
		Echo "%BoxIn%\%NNN%.%ExtIn%"
		Echo:
		Copy "%BoxIn%\%NNN%.%ExtIn%" "%BoxOut%\%NNN%.%ExtOut%" >nul
rem ---------------------

		Call :MyMove "%BoxIn%\%NNN%.%ExtIn%" "%BoxIn%\%%f"
		Call :MyMove "%BoxOut%\%NNN%.%ExtOut%" "%BoxOut%\%%~nf.%ExtOut%"
	)
pause
GoTo :Eof

:MyMove
		If Not Exist %1 (
			>>"%LogBat%" Echo --- not found %1
			Exit /B 2			
		)

		>>"%LogBat%" 2>&1 Move /Y %1 %2 
		If Exist %2 (
			>>"%LogBat%" Echo +++ success Move /Y %1 %2
		) Else (
			>>"%LogBat%" Echo --- failure Move /Y %1 %2
			>>"%LogBat%" Echo --- failure Move /Y %1 %2
		)
GoTo :Eof

Не забудьте удалить выделенную красным имитацию Вашей обработки и вставить свои программы
Лог-файл делается рядом с батником, с именем батника. Вы можете прописать его куда угодно с любым именем

[rider42]

megaloman, спасибо что продолжаете заморачиваться. Приложил к сообщению файлы.

[megaloman]

rider42, Похоже, в названиях присутствуют символы, не отражающиеся в 866 кодировке. Приложил переименованный vbs-скрипт, выполните его, полученный txt-файл приложите к сообщению.

[rider42]

rider42, Похоже, в названиях присутствуют символы, не отражающиеся в 866 кодировке. Приложил переименованный vbs-скрипт, выполните его, полученный txt-файл приложите к сообщению. »

Готово

[megaloman]

rider42,

Попробуйте вариант, у меня отрабатывает на Ваших наименованиях. Отличие - в одной строке CHCP

Код:

@Echo Off
cls
chcp 1251 >nul
	Set "BoxIn=D:\Download\Video"
	Set "BoxOut=D:\Download\!Vid2CHG"

	Set "ExtIn=mp4"
	Set "ExtOut=mkv"
	
	Set "LogBat=%~dpnx0.log"
	
	If Not Exist "%BoxOut%" Md "%BoxOut%"

	Set /A NNN=11
	>"%LogBat%" Echo    %Date% %Time%

	FOR /F "usebackq delims=" %%f IN (`2^>nul Dir "%BoxIn%\*.%ExtIn%" /b /a:-d /O:D`) DO (

		>>"%LogBat%" (Echo: &Echo === begin "%BoxIn%\%%f")

		Call :MyMove "%BoxIn%\%%f" "%BoxIn%\%NNN%.%ExtIn%"
		Del "%BoxOut%\%NNN%.%ExtOut%" >nul 2>&1

rem Обработка программами
		Echo "%BoxIn%\%%f"
		Echo "%BoxIn%\%NNN%.%ExtIn%"
		Echo:
		Copy "%BoxIn%\%NNN%.%ExtIn%" "%BoxOut%\%NNN%.%ExtOut%" >nul
rem ---------------------

		Call :MyMove "%BoxIn%\%NNN%.%ExtIn%" "%BoxIn%\%%f"
		Call :MyMove "%BoxOut%\%NNN%.%ExtOut%" "%BoxOut%\%%~nf.%ExtOut%"
	)
pause
GoTo :Eof

:MyMove
		If Not Exist %1 (
			>>"%LogBat%" Echo --- not found %1
			Exit /B 2			
		)

		>>"%LogBat%" 2>&1 Move /Y %1 %2 
		If Exist %2 (
			>>"%LogBat%" Echo +++ success Move /Y %1 %2
		) Else (
			>>"%LogBat%" Echo --- failure Move /Y %1 %2
			>>"%LogBat%" Echo --- failure Move /Y %1 %2
		)
GoTo :Eof

[rider42]

megaloman, огромное спасибо. Теперь всё работает. Правда в самой командной строке при отработке bat'ника вместо русского крякозябры, но в итоге с конечными файлами всё отлично.

[megaloman]

rider42,

Правда в самой командной строке при отработке bat'ника вместо русского крякозябры »

А оно Вам надо? Для этого есть лог-файл.

[rider42]

А оно Вам надо? Для этого есть лог-файл. »

Нее, ни разу. Просто подумал, что это надо озвучить на всякий случай. И ещё раз огромное спасибо!