[Black Babay]

Я привык учится на конкретных и точных примерах. »

Пожалуйте бриться!

Скрытый текст

05-2---Create-Script-To-Remove-Metro.bat

Код:

@ECHO OFF
:: BlackBabay 2015
  TITLE Формирование скрипта для удаления предустановленных приложений
  COLOR 0A
::==================================================================
:: Корневая папка сборки
set /p wd=<%~dp0_wd.txt
:: Битность дистрибутива
set /p bits=<%~dp0_bits.txt
:: Каталог для временных файлов
set tempdir=%wd%\Temp
:: Каталог подключения образа
set mountfolder=%wd%\Mount\%bits%\InstallWIM-Mount
:: Название формируемого скрипта (рассширение .bat)
set metrodel=05-3---Remove-Metro-Packages.bat
:: Удаление предыдущей версии скрипта, если она существует
  IF EXIST %~dp0%metrodel% (DEL /F /Q %~dp0%metrodel%)
::==================================================================
  echo.
echo Установлены следующие параметры:
echo Битность дистрибутива  - %bits%
echo Каталог подключения    - %mountfolder%
echo.
echo Сейчас будет сформирован скрипт, позволяющий
echo удалить предустановленные приложения "METRO".
  echo.
echo Для начала работы, нажмите любую клавишу . . .
PAUSE > NUL
  cls
::==================================================================
  echo.
echo Формируется скрипт для удаления приложений METRO.
echo Пожалуйста подождите...
  echo.
:: Запрос сведений о МЕТРО приложениях с выводом информации во временный файл
  DISM.EXE /ScratchDir:%tempdir% /image:%mountfolder%\ /Get-ProvisionedAppxPackages > %tempdir%\AllAppxPackages.txt
:: Выборка данных из временного файла в инфо-файл
  TYPE "%tempdir%\AllAppxPackages.txt" | findstr.exe /C:"Имя пакета:" > "%tempdir%\FindAppxPackages.txt"
:: Вывод данных из инфо-файла на экран
echo В подключенном образе обнаружены следующие приложения "METRO":
  TYPE "%tempdir%\FindAppxPackages.txt"
echo.
:: ========= Эти строки копируются в начало формируемого файла =====
@echo @ECHO OFF >> %~dp0%metrodel%
@echo TITLE Удаление приложений "METRO" из подключенного образа >> %~dp0%metrodel%
@echo COLOR 0A >> %~dp0%metrodel%
@echo echo. >> %~dp0%metrodel%
@echo echo Пожалуйста подождите, приложения "METRO" покидают подключенный образ . . . >> %~dp0%metrodel%
@echo echo. >> %~dp0%metrodel%
::==================================================================
SetLocal EnableDelayedExpansion 
:: Что искать в исходном списке
set find=Имя пакета: 
:: На что заменить в формируемом файле
set replace=DISM.EXE /ScratchDir:%tempdir% /Image:%mountfolder%\ /Remove-ProvisionedAppxPackage /PackageName:
:: Выборка названий пакетов и склеивание с коммандой удаления
for /F "tokens=* delims=," %%n in (%tempdir%\FindAppxPackages.txt) do ( 
set LINE=%%n 
set LINE=!LINE:%find%=%replace%! 
@echo !LINE! >> %~dp0%metrodel%
)
:: ========= Эти строки копируются в конец формируемого файла ======
@echo echo. >> %~dp0%metrodel%
@echo echo Запрос актуального статуса "METRO" приложений в подключенном образе . . . >> %~dp0%metrodel%
@echo DISM.EXE /ScratchDir:%tempdir% /image:%mountfolder%\ /Get-ProvisionedAppxPackages >> %~dp0%metrodel%
@echo echo. >> %~dp0%metrodel%
@echo PAUSE >> %~dp0%metrodel%
::==================================================================
:: Удаление временных файлов
  IF EXIST %tempdir%\*.txt (DEL /F /Q %tempdir%\*.txt)
echo.
echo Скрипт для удаления предустановленных приложений "METRO" готов.
echo Название файла:"%metrodel%"
::==================================================================
echo.
echo Для завершения работы скрипта, нажмите любую клавишу . . .
PAUSE > NUL
:eof

_bits.txt

Код:

x64

_wd.txt

Код:

D:\WIN-10-PREP\RU-WIN10-PRO-VL

Результат работы скрипта:
05-3---Remove-Metro-Packages.bat

Код:

@ECHO OFF 
TITLE Удаление приложений "METRO" из подключенного образа 
COLOR 0A 
echo. 
echo Пожалуйста подождите, приложения "METRO" покидают подключенный образ . . . 
echo. 
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.3DBuilder_10.9.50.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Appconnector_2015.707.550.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.BingFinance_4.6.169.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.BingNews_4.6.169.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.BingSports_4.6.169.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.BingWeather_4.6.169.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.CommsPhone_1.10.15000.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.ConnectivityStore_1.1509.1.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Getstarted_2.3.7.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Messaging_1.10.22012.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.MicrosoftOfficeHub_2015.6306.23501.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.MicrosoftSolitaireCollection_3.3.9211.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Office.OneNote_2015.6131.10051.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Office.Sway_2015.6216.20251.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.People_2015.1012.106.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.SkypeApp_3.2.1.0_neutral_~_kzf8qxf38zg5c   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.Windows.Photos_2015.1001.17200.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsAlarms_2015.1012.20.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsCalculator_2015.1009.20.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsCamera_2015.1071.40.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:microsoft.windowscommunicationsapps_2015.6308.42271.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsMaps_4.1509.50911.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsPhone_2015.1009.10.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsSoundRecorder_2015.1012.110.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.WindowsStore_2015.1013.14.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.XboxApp_2015.930.526.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.ZuneMusic_2019.6.13251.0_neutral_~_8wekyb3d8bbwe   
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /Image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Remove-ProvisionedAppxPackage /PackageName:Microsoft.ZuneVideo_2019.6.13251.0_neutral_~_8wekyb3d8bbwe   
echo. 
echo Запрос актуального статуса "METRO" приложений в подключенном образе . . . 
DISM.EXE /ScratchDir:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Temp /image:D:\WIN-10-PREP\RU-WIN10-PRO-VL\Mount\x64\InstallWIM-Mount\ /Get-ProvisionedAppxPackages 
echo. 
PAUSE

/Remove-ProvisionedAppxPackage

Это если совсем коротко.

[Vadikan]

Я привык учится на конкретных и точных примерах »

tsya.ru

[pandarianin]

Black Babay, а одной командой разве нельзя удалить все приложения, нужно для каждого приложения отдельную команду давать? Подойдет ли скрипт для Windows 8?

Vadikan вы кажеться на форуме не разу так и ни давали ответа на подобный вопрос лиш кидали сылки на староние сайты мол читайте и разберайтесь сами.
Так вот, я это читал, и сообщаю что по тем ссылкам инфы недостаточно.

ps. Хотя может я и ошибаюсь, может это даже и не вы ссылки давали.

[Vadikan]

не разу так и ни давали ответа на подобный вопрос лиш кидали сылки на староние сайты мол читайте и разберайтесь сами. »

а одной командой разве нельзя удалить все приложения, нужно для каждого приложения отдельную команду давать? »

Между прочим, вы сегодня дублировали этот вопрос в другой теме, где как раз была ссылка на статью, в которой описана "одна команда". Да, она для установленной системы, а не подключенного образа, но это легко исправить, если потратить 5 минут на чтение документации или той же статьи, где написано решение для образа.

А документация Microsoft и недосказанные статьи, о том как работать с DISM мне ни чего не говорят. »

Так вы не пытаетесь в них вникнуть. Просто ждете, пока вам готовое решение тут выложат. Это видно даже по вопросам "Подойдет ли скрипт для Windows 8", ибо в ссылке на документацию это черным по белому написано.

LOL

Так вот, я это читал »

Нет, не читали, видно же ↓ :)

вы кажеться »

[Harkovchanin1968]

К сожалению я очень поздно увидел эту статью, вот может кому пригодится в будущем, по другим вопросам можно к примеру в google вводить запрос так Как из общего дистрибутива Windows 10 выделить одно издание, ремонт компа (или remontcompa), из большей долей вероятности вы найдёте ответ.