CMD/BAT - Создание скрипта подсчета по маске и вывода на экран через msg

romfus · Отправлено: **11:19, 08-08-2017** | #2

то есть вывел не общее количество файлов а именно города столько то файлов области столько то и иногорода столько то файлов

alpap · Конфигурация компьютера

Код:

@echo off
set "d=Z:\Printer\08.08.2017"
set "m1=34s_1*"
set "m2=34s_400139*"
set "m3=34s_400000*"
set "fe=.pdf"
<nul set /p=иногород=
dir /a-d/b "%d%\%m1%%fe%"|find /c /v ""
<nul set /p=область=
dir /a-d/b "%d%\%m2%%fe%"|find /c /v ""
<nul set /p=город=
dir /a-d/b "%d%\%m3%%fe%"|find /c /v ""
pause>nul

romfus · Отправлено: **11:42, 08-08-2017** | #4

Работает, а вот если через msg? реально так?

alpap · Конфигурация компьютера

Покрасивше:

Код:

@echo off
setlocal enabledelayedexpansion
set "d=Z:\Printer\08.08.2017"
set "m1=иногород=34s_1*"
set "m2=область=34s_400139*"
set "m3=город=34s_400000*"
set "fe=.pdf"
for /l %%n in (1 1 3) do for /f "tokens=1* delims==" %%a in ("!m%%n!") do (
 <nul set /p=%%~a=
 dir /a-d/b "%d%\%%~b%fe%"|find /c /v ""
)
pause>nul

с msg:

Код:

@echo off
setlocal enabledelayedexpansion
set "d=Z:\Printer\08.08.2017"
set "m1=иногород=34s_1*"
set "m2=область=34s_400139*"
set "m3=город=34s_400000*"
set "fe=.pdf"
for /l %%n in (1 1 3) do for /f "tokens=1* delims==" %%a in ("!m%%n!") do for /f "delims=" %%z in ('dir /a-d/b "%d%\%%~b%fe%"^|find /c /v ""') do msg * %%~a=%%z
pause>nul

romfus · Отправлено: **11:57, 08-08-2017** | #6

спасибо большое!

а вот если путь каждый день меняется. Можно ли как то автоматизировать в скрипте это? То есть сегодня путь Z:\Printer\08.08.2017 а завтра будет путь Z:\Printer\09.08.2017

alpap · Конфигурация компьютера

Допустим:
Z:\Printer\09.08.2017 - Z:\Printer\%date%, если всегда равно текущей или нет?

romfus · Отправлено: **12:11, 08-08-2017** | #8

да да . Точно. Спасибо. Работает

alpap · Конфигурация компьютера

если в папке "Z:\Printer" только одна единственная папка с датой, будет правильно работать и такой код:

Код:

@echo off
setlocal enabledelayedexpansion
set "d=Z:\Printer"
set "m1=иногород=34s_1*"
set "m2=область=34s_400139*"
set "m3=город=34s_400000*"
set "fe=.pdf"
for /l %%n in (1 1 3) do for /f "tokens=1* delims==" %%a in ("!m%%n!") do for /f "delims=" %%z in ('dir /a-d/b/s "%d%\%%b%fe%"^|find /c /v ""') do echo %%a=%%z
pause>nul

(поставил echo в вывод, поменяете)

romfus · Отправлено: **12:22, 08-08-2017** | #10

а можно указать чтоб еще в одной папке искало? то есть еще одну папку добавить для поиска? D:\IVC\Operators\Printer\Повестки\%date% и также по маскам выдавало тоже самое по 2 папкам? только маска будет уже другая 34P_400000*" это город 34P_400139* это область"

нет там не одна папка там много папок с датами