[Iska]

в большинстве с них в конце цифры »

с каждой строки в которой есть цифры »

Определитесь, что ищем/извлекаем.

1. Ищем: строки, в конце которых цифры, или же — строки, в которых просто есть цифры в любом месте?
2. Извлекаем: только цифры или всю строку целиком?

[KooDI]

1. Ищем: строки, в конце которых цифры »

Цифры там всегда только в конце

2. Извлекаем: только цифры или всю строку целиком? »

Только цифры

[Iska]

KooDI, попробуйте так:

читать дальше »

Код:

Option Explicit


Dim strSourceFile
Dim objFSO
Dim objRegExp
Dim objTS

Dim strLine


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		Set objRegExp = WScript.CreateObject("VBScript.RegExp")
		Set objTS     = objFSO.CreateTextFile(strSourceFile & ".export.txt", True)
		
		objRegExp.Pattern = "\D*(\d+)$"
		
		With objFSO.OpenTextFile(strSourceFile)
			Do Until .AtEndOfStream
				strLine = .ReadLine()
				
				If objRegExp.Test(strLine) Then
					objTS.WriteLine objRegExp.Execute(strLine).Item(0).SubMatches(0)
				End If
			Loop
			
			.Close
		End With
		
		objTS.Close
		
		Set objTS     = Nothing
		Set objRegExp = Nothing
	Else
		WScript.Echo "Source file [" & strSourceFile & "] not found"
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: " & WScript.ScriptName & " <Source file>"
End If

WScript.Quit

[KooDI]

Это скрипт для исполняемого файла?
Какое имя надо дать файлу с текстом?

[Iska]

Это скрипт для исполняемого файла? »

Это скрипт WSH — Windows Script Host. Сохраните код скрипта в файл с расширением .vbs.

Какое имя надо дать файлу с текстом? »

Любое. Исходный файл указывается аргументом скрипта при запуске. Также можно просто перетащить исходный файл на скрипт. Результирующий файл получит имя целевого +«.export.txt».

[KooDI]

Спасибо. Задача решена, все очень легко и просто.