[Creat0R]

как это можно реализовать через AutoIt ? »

Можно попробовать посылать запрос «http://save2go.ru/parse/?url=тут ссылка».

P.S
Есть сервис получше для этого, он извлекает все возможные флэш-ссылки на странице.

[madmasles]

shadowbat,
Так можно попробовать:

Код:

#include <IE.au3>
#include <Array.au3>

Dim $aUrl[3] = ['http://mult.ru/projects/mas/mults/mult_7.html', _
        'http://mult.ru/projects/mas/mults/mult_8.html', _
        'http://mult.ru/projects/mas/mults/mult_9.html']
Dim $aLinks[1][3]
$j = 0
$oIE = _IECreate('http://save2go.ru/')

For $i = 0 To UBound($aUrl) - 1
    $oForm = _IEFormGetCollection($oIE, 0)
    $oInput = _IEFormElementGetObjByName($oForm, 'url')
    _IEFormElementSetValue($oInput, $aUrl[$i])
    _IEFormSubmit($oForm)
    $oDiv = _IEGetObjById($oIE, 'pageFiles')
    $j += 1
    ReDim $aLinks[UBound($aLinks) + 1][3]
    $aLinks[$j][0] = $aUrl[$i]
    $aLinks[$j][1] = _IEPropertyGet($oIE, 'locationurl')
    $aLinks[$j][2] = StringRegExpReplace(_IEPropertyGet($oDiv, 'innerhtml'), '(?s).*?target=_blank>(http://.*?)</A></B>?.*', '\1')
Next
_IEQuit($oIE)
$aLinks[0][0] = UBound($aLinks) - 1
_ArrayDisplay($aLinks)

[Creat0R]

Так можно попробовать »

Для этого IE не нужен:

Код:

#include <Array.au3>

Dim $aUrl[4] = [3, _
        'http://mult.ru/projects/mas/mults/mult_7.html', _
        'http://mult.ru/projects/mas/mults/mult_8.html', _
        'http://mult.ru/projects/mas/mults/mult_9.html']

Dim $aLinks[$aUrl[0]+1]
$aLinks[0] = $aUrl[0]

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $aLinks[$i] = StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1')
Next

_ArrayDisplay($aLinks)

[shadowbat]

Creat0R
1. немного не понял, что имелось ввиду.
по Вашей ссылке

Невозможно получить данные со страницы сайта

если Вы предлагаете руками забивать все адреса, то это невозможно.

2. по поводу сервиса "получше" - к сожалению он ничего не находит по скармливаемым ссылкам. а save2go дает реальную ссылку на ролик.

3. madmasles отличное решение!
только результат выдается вот так:
http://www.site.ru/...s/video/0001.f4v, т.е. урезанно.
как это вылечить?

пробовал сократить табличку для вывода

читать дальше »

Код:

For $i = 0 To UBound($aUrl) - 1
    $oForm = _IEFormGetCollection($oIE, 0)
    $oInput = _IEFormElementGetObjByName($oForm, 'url')
    _IEFormElementSetValue($oInput, $aUrl[$i])
    _IEFormSubmit($oForm)
    $oDiv = _IEGetObjById($oIE, 'pageFiles')
    $j += 1
    ReDim $aLinks[UBound($aLinks) + 1][3]
    $aLinks[$j][2] = StringRegExpReplace(_IEPropertyGet($oDiv, 'innerhtml'), '(?s).*?target=_blank>(http://.*?)</A></B>?.*', '\1')
Next
_IEQuit($oIE)
$aLinks[0][0] = UBound($aLinks) - 1
_ArrayDisplay($aLinks)

но все хоть и количество выдаваемых столбцов уменьшилось с 3х до 1го. все равно сама таблица имеет формат 3х3, а самое главное - выходная ссылка видимо длинная или как... выдается в таком урезанном формате

Код:

http://www.site.ru/...s/video/0001.f4v

________________________________________________
4. Creat0R - как раз то, что нужно. ссылка получается полная, только перед ней ставится колонка Row
[2]|http://www....
как ее удалить, чтобы для копирования осталась чистая ссылка? (конечно можно и в ворде через замену но для чистоты эксперимента по=хорошему нужно здесь)

P.S. получился мини-парсер (сегодня узнал это слово) - мне кажется отличный вариант

[madmasles]

Creat0R,
Согласен, с Вашим вариантом все это сделать можно гораздо быстрее и удобнее.


shadowbat,
В моем варианте попробуйте заменить эту строку:

Код:

$aLinks[$j][2] = StringRegExpReplace(_IEPropertyGet($oDiv, 'innerhtml'), '(?s).*?href="(http://.*?)"\n?.*', '\1')

Но я бы на Вашем месте воспользовался вариантом Creat0R`a.

[Creat0R]

по Вашей ссылке »

Это был пример, вместо «тут ссылка» нужно подставить ссылку страницы с флэшками.

по поводу сервиса "получше" - к сожалению он ничего не находит по скармливаемым ссылкам »

Пример можно этих ссылок?

перед ней ставится колонка »

Это только при отображений, в массиве то их нет, вам нужно копировать список сразу в буфер? тогда так:

Код:

Dim $aUrl[4] = [3, _
        'http://mult.ru/projects/mas/mults/mult_7.html', _
        'http://mult.ru/projects/mas/mults/mult_8.html', _
        'http://mult.ru/projects/mas/mults/mult_9.html']

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF
Next

ClipPut(StringStripWS($sLinks, 3))

[madmasles]

Только перед ней ставится колонка Row [2]|http://www.... »

Или для сохранения в файл добавьте вначале скрипта #include <File.au3>, а в конце _FileWriteFromArray(@ScriptDir & '\MySuperLinks.txt', $aLinks, 1)

[shadowbat]

Пример можно этих ссылок?

http://www.teachvideo.ru/v/5471
http://iqcomp.ru/v/e2545

Отлично! благодарю за помощь! итого получилось 2 решения:
сохранение ссылок в буфер обмена:

Код:

Dim $aUrl[4] = [3, _
        'http://mult.ru/projects/mas/mults/mult_7.html', _
        'http://mult.ru/projects/mas/mults/mult_8.html', _
        'http://mult.ru/projects/mas/mults/mult_9.html']

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF
Next

ClipPut(StringStripWS($sLinks, 3))

сохранение ссылок в файл:

Код:

#include <File.au3>
#include <Array.au3>

Dim $aUrl[4] = [3, _
        'http://mult.ru/projects/mas/mults/mult_7.html', _
        'http://mult.ru/projects/mas/mults/mult_8.html', _
        'http://mult.ru/projects/mas/mults/mult_9.html']

Dim $aLinks[$aUrl[0]+1]
$aLinks[0] = $aUrl[0]

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $aLinks[$i] = StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1')
Next

_ArrayDisplay($aLinks)	
_FileWriteFromArray(@ScriptDir & '\MySuperLinks.txt', $aLinks, 1)

[Creat0R]

сохранение ссылок в файл »

Зачем городить огород:

Код:

Dim $aUrl = StringSplit( _
        'http://iqcomp.ru/v/e2545|' & _
        'http://teachvideo.ru/v/5471', _
        '|')

$sLinks = ""

For $i = 1 To $aUrl[0]
    $sHtml = BinaryToString(InetRead("http://save2go.ru/parse/?url=" & $aUrl[$i]))
    $sLinks &= StringRegExpReplace($sHtml, '(?s).*?<b><a href="(.*?)" target="_blank" onclick=".*">.*</a>.*', '\1') & @CRLF
Next

$sLinks = StringStripWS($sLinks, 3)

;В буфер обмена
ClipPut($sLinks)

;В файл
FileWrite(@ScriptDir & '\MySuperLinks.txt', $sLinks)

правда что то я не расмотрел там 800 ссылок