[amel27]

не пойму в чем дело »

очевидно ждет окна, которого нету:

Код:

WinWaitActive ('Мастер новых подключений','Выберите, надо ли автоматически подключаться к Интернету или иной общей сети перед установлением виртуального подключения.')

как вариант - поставить таймаут ожидания в WinWaitActive() - третий параметр (в секундах), по истечении периода ожидания если окно не появится скрипт продолжит работу... для просмотра в трее строки, на которой "висит" скрипт используйте команду:

Код:

Opt("TrayIconDebug", 1)

[Vic_tory]

Спасибо за ответ, но дело в том что на компьютере на котором пишется скрипт все работает. На других компьютерах с той же ОС останавливается на активном окне 'Мастер новых подключений','Имя компьютера или IP-адрес (например, microsoft.com или 157.54.0.1):' и мигающим курсором в окне ввода имени сервера.

Если поставить таймаут то скрипт продолжает работу но в параметрах сервера остается пусто.

[proxy]

Ипользуйте утилиту: Au3Info.exe (находится в корне папки AutoIt)
и посмотрите окно на котором останавливается выполнение скрипта.

Окно должно иметь заголовок: Мастер новых подключений
В тексте окна должен присутсвовать текст (точь в точь): Имя компьютера или IP-адрес (например, microsoft.com или 157.54.0.1):

Поле ввода ip адреса должно иметь ClassnameNN: Edit1

[amel27]

Vic_tory, попробуйте так:

Код:

Run("rundll32.exe netshell.dll,StartNCW")

$TITLE = "Мастер новых подключений"
While WinWaitActive($TITLE, "", 3)
    $TEXT = WinGetText("")
    Select
        Case StringInStr($TEXT,'Этот мастер поможет:')
        Case StringInStr($TEXT,'Подключить к рабочей сети (используя удаленный доступ или VPN), чтобы можно было работать из дома, удаленного офиса или другого места.')
            ControlClick ("","","Button2")
        Case StringInStr($TEXT,'Создать подключение')
            ControlClick ("","","Button2")
        Case StringInStr($TEXT,'Организация')
            ControlSetText("","","Edit1","Name")
        Case StringInStr($TEXT,'Выберите, надо ли автоматически подключаться к Интернету или иной общей сети перед установлением виртуального подключения.')
            ControlClick ("","","Button1")
        Case StringInStr($TEXT,'Имя компьютера или IP-адрес (например, microsoft.com или 157.54.0.1):')
            ControlSetText("","","Edit1","Host")
        Case StringInStr($TEXT,'Создать это подключение:')
            ControlCommand("","","Button1","Check","")
        Case StringInStr($TEXT,'Завершение работы мастера новых подключений')
            ControlCommand("","","Button10","UnCheck","")
        Case Else
            Sleep ('100')
            ContinueLoop
    EndSelect
    Sleep ('500')
    Send('{Enter}')
WEnd

[Vic_tory]

Ипользуйте утилиту: Au3Info.exe (находится в корне папки AutoIt) и посмотрите окно на котором останавливается выполнение скрипта. Окно должно иметь заголовок: Мастер новых подключений В тексте окна должен присутсвовать текст (точь в точь): Имя компьютера или IP-адрес (например, microsoft.com или 157.54.0.1): »

Проверила окно, заголовок точно такойже
в начеле перед текстом окна стоит знак "&" поставила, не помогло

Поле ввода ip адреса должно иметь ClassnameNN: Edit1 »

так и есть

[Vic_tory]

Спасибо amel27 ваш скрипт работает :о)

только я так и не поняла почему не работает мой :о( что было не так?

[proxy]

Код:

#region: - Options
    Opt('MustDeclareVars',      1)
    Opt('TrayIconDebug',        1)
    Opt('TrayIconHide',         0)
    Opt('WinDetectHiddenText',  1)
#endregion

HotKeySet('{ESC}', '_Pro_Exit')

Local   $iPid = Run('rundll32.exe netshell.dll,StartNCW')
Local   $sRasPhoneFilePath = @AppDataCommonDir & '\Microsoft\Network\Connections\Pbk\rasphone.pbk'
Local   $sRasPhoneFileText = FileRead($sRasPhoneFilePath)
Local   $iHwd, $sText
Local   $sTitle = 'Мастер новых подключений'
Local   $sConnectName = 'Connect name - Имя подключения'
Local   $sConnectIP = '150.100.0.12'
Local   $fAddShortcutOnDesktop = 1

While 1
    $iHwd = _ProcessGetWindow($iPid)
    If BitAnd(WinGetState($iHwd), 2) Then ExitLoop
WEnd

While 1
    $sText = WinGetText($iHwd)

    Select
        Case StringInStr($sText,'Этот мастер поможет:')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:2]')

        Case StringInStr($sText,'Подключить к рабочей сети (используя удаленный доступ или VPN), чтобы можно было работать из дома, удаленного офиса или другого места.')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:2]')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:6]')

        Case StringInStr($sText,'&Подключение к виртуальной частной сети')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:2]')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:8]')

        Case StringInStr($sText,'Введите в следующем поле имя для этого подключения.')
            While 1
                If StringInStr($sRasPhoneFileText, '[' & _StringToUTF($sConnectName) & ']') OR $sConnectName == '' Then
                    $sConnectName = InputBox('Внимание', 'Подключение с иминем "' & $sConnectName & '" уже существует' & @CRLF & @CRLF & _
                                             'Введите другое название для подключения:', '', '', 300, 150, -1, -1)
                Else
                    ExitLoop
                EndIf
            WEnd
            ControlSetText($iHwd, '', '[CLASS:Edit; INSTANCE:1]', $sConnectName)
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:8]')

        Case StringInStr($sText,'Выберите, надо ли автоматически подключаться к Интернету или иной общей сети перед установлением виртуального подключения.')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:1]')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:10]')

        Case StringInStr($sText,'Введите имя узла или IP-адрес компьютера, к  которому осуществляется подключение.')
            ControlSetText($iHwd, '', '[CLASS:Edit; INSTANCE:1]', $sConnectIP)
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:10]')

        Case StringInStr($sText,'Успешно завершено создание следующего подключения:')
            If $fAddShortcutOnDesktop Then ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:1]')
            ControlClick($iHwd, '', '[CLASS:Button; INSTANCE:21]')
            ExitLoop
    EndSelect
    Sleep('10')
WEnd

Func _Pro_Exit()
    Exit
EndFunc

Func _ProcessGetWindow($iPID, $iRet=1)
    Local $aWinList = WinList()
    Local $aRet[2]

    If IsString($iPID) Then $iPID = ProcessExists($iPID)

    For $i = 1 To UBound($aWinList)-1
        If WinGetProcess($aWinList[$i][1]) = $iPID Then
            $aRet[0] = $aWinList[$i][0] ;Title
            $aRet[1] = $aWinList[$i][1] ;WinHandle

            If $iRet = 0 Then Return $aRet[0]
            If $iRet = 1 Then Return $aRet[1]

            Return $aRet
        EndIf
    Next

    Return SetError(1, 0, $aRet)
EndFunc

Func _StringToUTF($String)
    Local $sResult = "", $iCode
    Local $VarUTFArr = StringSplit($String, "")

    For $i = 1 To $VarUTFArr[0]
        $iCode = Asc($VarUTFArr[$i])

        Select
            Case $iCode >= 192 And $iCode <= 239
                $VarUTFArr[$i] = Chr(208) & Chr($iCode - 48)
            Case $iCode >= 240 And $iCode <= 255
                $VarUTFArr[$i] = Chr(209) & Chr($iCode - 112)
            Case $iCode = 168
                $VarUTFArr[$i] = Chr(208) & Chr(129)
            Case $iCode = 184
                $VarUTFArr[$i] = Chr(209) & Chr(145)
            Case Else
                $VarUTFArr[$i] = Chr($iCode)
        EndSelect

        $sResult &= $VarUTFArr[$i]
    Next

    Return $sResult
EndFunc

+ еще немного и можно сделать для работы в скрытом виде...

[Vic_tory]

Большое спасибо всем за ответы, скрипт работает.

но я так и не уяснила себе в чем было дело, хотелось бы знать, что бы не делать ошибок в будущем.

[amel27]

Vic_tory, поймите правильно - иногда проще и быстрее переписать, чем искать ошибку
обсуждалось неоднократно - посмотрите к примеру ТУТ, ТУТ и ТУТ