[gora]

Ещё один, более короткий, вариант записи определения разрядности, предложенной в посте 3.

Код:

Set xOS=x64
If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set xOS=x86

[Salmo]

А я так:

Код:

Set xOS=x86
IF EXIST %windir%\Sysnative\* Set xOS=x64

Определение из 32 битного приложения

[DesmondTruman]

Код:

Set xOS=x86   If Defined PROCESSOR_ARCHITEW6432 (Set xOS=x64) Else If "%PROCESSOR_ARCHITECTURE%"=="AMD64" Set xOS=x64

Код:

copy "test.exe" "%systemroot%\system32\test.exe" /y 
copy "test.exe" "%systemroot%\system64\test.exe" /y

Вот нужно к примеру исходя из переменной xOS использовать соответствующий путь (system32\system64). Как более элегантно их соединить не используя call?

[Salmo]

исходя из переменной xOS использовать соответствующий путь (system32\system64) »

Скажите, пожалуйста, что Вы называете соответствующим путем и что такое system64? Если это SysWOW64, то укажите, где должен оказаться test.exe в 64 битной системе, - в system32 (64 битная среда) или в SysWOW64 (32 битная)?

[angel_lyucifer]

Привет, мне нужен батник который определяет разрядность системы x86 или x64 если система 32 битная, то есть x86 то тогда нужно запустить файл 1.exe если система 64 битная то есть x64 тогда нужно запустить файл 2.exe

Кто может подскажите варианты такого батника пожалуйста.

[zion87]

Код:

@echo off
set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
reg.exe Query %RegQry% > checkOS.txt
find /i "x86" < CheckOS.txt > StringCheck.txt

if %ERRORLEVEL% == 0 (
goto os32
) else (
goto os64
)

:os32
1.exe
goto check_done

:os64
2.exe

:check_done
del StringCheck.txt, CheckOS.txt

Стучим в бубен )))

[angel_lyucifer]

Спасибо zion87!

[7ka]

2ALL

Код:

@Echo Off
If !%PROCESSOR_ARCHITECTURE%==!x86 Goto Install_x86
If !%PROCESSOR_ARCHITECTURE%==!AMD64 Goto Install_x64
Goto End
 
:Install_x86
start "" /wait msiexec /i"%~dp0\setup-x86.msi" /quiet /norestart
Goto End
 
:Install_x64
start "" /wait msiexec /i"%~dp0\setup-x64.msi" /quiet /norestart
Goto End
 
:End

[gora]

If !%PROCESSOR_ARCHITECTURE%==!x86 Goto Install_x86 »

1 Символ ! здесь применен, видимо, для "экономии" на кавычках, которые традиционно используются в таких случаях:

Код:

If "%PROCESSOR_ARCHITECTURE%"=="x86" Goto Install_x86

Прием известный, но символ выбран крайне неудачно, т.к., является спец. символом, что в ряде случаев может привести к сбоям в работе скрипта, например при наличии строки в начале скрипта:

Код:

SetLocal EnableDelayedExpansion

2 По одной переменной PROCESSOR_ARCHITECTURE нельзя определить разрядность системы однозначно! У меня на Win7 x64 она равна x86 - при запуске скрипта в х86 среде (из x86 ТС, например) и AMD64 - при запуске скрипта в х64 среде (из x64 ТС, например).
Это скорее определение среды запуска скрипта, нежели разрядности ОС.

[7ka]

gora, есть еще такой прием:

Код:

@Echo off
SystemInfo | find "x64-based PC"
if ERRORLEVEL 1 Goto Tre

:Ses
start "" /wait msiexec /i"%~dp0\setup-x64.msi" /quiet /norestart
Goto Quiet

:Tre
start "" /wait msiexec /i"%~dp0\setup-x86.msi" /quiet /norestart
:Quit
:End