[mitiya]

__sa__nya,
перекодировать 1.txt в 2.txt , удалить 1.txt , переименовать 2.txt в 1.txt

не подходит ?

[amel27]

mitiya, __sa__nya, если в этих файлах удалить первые три псевдосимвола (BOM), RECODE вроде работает... по ходу это наследие никсов... кстати, мануал по утилю: http://www.informatik.uni-hamburg.de...ecode_toc.html

__sa__nya, типа такого?.. с учетом замен двух строчек, как сказал mitiya

Код:

For /F "Delims=" %%i In ('DIR /B *.txt') Do (
   cscript //Nologo recode.vbs "%%i" "%%~dpn.tmp"
   copy /Y "%%~dpn.tmp" "%%i"
   del "%%~dpn.tmp"
)

[__sa__nya]

amel27, самое оно , вроде работает, сейчас возьму файлов с десяток, буду проверять.
Еще вопрос: чтобы скрипт vbs отрабатывал, какая служба в системе должна быть запущена, он же на что-то опирается?

[amel27]

__sa__nya, WSH - это встроенный набор компонент, службы тут не причем:

- для VBS минимум Win2K, но лучше XP/2003 или обновить WSH до версии 5.6;
- для поддержки "ADODB.Stream" минимум XP SP2, иначе накатывать MDAC 2.8

[mitiya]

а скомпилировать в exe vbs нельзя ? только действительно скомпилировать , а не так как с батниками, вся компиляция которых заключается просто в запихивание в ехе который распаковывает сам батник в темп и от туда запускает его.

[amel27]

mitiya, смысл?.. ИМХО это из разряда извращений, если очень хочется используй AutoIT... в него кста можно запихать и VBS-код

[anatolysn]

взято из http://forum.oszone.net/post-1156258-6.html

а как выставить принудительно кодировку 866 в получаемом файле в это скрипте?

Код:

FileIn  = "info.xml"
FileOut = "info.txt"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(FileOut, 2, vbTrue)
strText = FileDecode(FileIn, "utf-8")
objFile.WriteLine(strText)

Function FileDecode (strFile, strCP)
   Set Stream = CreateObject("ADODB.Stream")
   With Stream
     .Type = 2
     .Mode = 3
     .CharSet = strCP
     .Open
     .LoadFromFile(strFile)
   End With
   FileDecode = Stream.Readtext()
   Stream.Close
End Function

[Iska]

а как выставить принудительно кодировку 866 в получаемом файле в это скрипте? »

WSH: пример конвертации текста из кодировки в кодировку — Windows Script Host, HTA (VBScript, JScript) — Коллекция скриптов и идей — Серый форум:

Доступные варианты кодировок на компьютере для использования в вышеприведённых скриптах находятся в реестре по адресу HKEY_CLASSES_ROOT\MIME\Database\Charset.

В данном случае сие может выглядеть, например, так:

Код:

Option Explicit

Const adTypeText            = 2
Const adModeReadWrite       = 3
Const adSaveCreateOverWrite = 2


Dim strSourceFile
Dim strDestFile

Dim strSourceCharset
Dim strDestCharset

Dim objFSO
Dim strContent


strSourceFile = "C:\Мои проекты\0153\0001.xml"
strDestFile   = "C:\Мои проекты\0153\Result.txt"

strSourceCharset = "utf-8"
strDestCharset   = "cp866"


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strSourceFile) Then
	With WScript.CreateObject("ADODB.Stream")
		.Type = adTypeText
		.Mode = adModeReadWrite
		
		.Charset = strSourceCharset
		.Open
		.LoadFromFile strSourceFile
		strContent = .ReadText()
		.Close
		
		.Charset = strDestCharset
		.Open
		.WriteText strContent
		.SaveToFile strDestFile, adSaveCreateOverWrite
		.Close
	End With
Else
	WScript.Echo "Can't find source file [" & strSourceFile & "]."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

[anatolysn]

Код:

strSourceFile = "C:\test\*.log"
strDestFile   = "C:\test\*.log"

Код:

strSourceFile = "C:\test\*.log"
strDestFile   = "C:\test\dir2\*.log"

пакетный режим не работает когда нужно все файлы в одной папке с расширением log конвертировать в другую кодировку

на единичный файл работает проверил , гуд

система windows xp sp3

П.С.
Я не программист, ссылки на код не понимаю только юзать умею.

[Iska]

пакетный режим не работает »

Странно, да ?

нужно все файлы в одной папке с расширением log конвертировать в другую кодировку »

Вот с этого и нужно было начинать.

Код:

Option Explicit

Dim strSourceFolder
Dim objFile


strSourceFolder = "C:\Мои проекты\0153"

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strSourceFolder) Then
		For Each objFile In .GetFolder(strSourceFolder).Files
			If StrComp(.GetExtensionName(objFile.Name), "log", vbTextCompare) = 0 Then
				ConvertFile objFile.Path, "utf-8", "cp866"
			End If
		Next
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub ConvertFile(strFile, strSourceCharset, strDestCharset)
	Const adTypeText            = 2
	Const adModeReadWrite       = 3
	Const adSaveCreateOverWrite = 2
	
	Dim strContent
	
	With WScript.CreateObject("ADODB.Stream")
		.Type = adTypeText
		.Mode = adModeReadWrite
		
		.Charset = strSourceCharset
		.Open
		.LoadFromFile strFile
		strContent = .ReadText()
		.Close
		
		.Charset = strDestCharset
		.Open
		.WriteText strContent
		.SaveToFile strFile, adSaveCreateOverWrite
		.Close
	End With
End Sub
'=============================================================================

Путь к целевому каталогу и расширение файлов тупо заданы в коде, резервные копии не делаются.