[sov44]

Syna, так?

Код:

@Echo Off
set papka=D:\Din

For /F "delims=" %%a In ('dir /b/s/a-d "%papka%"') Do Echo %%~nxa - %%~ta
pause
exit /b

[gora]

Код:

@Echo Off
SetLocal EnableDelayedExpansion
set folder=e:\Temp 1
For /F "delims=" %%a In ('dir /A:-D /T:C /O:D "%folder%" ^| Findstr /E /c:".txt" /c:".xml"') Do (
	Set ta=%%a
	Set name=!ta:~36!
	Set dat=!ta:~0,10!
	Echo !dat!	!name!
)
Pause
Exit

[Syna]

Спасибо, "gora", то что нужно, если не трудно, можешь еще в этот скрипт дописать следующие:
нужно копировать эти файлы только, если они меньше даты создания файла.
Например: файл создан 12.12.2012 его копировать не надо, если файл создан 06.12.2012 его надо уже копировать, т.е. интервал -5 дней.
Еще раз, огромное спасибо.

[gora]

Код:

@Echo Off
SetLocal EnableDelayedExpansion
Set folder=e:\Temp
Set old=5

For /F "Tokens=1 Delims=." %%i In ('WMIC OS Get LocalDateTime^|Find "."') Do Set tim=%%i
Set YYYY=%tim:~0,4%&Set MM=%tim:~4,2%&Set DD=%tim:~6,2%
::Call :formatMM_DD
Echo Now	%DD% %MM% %YYYY%
Call :GetOldDate %old%
Echo Old	%DD% %MM% %YYYY%

For /F "delims=" %%a In ('dir /A:-D /T:C /O:D "%folder%" ^| Findstr /E /c:".txt" /c:".xml"') Do (
	Set ta=%%a
	Set name=!ta:~36!& Set dat=!ta:~6,4!!ta:~3,2!!ta:~0,2!
	If %YYYY%%MM%%DD% GTR !dat! (Echo Copy	!dat!	%folder%\!name!) Else Echo Not copy !dat!	%folder%\!name!
)
Pause
Exit

:GetOldDate
Set /A DD-=%1
If %DD% GTR 0 GoTo formatMM_DD
Set /A MM=MM+11-((MM+10)/12)*12
If %MM%==12 Set /A YYYY-=1
For /F "Tokens=%MM%" %%i In ("31 28 31 30 31 30 31 31 30 31 30 31") Do Set X=%%i
If %MM%==2 (
	Set /A B1=YYYY%%4, B2=YYYY%%100, B3=YYYY%%400
	If !B1!==0 If Not !B2!==0 Set /A X+=1
	If !B3!==0 Set /A X+=1
)
Set /A DD=DD+X-((DD+X-1)/X)*X
:formatMM_DD
Set MM=0%MM%&Set DD=0%DD%
Set MM=%MM:~-2%&Set DD=%DD:~-2%
GoTo :EOF

[Syna]

Спасибо, огромное, gora. Выручил. Респект тебе.

[Syna]

Сегодня только толком просмотрел батник, прошу прощения за тупой вопрос. Скажи, пожалуйста, какую переменную брать для копирования старых файлов? Спасибо.

[gora]

Напишите в этой строке путь для копирования (Вы его не указали в первом сообщении):

Код:

	If %YYYY%%MM%%DD% GTR !dat! (Copy "%folder%\!name!" "Path for old files")

[Syna]

.

Напишите в этой строке путь для копирования (Вы его не указали в первом сообщении): Код: If %YYYY%%MM%%DD% GTR !dat! (Copy "%folder%\!name!" "Path for old files") »

Выдает такую ошибку:
Now 12 12 2012
Old 07 12 2012
Непредвиденное появление: /12)*12

If %YYYY%%MM%%DD% GTR !dat! (Copy "%folder%\!name!" "%folder1%")

[gora]

Выдает такую ошибку: Now 12 12 2012 Old 07 12 2012 Непредвиденное появление: /12)*12 »

1 Укажите полное название Вашей ОС и ее разрядность.
2 Попробуйте еще раз скопировать скрипт из поста 5 и не меняйте в нем ни чего кроме строки

Код:

Set folder=e:\Temp

в которой укажите путь к Вашей папке.
3 Приведите здесь путь к этой папке.
4 Покажите вывод скрипта здесь в тегах code
5 Если скрипт продолжает выдавать ошибку, то повторите пп 2-4 для скрипта из поста 3.
6 Приведите значение переменной "%folder1%"
7 Проверьте Ваши пути и имена обрабатываемых файлов на отсутствие спец. символов в них.