CMD/BAT

Iska · Отправлено: **19:47, 03-04-2020** | #2

Devddd, переименовывает во что?

Devddd · Отправлено: **19:58, 03-04-2020** | #3

К названию файла например добавляем 111

megaloman · Отправлено: **20:32, 03-04-2020** | #4

Код:

@Echo Off

Rem %1 Каталог
Rem %2 Маска файлов
Rem %3 Префикс для переименования (может отсутствовать, то есть в параметре "")
Rem %4 Суффикс для переименования (может отсутствовать или  в параметре "")

	If "%~3"=="" If "%~4"=="" Exit /B 1
	If Not "%~1"=="" If Not "%~2"=="" (
		For %%f In ("%~1\%~2") Do Ren "%%~f" "%~3%%~nf%~4%%~xf"
	)
Exit /B

Любой параметр с пробелами должен быть в кавычках

megaloman · Отправлено: **07:50, 04-04-2020** | #5

Виноват! Не увидел:

Цитата Devddd:

которые имеют атрибут "только для чтения". »

Работает так:

Код:

@Echo Off

Rem %1 Каталог
Rem %2 Маска файлов
Rem %3 Префикс для переименования (может отсутствовать, то есть в параметре "")
Rem %4 Суффикс для переименования (может отсутствовать или  в параметре "")

	If "%~3"=="" If "%~4"=="" Exit /B 1
	If Not "%~1"=="" If Not "%~2"=="" (
		FOR /F "usebackq delims=" %%f IN (`2^>nul Dir /B /A:-DR "%~1\%~2"`) DO Ren "%~1\%%~f" "%~3%%~nf%~4%%~xf"
	)
Exit /B