[MKN]

Хотелось бы ясности для ситуаци, когда требуется установить драйверы из NSIS инсталлятора. И не только драйверы оборудования, но и специфические драйверы, не имеющие HWID (во всяком случае, явного...). ( драйверы для видеоприложений, программ записи дисков и пр.)
В частности интересует установка, когда имеются такие сочетания файлов :
К примеру - drv.sys и drv.inf. (ну, это болеее-менее ясно...) , один только drv.sys, drv.sys и "вспомогательная" DLL, вообще какой нибудь странный драйвер типа 001.fcl и т.п.
Ессно для "разноразрядных" ОС всех типов.
Специальных плагинов для установки драйверов, вроде как нет, а "devcon и dpinst" утилиты годятся только для установки драйверов оборудования...

Ну, при иналичии INF файла наверное можно использовать команду (?) :

rundll32.exe setupapi.dll,InstallHinfSection DefaultInstall 0 Путь\drv.inf

А если нет INF ? Как вообще устанавливаются такие драйверы ?

[kotkovets]

А если нет INF ? Как вообще устанавливаются такие драйверы ? »

По такому поводу, как - нужно спрашивать у разраба драйвера, что в реестр писать, регистрировать и т.д
А по INF файлу, я иногда ставлю драйвера к тюнеру вот так, проверял тока XP

читать дальше »

Код:

!define ERROR_NO_SUCH_DEVINST       -536870389
!define SPOST_NONE                  0
!define SPOST_PATH                  1
!define SPOST_URL                   2
!define SP_COPY_DELETESOURCE        0x1
!define SP_COPY_REPLACEONLY         0x2
!define SP_COPY_NOOVERWRITE         0x8
!define SP_COPY_OEMINF_CATALOG_ONLY 0x40000
!define CM_LOCATE_DEVNODE_NORMAL    0x00000000
!define CM_REENUMERATE_NORMAL       0
!define InstallDriver               "!insertmacro InstallDriverCall"

!include "logiclib.nsh"


!macro InstallDriverCall HID INFPATH INFDIR
     System::Store S 
      Push `${INFDIR}`
      Push `${INFPATH}`
      Push `${HID}`
      DetailPrint "Rescan drivers..."
      System::Call "cfgmgr32::CM_Locate_DevNode(*i.r0, n, i${CM_LOCATE_DEVNODE_NORMAL}) i.r1"
      ${If} $1 <> 0
         StrCpy $1 1
      ${Else}
          System::Call "cfgmgr32::CM_Reenumerate_DevNode (ir0, i${CM_REENUMERATE_NORMAL}) i.r1"
         ${IfThen} $1 <> 0 ${|}StrCpy $1 2${|}
      ${EndIf}
      ${If} $1 = 0
          DetailPrint "Installing the driver..."
          System::Call "newdev::UpdateDriverForPlugAndPlayDevices(i0, ts, tss, i0, *i0)?ei.s"
         Pop $0
         IntCmp $0 ${ERROR_NO_SUCH_DEVINST} 0 +2 +2
         DetailPrint "The device is not plugged in, cannot update the driver."
         ${If} $0 = 0
              System::Call "setupapi::SetupCopyOEMInf(ts, ts, i${SPOST_PATH}, i0, i0, i0, *i0, tn)i.r0"
              IntCmp $0 1 0 +2 +2
              DetailPrint "Istall driver success!"
              IntCmp $0 0 0 +2 +2
              DetailPrint "Istall driver error!"
         ${EndIf}
    ${ElseIf} $1 = 1
          DetailPrint "An error occurred while trying to get the device instance for the machine"
    ${ElseIf} $1 = 2
          DetailPrint "An error occurred while trying to refresh the device list"
    ${EndIf}
    System::Store L
!macroend

OutFile InstDrv.exe
ShowInstDetails show

Section
   # ${InstallDriver} "HWID" "путь к inf файлу" "папка с дровами"
   ${InstallDriver} "PCI\VEN_1131" "$EXEDIR\beholder.inf" "$EXEDIR"
SectionEnd

MKN, вдруг я, напишу драйвер, который будет при установке компилировать еще нужные компоненты для установки...
И будут другие пользователи ломать голову, как...

[BARS73]

подскажите пожалуйста строчку кода для вывода ярлыка на рабочий стол...

[kotkovets]

подскажите пожалуйста строчку кода »

Код:

CreateShortCut "$DESKTOP\Мой_ацкий_линк.lnk" "$INSTDIR\my_proga.exe"

[K.A.V.]

В дополнение к сообщению kotkovets
Страничка справки по команде из будущей версии "Справочника по NSIS"
CreateShortCut: создаём ярлыки

читать дальше »

Команда "CreateShortCut" предназначена для создания ярлыков.

Код:

 Расположение_ярлыка.lnk Путь_до_файла.exe [параметры_запуска [Файл_иконки [Индекс_иконки [Тип_окна [Горячая_клавиша [Описание_ярлыка]]]]]]

В параметре "Тип окна" вы можете указать одно из значений:
SW_SHOWNORMAL
SW_SHOWMAXIMIZED
SW_SHOWMINIMIZED

Создаём обычный ярлык:

Код:

CreateShortCut "$DESKTOP\Справочник по NSIS.lnk" "$WINDIR\NSIS_Help.chm"

Ярлык с файлом иконки:

Код:

CreateShortCut "$DESKTOP\Справочник по NSIS.lnk" "$WINDIR\NSIS_Help.chm" "" "$WINDIR\Explorer.exe" "2"

Ярлык с сочетанием клавиш ALT+F5 для запуска и с описанием ярлыка:

Код:

CreateShortCut "$DESKTOP\Справочник по NSIS.lnk" "$WINDIR\NSIS_Help.chm" "" "" "" "" "ALT|F5" "Это единственный русскоязычный справочник по NSIS"

[BARS73]

а путь к .exe нужно указывать к тому, который распаковался уже?

спасибо!! наконец таки разобрался))

[BARS73]

и еще один вопрос...
как поместить ярлык в пуск->все программы, в отдельной папке естественно?

[Krinkels]

как поместить ярлык в пуск->все программы, в отдельной папке естественно? »

Ну для начала нужно там создать саму папку, а потом туда поместить ярлык.
Вот пример:

Код:

CreateDirectory "$SMPROGRAMS\${APPNAME}\"
CreateShortCut "$SMPROGRAMS\${APPNAME}\Packers Show.lnk" "$INSTDIR\PackersShow.exe"
CreateShortCut "$SMPROGRAMS\${APPNAME}\Help.lnk" "$INSTDIR\Help.chm"
CreateShortCut "$SMPROGRAMS\${APPNAME}\Uninstall.lnk" "$INSTDIR\Uninstall.exe"

[kotkovets]

Дополненение к сообщению Krinkels , разместить ярлыки в меню в пуск->все программы
для текушего пользователя, перед созданием ярлыков (по умолчанию NSIS создает ярлыки для текущего пользователя)

Код:

SetShellVarContext current

для всех пользователей:

Код:

SetShellVarContext all

Небольшой пример перенаправления папки пользователя:

Код:

SetShellVarContext current
    MessageBox MB_OK $DESKTOP
SetShellVarContext all
   MessageBox MB_OK $DESKTOP

[BARS73]

а для того чтобы вставлять в эту папку Uninstall.exe нужно его создать, верно?
тогда вопрос, что может быть не так в строчке

Код:

WriteUninstaller "$OUTDIR\uninst.exe"

, мне выдает ошибку