Любой язык

Iska · Отправлено: **20:07, 16-10-2018** | #2

Patroklos, давайте представим, что у нас есть каталог «Затупил» в каталогах «нудно», «долго» и «шмапка» с частично совпадающими именами файлов, но различающимся содержимым (полностью или частично). Например, в каждом из трёх каталогов «Затупил» есть файл «Выплыл косяк.txt», и везде — разного размера. Наши действия?

Patroklos · Отправлено: **20:39, 16-10-2018** | #3

Согласен - затупил.
Если это проще то перезаписываем. А лучше переименовываем.

megaloman · Отправлено: **22:09, 16-10-2018** | #4

Patroklos,

Если перезаписываем

Код:

@Echo off
	Set "BoxIn=Z:\Источник"
	Set "BoxOut=Z:\Результат"
	Set "Mask=*.txt"

	FOR /R "%BoxIn%" %%f IN ("%Mask%") DO Set "NDir=%%~dpf" &Call :FMove "%%f" "%%NDir:~0,-1%%" "%BoxOut%"
GoTo :Eof

:FMove
	Set "Out=%~3\%~nx2"
	If Not Exist "%Out%" Md "%Out%"
	Move /Y %1 "%Out%\" >nul
GoTo :Eof

Если переименовываем

Код:

@Echo off
	Set "BoxIn=Z:\Источник"
	Set "BoxOut=Z:\Результат"
	Set "Mask=*.txt"

	FOR /R "%BoxIn%" %%f IN ("%Mask%") DO Set "NDir=%%~dpf" &Call :FMove "%%f" "%%NDir:~0,-1%%" "%BoxOut%"
GoTo :Eof

:FMove
	Set "Out=%~3\%~nx2"
	If Not Exist "%Out%" Md "%Out%"
	Set /A i=1000
	Set "NewName=%Out%\%~nx1"
	:Begin
		If Not Exist "%NewName%" Move %1 "%NewName%" >nul &GoTo :Eof
		Set /A i+=1
		Set "NewName=%Out%\%~n1_%i:~1%%~x1"
	GoTo :Begin
GoTo :Eof

Iska · Отправлено: **22:45, 16-10-2018** | #5

Цитата Patroklos:

Согласен - затупил. »

Вообще-то это была аллюзия на нудно и шмапка

.

Patroklos · Отправлено: **22:53, 16-10-2018** | #6

Цитата megaloman:

Если перезаписываем
Если переименовываем »

Супер,супер,супер! Как всегда безукоризненно! Спасибо!

Цитата Iska:

Вообще-то это была аллюзия на нудно и шмапка »

А теперь понятно! Написал я и понял что затупил.

Patroklos · Отправлено: **09:45, 17-10-2018** | #7

Ещё раз спасибо. У меня остался один непринципиальный вопрос.
Скрипт отработал на отлично но у меня этих папок семь
и я должен буду время от времени повторять этот процесс.
В скрипте есть возможность перечислить папки через запятую
или мне сделать семь батников?

megaloman · Отправлено: **10:56, 17-10-2018** | #8

Patroklos,

Код:

@Echo Off
	Call :In "Z:\Источник" "*.txt" "Z:\Результат"
	Call :In "Z:\Источник 1" "*.txt" "Z:\Результат 12"
	Call :In "Z:\Источник 2" "*.txt" "Z:\Результат 12"
GoTo :Eof

:In
	FOR /R "%~1" %%f IN ("%~2") DO Set "NDir=%%~dpf" &Call :FMove "%%f" "%%NDir:~0,-1%%" "%~3"
GoTo :Eof

:FMove
................................  далее кусок из предыдущего кода

ПишИте хоть 100 строк с Call, при этом Маски и выходные папки могут совпадать или не совпадать при разных вызовах

Patroklos · Отправлено: **11:47, 17-10-2018** | #9

Спасибо большое!

Iska · Отправлено: **12:23, 17-10-2018** | #10

Если результирующий каталог и маски совпадают, то можно сократить до (не проверялось):

Код:

…
for %%i in (
	"Z:\Источник 1"
	"Z:\Источник 2"
	"Z:\Источник 3\Какой-то каталог"
	"Z:\Источник 3\Ещё какой-то каталог"
) do call :In "%%~i" "*.txt" "Z:\Единый результирующий каталог"
…