[megaloman]

4zz, Попробуйте переставить кавычки

Код:

:: Обрабатываемая папка
Set "Folder=%cd%"

:: папка назначения
Set "Out=%cd%"

И лучше бы Вы сформулировали Вашу задачу для оптимального решения

[alpap]

лучше бы »

лучше бы не использовать для работы с перемещением файлов одну и ту же папку и очень желательно при этом сам bat держать также не в папке где обрабатываются файлы.

[4zz]

Попробуйте переставить кавычки »

Ура! поехало!))
Спасибо!)

И лучше бы Вы сформулировали Вашу задачу для оптимального решения »

Задача простая - есть много файлов - счета за месяц обозванные по номерам домов или фамилиям, их нужно разбросать по одноименным папкам, чтобы чуть позже дополнить эти папки другими файлами этих же собственников/домов.

А может можно как-то упростить/автоматизировать дополнительно?

Допустим есть файлы test и test1 - это один и тот же собственник, просто разные счета - их нужно в одну папку - в моем варианте я батником создаю папки для счетов типа test и отдельно папки для счетов типа test1 применив к их созданию MD "%Out%\!ti:~0,-1%!", т.е. убираю единичку и создаю те же папки, что и в первом случае, но в другом месте, а потом вручную переношу (совмещаю) однотипные папки. Получаю, например папку TEST и в ней файлы test и test1

[4zz]

Надо конкретика, а не абстракция »

Приложил рисунки:
1.Был список файлов
2.Образованы папки
3. Список файлов в папках

[megaloman]

Код:

@Echo Off
cls
>nul Chcp 1251
	Set "BoxIn=Z:\Users\Users\Desktop\Февраль 2022"
rem	Set "BoxIn=%~dp0"
	Set "BoxOut=%BoxIn%"

	Set "Ext=xlsx"

	If "%BoxIn:~-1%"=="\"  Set "BoxIn=%BoxIn:~0,-1%"
	If "%BoxOut:~-1%"=="\" Set "BoxOut=%BoxOut:~0,-1%"

	For /F "usebackq delims=" %%f In (`2^>nul Dir "%BoxIn%\*.%Ext%" /B /A:-D ^| FindStr/I /R /V /C:"^.*([0-9]*)\.%Ext%$"`) Do (
		2>nul Md "%BoxOut%\%%~nf"
		>nul Move "%BoxIn%\%%f" "%BoxOut%\%%~nf\"
		>nul Move "%BoxIn%\%%~nf(*)%%~xf" "%BoxOut%\%%~nf\"
	)
Exit /B

Путь к входной и выходной папке укажите свой. Я здесь указал их одинаковыми. Если батник в исходной папке, уберите rem

[4zz]

megaloman,

ВЫ ВОЛШЕБНИК!!!
СПАСИБО!!! СУПЕР!!!)))

[Julia111]

Доброго дня! Помогите , пожалуйста, создать скрипт.
Есть файлы у которых название начинается с индексов «420004 …. 420005 …. 420021 … И так далее»
Подскажите как для каждого файла создать папку? Чтобы и файл туда переместился.

[megaloman]

Код:

@Echo Off &cls
>nul Chcp 1251
	Set "BoxIn=Z:\Box_In"
	Set "Mask=42*.*"
	Set "BoxOut=Z:\Box_In"

	For /F "usebackq delims=" %%f In (`2^>nul Dir "%BoxIn%\%Mask%" /B /A:-D ^| FindStr /I /R /B /C:"[0-9][0-9][0-9][0-9][0-9][0-9]"`) Do (
		If Exist "%BoxIn%\%%f" (
			Set "Name=%%f"
			2>nul Call MD "%BoxOut%\%%Name:~0,6%%"
			>nul Call Move /Y "%BoxIn%\%%Name:~0,6%%*.*" "%BoxOut%\%%Name:~0,6%%\"
		) 
	)
pause
Exit /B