[lipro122]

P.S. Лучше сразу заиметь привычку заключать пути в качестве аргументов скриптов WSH в кавычки, независимо от наличия в них пробелов. Привыкнете — станете делать сие автоматически. »

Привыкну ))) .. мне так удобнее )))... спасибо большое.

[artem_cher]

Здравствуйте, можете мне кто нито помочь? Ситуация такая, нужен скрипт или программка которая будет удалять вложенные папки с файлами из рабочей директории. То есть имеется сервер на котором делается бэкап, (e:/backup) в этой директории создается папка с датой создания>туда копируется дамп базы, и после этого он в ней архивируется в rar архив. Но есть одно но, иногда дамп снимается с ошибками и он не архивируется или недоорхивируется, нужно что бы скрипт проверял перед удалением папки, что бы всегда в директории оставалась последний актуальный бэкап. (По хорошему завершению бэкапа, в папке с датой остается один файл Export.rar, если что то не так в папке много файлов).

[Iska]

artem_cher, хорошо бы изложить то же самое, но по-русски.

[zhuk09]

Добрый день!
Подниму старую тему)!
Необходимо для этой части кода

Код:

intDays = Int(Wscript.arguments.Item(0))
strFldr = Wscript.arguments.Item(1)

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objDIR = objFSO.GetFolder(strFldr)
Set objCol = objDIR.Files

For Each objItem In objCol
   If DateDiff("d", objItem.DateLastModified, Now) > intDays Then objItem.Delete
Next

Добавить рекурсивное удаление файлов во всех вложенных папках переменной strFldr
Спасибо!

[zhuk09]

Добавить рекурсивное удаление файлов во всех вложенных папках переменной strFldr »

С этим вроде бы справились, для удаления только файлов, удалили строку

Код:

If oI.Size = 0 Then oI.Delete

Сам скрипт выглядит так

Код:

intDays = 1
strFldr = "D:\Work"

Set objFSO = CreateObject("Scripting.FileSystemObject")
DelOld strFldr, intDays

Function DelOld(sFldr, iDays)
On Error Resume Next
   Dim oD, cF, cD, oI

   Set oD = objFSO.GetFolder(sFldr)
   Set cF = oD.Files
   Set cD = oD.SubFolders

   For Each oI In cF
      If DateDiff("d", oI.DateLastModified, Now) > iDays Then oI.Delete
   Next

   For Each oI In cD
      DelOld oI.Path, iDays
      Next
End Function

[kaelrnd]

Добрый день, нужен скрипт или программа, ну или другое решение для следующей ситуации: IP камера записывает видеофайлы и файлы log в расшаренную папку на одном из компов в сети, данные файлы записываются в папку имеющую название в виде даты, в ней создаются папки с названием равным текущем времени, в данные папки соответственно записываются видеозаписи и файлы лог. Требуется, чтобы раз в 3-4 дня удалялась самая старая папка (места на диске мало и когда оно кончается, видео перестает писаться). Также, хотелось бы, чтобы из общей папки, где создаются все эти файлы и папки удалялись файлы *.log (эти файлы создаются, когда камера фиксирует движение и их достаточно много).
Может ли кто помочь в решении данного вопроса?

[Dimu4]

Подскажите, пожалуйста можно ли автоматизировать вот это действие:
Windows7, в которой 20 пользователей, раз в неделю нужно на каждой из них почистить папки - C:\Users\userNNN\AppData\Local\Temp для каждого пользователя(имя пользователей в формате user_NNN)

[Iska]

Dimu4, можно.

[Dimu4]

У меня была вот такая мысль - создать cmd файл, в нем

Код:

forfiles.exe /p %temp% /s /m *.* /d -14 /c "cmd /c del /q /f @file"

Вместо %temp% написать путь к каждой папке которую надо почистить и создать сценарий как тут - https://www.youtube.com/watch?v=-l24UCfQ7Cg который будет при выходе из системы или перезагрузке чистить папки пользователей.
Может есть еще подсказки/идеи?
Спасибо

[Iska]

Например, назначьте групповой политикой на Logout пользователям:

Скрытый текст

Код:

Option Explicit

Const TemporaryFolder = 2
Const intDays2Live   = 30

Dim strPathToClear


With WScript.CreateObject("Scripting.FileSystemObject")
	strPathToClear = .GetSpecialFolder(TemporaryFolder)
	
	If .FolderExists(strPathToClear) Then
		ClearSubFolders .GetFolder(strPathToClear)
	Else
		WScript.Quit 1
	End If
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub ClearSubFolders(objFolder)
	Dim objSubFolder
	Dim objFile
	
	
	For Each objSubFolder In objFolder.SubFolders
		ClearSubFolders objSubFolder
	Next
	
	For Each objFile In objFolder.Files
		If DateDiff("d", objFile.DateLastModified, Now()) > intDays2Live Then
			objFile.Delete True
		End If
	Next
	
	If (objFolder.Files.Count = 0) And (objFolder.SubFolders.Count = 0) Then
		If objFolder.Path = strPathToClear Then
			' Nothing to do
		Else
			objFolder.Delete True
		End If
	End If
End Sub
'=============================================================================