[megaloman]

Vasya1998,

Если Дата/Время файла отображается в виде ДД.ММ.ГГГГ чч:мм, то вот вариант (поиск с точностью до минуты)

Код:

@Echo Off
cls
	Set "BoxIn=D:\CMD_Forum"
	Set "Mask=*.*"

	Set "NFname="
	Set "DTfile="
	Set  /A NFdate=0, NFtime=0
	For /F "usebackq delims=" %%j IN (`2^>nul Dir /A:-D /B /O:-D /T:W "%BoxIn%\%Mask%"`) DO (Call :NewFile "%BoxIn%\%%j" &GoTo :Cont)
	:Cont
	For /F "usebackq delims=" %%i IN (`2^>nul Dir /A:D /S /B /O:-D /T:W "%BoxIn%"`) DO Call :DirFiles "%%i" "%Mask%"

	Echo %DTfile% %NFname% 
Pause
GoTo :Eof

:DirFiles
	For /F "usebackq delims=" %%j IN (`2^>nul Dir /A:-D /B /O:-D /T:W "%~1\%~2"`) DO (Call :NewFile "%~1\%%j" &GoTo :Eof)
GoTo :Eof

:NewFile
rem Echo %~t1 %1
	Set "Fdate=%~t1"
	Set /A Ftime=1%Fdate:~11,2%%Fdate:~14,2%
	Set /A Fdate=%Fdate:~6,4%%Fdate:~3,2%%Fdate:~0,2%
	
	If %Fdate% LSS %NFdate% GoTo :Eof
	If %Fdate% EQU %NFdate% If %Ftime% LSS %NFtime% GoTo :Eof

	Set /A NFdate=%Fdate%, NFtime=%Ftime%
	Set "NFname=%~1"
	Set "DTfile=%~t1" 		
GoTo :Eof

В указанной папке с подпапками будет найден самый последний по времени изменения файл по указанной маске - Вы не уточняли, о каких файлах идёт речь, так что путь к папке и маску файлов напишите свои

[YuS_2]

переписать батник таким образом, чтобы он находил последний созданный файл во вложенных папках. »

Вот поправленный батник:

Код:

@echo off
set "src=C:\SourceMainDir"
set "dst=C:\DestinationDir"
for /f "delims=" %%i in ('powershell -ex bypass -c "&{(dir '%src%' -file -rec|sort -prop creationtime -desc).fullname[0]}"') do echo xcopy "%%i" "%dst%"
echo excellent!
pause&exit

в боевом применении, после do, команду echo следует удалить.

[Iska]

YuS_2, фокус не удастся: файлы по дате, конечно, сортируются, но только в пределах того каталога, в котором находятся. То есть, таким образом мы получим самый свежий файл из… «корневого» для dir каталога (если в нём нет файлов — получим самый свежий файл из первого каталога, и там нет файлов — из первого вложенного в него, нет вложенных — из второго и т.д.). Это не массив объектов и не конвеер PowerShell, увы .

[YuS_2]

Это не массив объектов и не конвеер PowerShell, увы »

А, да, верно, совсем упустил из вида рекурсию! Это же cmd
При рекурсивном просмотре файлов, они же выводятся вместе с путями, при этом сначала сортируются по именам каталогов в пути, что бы там в ключах ни нарисовали... казалось бы, какого фига? Но увы, это ведь cmd...
Отсюда вывод: переходите на powershell, чтобы не было так мучительно больно... и тоскливо.
Поправил исходное решение...

[Iska]

Отсюда вывод: переходите на powershell, чтобы не было так мучительно больно... и тоскливо. »

Таки да. Я не особо люблю PowerShell, но выбора, в общем-то, и нет.

[YuS_2]

но выбора, в общем-то, и нет »

Ну, выбор-то есть всегда (cygwin, например, а в десятке так и вообще уже и cygwin не особо нужен)... вопрос в только в том, что предпочтительнее...

[Iska]

cygwin, например, »

Чур меня, чур! .

[Vasya1998]

то вот вариант »

Спасибо, вам, большущее!
Оно работает.

поправленный батник »

Оно не заработало:
xcopy "Get-ChildItem : Не удается найти параметр, соответствующий имени параметра "file"." "C:\DestinationDir"
xcopy "строка:1 знак:32" "C:\DestinationDir"
xcopy "+ &{(dir 'C:\SourceMainDir' -file <<<< -rec|sort -prop creationtime -desc).fullname[0]}" "C:\DestinationDir"
xcopy " + CategoryInfo : InvalidArgument: ( [Get-ChildItem], ParameterBindingException" "C:\DestinationDir"
xcopy " + FullyQualifiedErrorId : NamedParameterNotFound,Microsoft.PowerShell.Commands.GetChildItemCommand" "C:\DestinationDir"
xcopy " " "C:\DestinationDir"
Но, в любом случае, большое спасибо.

А вообще, ребята, какие же вы красавчики, что помогаете. Спасибо вам всем за то что вы есть такие добрые.

[YuS_2]

Оно не заработало »

оно работает, если powershell обновить...
ну, а если случай запущенный (WinXP), то можно так:

Код:

@echo off
set "src=C:\SourceMainDir"
set "dst=C:\DestinationDir"
for /f "delims=" %%i in ('powershell -ex bypass -c "&{(dir '%src%' -rec|?{!$_.psiscontainer}|sort -prop creationtime -desc).fullname[0]}"') do echo xcopy "%%i" "%dst%"
echo excellent!
pause&exit

Но, кстати... если уж powershell на борту, то и всю задачу проще на него перевести...

Чур меня, чур! »

таладна, чего его бояться?
вполне функционально и достаточно производительно... ну, если уж powershell совсем не в радость...

[Iska]

таладна, чего его бояться? вполне функционально и достаточно производительно... ну, если уж powershell совсем не в радость... »

Ну, ежели токмо по анекдоту — «Слышь, Вась, по-моему и до аэродрома не так уж далеко» .