[rested]

пока на дельфи почти все сделали, с вбс не как... видимо не посильно.

[Iska]

и еще к информации там файлы с кодировкой unicode... »

Это шутка такая, да? В приведённых Вами файлах — ANSI/1251. Никаким юникодом даже и не пахнет.

Далее — зачем мне два одинаковых файла под разными именами? При нужде я могу проделать то же самое с ничуть не меньшим успехом, получив хоть сотню их. Мне нужны были примеры, образцы. Разные. Я, конечно, ценю юмор, но не настолько.

Да — и при частом повторе:

не посильная задача ?! »

пока на дельфи почти все сделали, с вбс не как... видимо не посильно. »

он не вызывает ничего, кроме раздражения.

Пробуйте:

читать дальше »

Код:

Option Explicit

Dim strSourceFolder

Dim objFile
Dim objRegExp
Dim strContent


If WScript.Arguments.Count = 1 Then
	strSourceFolder = WScript.Arguments.Item(0)
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FolderExists(strSourceFolder) Then
			Set objRegExp = WScript.CreateObject("VBScript.RegExp")
			
			With objRegExp
				.IgnoreCase = True
				.Pattern    = ".*(RE:[\S\s]*?)From:.*"
			End With
			
			For Each objFile In .GetFolder(strSourceFolder).Files
				If LCase(.GetExtensionName(objFile.Name)) = "txt" Then
					With .OpenTextFile(objFile.Path)
						strContent = .ReadAll()
						.Close
					End With
					
					If objRegExp.Test(strContent) Then
						objFile.Copy .GetBaseName(objFile.Name) & ".bak", True
						
						With .CreateTextFile(objFile.Path)
							.WriteLine objRegExp.Execute(strContent).Item(0).Submatches(0)
							.Close
						End With
					End If
				End If
			Next
			
			Set objRegExp = Nothing
		Else
			WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
			WScript.Quit 2
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <Source folder>"
	WScript.Quit 1
End If

WScript.Quit 0

Можно просто перетащить исходную папку на скрипт.