[c4uran]

Прошу прощение, сейчас попробую описать подробнее процесс который приходится делать руками на 30 компьютерах:

1. Запускаю Excel
2. Щелкаю в левый верхний угол на выпадающее меню файл
3. Там выбираю Параметры
4. В открывшемся меню Параметры Excel в списке слева выбираю Надстройки
5. В открывшемся меню снизу где написано Управление выбираю в выпадающем меню Надстройки Excel и правее нажимаю кнопку Перейти
6. В открывшемся меню Надстройки справа выбираю кнопку Обзор...
7. В открывшемся меню выбора файла выбираю файл надстройки в формате XLAM
8. Снова открывается меню Надстройки и там уже в списке доступных надстроек я ставлю галочку у имени надстройки которую только что добавил
9. Нажимаю Ок и меню Надстройки закрывается я оказываюсь в начальном экране с таблицей где среди верхних выпадающих меню ( файл, главная, вставка, итд появляется раздел - Надстройки
10. выбираю этот раздел и теперь могу запустить надстройку которую я добавил

[megaloman]

Удаленного доступа и админки к компьютерам нет, можно только запустить bat like приложение »

То есть, на каждом компьютере ручками Вы хотите запустить что-то типа командного файла? Для такого случая вот .vbs -скрипт на примере надстройки "Поиск решения".

Код:

With CreateObject("Excel.Application")
    .Visible = True
'    .Visible = False
    .Workbooks.Add

    .AddIns("Поиск решения").Installed = False
    .AddIns.Add ("C:\Program Files\Microsoft Office\Office14\Library\SOLVER\SOLVER.XLAM")
    .AddIns("Поиск решения").Installed = True
    
    .ActiveWorkbook.Close
    .Quit
End With

Его можно, наверное, разместить на общем ресурсе и запускать на каждой машине. Или поместить на каждой машине в автозагрузку.

Пропишите свои имена надстройки и xlam-файла.
Конечно, это сработает, если Office на всех машинах установлен одинаково и путь к надстройке одинаков.

[Iska]

c4uran, у Вас есть административные привилегии на машине? Где будет размещаться файл надстройки?

[c4uran]

Не подключает вываливает такую ошибку, прикладываю ошибку и саму надстройку

[c4uran]

Iska, надстройка лежит на диске С или в Документах

[Iska]

c4uran, ответьте на мои вопросы.

[c4uran]

Iska, простите пока долго отвечал вопросы еще не появились, прав админа на компьютерах нет

[Iska]

c4uran, тогда установка надстройки возможна только в режиме «на пользователя».

Попробуйте так:

Скрытый текст

Код:

Option Explicit

Dim strSourceFile
Dim strDestPath

Dim objFSO
Dim objFolder


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

strSourceFile = objFSO.BuildPath(objFSO.GetParentFolderName(WScript.ScriptFullName), "mc.xlam")

If objFSO.FileExists(strSourceFile) Then
	Set objFolder = WScript.CreateObject("Shell.Application").NameSpace("shell:AppData")
	
	If Not objFolder Is Nothing Then
		strDestPath = objFolder.self.Path & "\Microsoft\AddIns"
		
		If objFSO.FolderExists(strDestPath) Then
			objFSO.CopyFile strSourceFile, strDestPath & "\", True
			
			With WScript.CreateObject("Excel.Application")
				.Workbooks.Add
				.AddIns.Add(objFSO.BuildPath(strDestPath, objFSO.GetFileName(strSourceFile))).Installed = True
				.Quit
			End With
		Else
			WScript.Echo "Can't find destination folder [" & strDestPath & "]."
			WScript.Quit 3
		End If
		
		Set objFolder = Nothing
	Else
		WScript.Echo "Can't parse [shell:AppData] special folder."
		WScript.Quit 2
	End If
Else
	WScript.Echo "Can't find source file [" & strSourceFile & "]."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

Надстройка mc.xlam должна находиться рядом со скриптом. Она будет скопирована в профиль пользователя, а затем зарегистрирована.

[c4uran]

Iska, Работает спасибо, а такой вопрос почему реализация на vbs, cmd нельзя сделать подобный вызов?

[Iska]

c4uran, такую реализацию никак нельзя сделать на пакетных файлах — там нет поддержки Automation. Кроме WSH, аналогичное также можно проделать посредством PowerShell.

P.S. Исправьте заголовок темы на более соответствующее содержанию, наподобие «Добавить надстройку в Microsoft Excel», путём редактирования первого сообщения темы.