CMD/BAT

morgan-12l1 · Отправлено: **15:30, 28-12-2018** | #2

Цитата chek:

что не так? »

Если посмотреть в справку команды IF - Оператор else должен размещаться в той же строке, что и команда if.
Вот Ваши скрипт, насколько понял работает.

Код:

::@echo off
::mode con:cols=100 lines=80
set /P cb="enter name : "
if %cb% ==t (set cbFullName="termserver") else (set cb0=cb0 echo %cb0% set cbFullName=%cb0%%cb%	echo %cbFullName% )
query user /server:%cbFullName% | sort
echo.
set /p usersession= Enter the session ID: 
mstsc /v:%cbFullName% /multimon /shadow:%usersession% /control /noConsentPrompt

P.S. Что за скрипт? Если правильно понял, теневое подключение к пользователям и контроль действий?

chek · Отправлено: **16:25, 28-12-2018** | #3

нет, не работает. да и как первое эхо поймет, что нужно вывести только %cb0%, а не всю строку?
верно, теневое управление сеансами пользователей.

megaloman · Отправлено: **16:31, 28-12-2018** | #4

chek,

Код:

@Echo Off
	Set /P cb="enter name : "
	if "%cb%"=="t" Set "cbFullName="termserver"" &GoTo :Cont

	Set "cb0=cb0"
	Set "cbFullName=%cb0%%cb%"
	:Cont
echo %cbFullName% 
pause
rem query ....... Далее Ваш код

chek · Отправлено: **16:59, 28-12-2018** | #5

спасибо, работает.
а какая ошибка в моем первоначальном?

megaloman · Отправлено: **17:38, 28-12-2018** | #6

Вот Ваш вариант, но рабочий.

Код:

@Echo Off
cls
	SetLocal EnableExtensions EnableDelayedExpansion

	set /P cb="enter name : "

	if %cb%==t (
		set cbFullName="termserver"
		echo !cbFullName!
	) else (
		set cb0=cb0
		echo !cb0!
		set cbFullName=!cb0!!cb!
		echo !cbFullName!
	)
pause

В CMD есть тонкость при использовании If, For: отложенное расширение переменной среды
Проанализируйте выполнение вот этого кода:

Код:

@Echo Off
cls

Set /A i=1

Set Out=Тра ля ля

Echo До If Out=%Out%

If %i% EQU 1 (
	Set Out=куку равно 1
	Echo If i=%i% Внутри If Out=%Out%
) Else (
	Set Out=куку не равное 1
	Echo If i=%i% Внутри If Out=%Out%
)

Echo После If Out=%Out%

pause

Ненавижу!!!
В принципе, если вести себя аккуратно и не совать Echo внутрь If, то конкретно ваш код можно написать:

Код:

@Echo Off
cls
	set /P cb="enter name : "
	set "cb0="
	if %cb%==t (
		set cbFullName="termserver"
	) else (
		set cb0=cb0
		set cbFullName="cb0%cb%"
	)

echo "%cb0%" %cbFullName%
pause

Iska · Отправлено: **17:40, 28-12-2018** | #7

Цитата chek:

а какая ошибка в моем первоначальном? »

Раскрытие переменных окружения выполняется для всей команды целиком. В Вашем случае, все переменные окружения, заключённые в операторные скобки:

Цитата:

Код:

if %cb%==t (
		set cbFullName="termserver"
	) else (
		set cb0=cb0
		echo %cb0%
		set cbFullName=%cb0%%cb%
		echo %cbFullName% )

будут раскрыты перед началом исполнения всей процитированной команды (начиная с if %cb%…, и данная команда будет исполняться в таком виде:

Код:

if Содержимое_переменной_окружения_cb==t (
		set cbFullName="termserver"
	) else (
		set cb0=cb0
		echo 
		set cbFullName=Содержимое_переменной_окружения_cb
		echo )

Можете временно закомментировать @echo off и посмотреть.

Что делать — использовать отложенное раскрытие переменных окружения (сообщение коллеги megaloman выше), использовать двойное раскрытие по call (годится не для всех случаев).